Never get a single pixel when you can get a whole line

The getPixels and setPixels functions for reading and writing pixels from / to bitmaps are rather slow.

When changing a large number or even all pixels of a bitmap, it is a good idea to perform the getPixels() and setPixels() just once for each horizontal line and do the rest of the work with the resulting array elements.

In the following examples, a 1000x1000 pixels bitmap should be altered by changing every single pixel. This means reading and writing back one million pixels.

In the first example, every single pixel will be read separately, multiplied by a number and written back. We will stop the time in order to compare to the optimized version.

b = bitmap 1000 1000 color:red--create new bitmap with red background
st = timestamp()--get start time in milliseconds
for y = 1 to 1000 do--go through all lines in the bitmap
(
  for x = 1 to 1000 do--go through all pixels in a line
  (
    pixels = getPixels b [x-1,y-1] 1--read one pixel from X,Y
    pixels[1] *= (x+y)/2000.0--alter the pixel
    setPixels b [x-1,y-1] pixels--write modified pixel back
  )--end x loop
)--end y loop
et = timestamp()--get end time in milliseconds
print (et-st)--print time to finish
display b--show a nice black-red gradient

In the second example, instead of reading every single pixel, will be read every line and process all its pixels inside the array returned by getPixels() before writing the whole line back to the bitmap. This means we will make only 1000 read and 1000 write calls instead of one million reads and one million writes.

b = bitmap 1000 1000 color:red--create new bitmap with red background
st = timestamp()--get start time in milliseconds
for y = 1 to 1000 do--go through all lines in the bitmap
(
  pixels = getPixels b [0,y-1] 1000--read all 1000 pixels of a single line
  for x = 1 to 1000 do--go through all pixels in the line
  (
    pixels[x] *= (x+y)/2000.0--alter the pixel
  ) 
  setPixels b [0,y-1] pixels--write back the complete modified line
)
et = timestamp()--get end time in milliseconds
print (et-st)--print time to finish
display b--show the same nice black-red gradient 

Since 3ds Max 2010, the pasteBitmap() function can be used in a custom function: mode to perform per-pixel operations using a MAXScript function. This method does not involve the getPixels() and setPixels() calls but does the same and is also great for bothcompositing two bitmaps together and for manipulating pixels ina single bitmap as in our test example.We simply pass the same bitmap twice. The result is normally stored in the second bitmap, in this case it is identical to the first bitmap so we effectively read and write using one bitmap value:

fn compfn c1 p1 c2 p2 =
(
  c1 * ((p1.x+p1.y)/2000.0)
)
b = bitmap 1000 1000 color:red--create new bitmap with red background
st = timestamp()--get start time in milliseconds
pasteBitmap b b [0,0] [0,0] type:#function function:compfn--call the function per pixel
et = timestamp()--get end time in milliseconds
print (et-st)--print time to finish
display b--show the same nice black-red gradient

The following table shows the times in milliseconds for the three examples at different image resolutions:

Previous Tip

Use the 'flagForeground' node viewport state method

Next Tip

Only calculate once if possible

 Except where otherwise noted, this work is licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License. Please see the Autodesk Creative Commons FAQ for more information.