Biped Node Hierarchy

Biped Node Hierarchy RelatedMethods

biped.maxNumNodes <biped | biped_ctrl>

Maximum nodes supported by Biped.

See the desrciption of biped.getNode() for a list of the top level nodes.

biped.maxNumLinks <biped | biped_ctrl>

Maximum link nodes supported by Biped.

See the desrciption of biped.getNode() for a list of the link nodes.

bipObj = biped.createNew 100 0 [0,0,0]  arms:true  neckLinks :5\
spineLinks:5 legLinks:4 tailLinks:5 ponyTail1Links:5 \
ponyTail2Links:5 fingers:5 fingerLinks:3 toes:5\
toeLinks:3 ankleAttach:0.3 trianglePelvis:True \
prop1Exists:True prop2Exists:True prop3Exists:True \
forearmTwistLinks:4

nn = biped.maxNumNodes bipObj
nl = biped.maxNumLinks bipObj
for i = 1 to nn do
(
anode = biped.getNode bipObj i
if anode != undefined do
(
format "% :\t%\n" i anode.name
for j = 1 to nl do
(
alink = biped.getNode bipObj i link:j
if alink != undefined do
format "% : % \t%\n" i j alink.name
)
)
)

The above example code will give you all of the Biped nodes, but it will NOTgive you the Biped twisty nodes.

In 3ds Max 7 it used to get the forearm twist nodeswith ID 24 and 25, but that was all the twist nodes a Biped had.

In 3ds Max 8, twist nodes were added for the upper arms, the calves, the horse legs, and the thighs.

maxNumNodes was changed to return 22 instead of 24, so one could no longer access the forarm twists.

The IDs of the forarm twists were changed, and newIDs were added for all of the other twists, but there were no methods to allow users to access the twists.

Twisty Bones Methods

The following methods were added in 3ds Max 9 to allow user access to the twisty bones in a Biped. They each take a Biped controller as their only parameter:

Biped.maxTwistNodes  <biped | biped_ctrl>

Number of twist node tracks supported by Biped.

See the description of biped.getNode() for a list of the top level twist nodes.

Biped.maxTwistLinks  <biped | biped_ctrl>

Maximum number of link nodes for each twist track supported by Biped.

See the desrciption of biped. biped.getNode() for a list of the link nodes.

Biped.getTwistStartId <biped | biped_ctrl>

Starting id for twist nodes.

See the desrciption of biped.getNode() for a list of the twist nodes and their ids.

Below is an example which gets all of the twisty nodes in a Biped.

nn = biped.maxTwistNodes bipObj
format "num twist nodes: %\n" nn
nl = biped.maxTwistLinks bipObj
format "max twist links: %\n" nl
ts = biped.getTwistStartId bipObj
format "twist start id: %\n" ts
 
for i = ts to ts+nn-1 do
(
    anode = biped.getNode bipObj i
   if anode != undefined do
    (
        format "% :\t%\n" i anode.name
       for j = 1 to nl do
        (
            alink = biped.getNode bipObj i link:j
           if alink != undefined do
            (
                format "% : % \t%\n" i j alink.name
            )
        )
    )
)