Float メソッド(ActiveX)

ツールバーを浮動します。

サポートされているプラットフォーム: Windows のみ

構文と要素

VBA:

object.Float Top, Left, NumberFloatRows

object

タイプ: Toolbar

このメソッドが適用されるオブジェクト。

Top

アクセス: 入力のみ

タイプ: 長整数型

ツールバーの上端のピクセル位置。

Left

アクセス: 入力のみ

タイプ: 長整数型

ツールバーの左端のピクセル位置。

NumberFloatRows

アクセス: 入力のみ

タイプ: 長整数型

水平ツールバーで作成する行数。ツールバーのボタンは指定された行数で自動的に横に配置されます。

戻り値(RetVal)

戻り値はありません。

注意

追加の注意はありません。

例

VBA:

Sub Example_Float()
    ' This example creates a new toolbar called "TestToolbar" and inserts three
    ' buttons into it. The toolbar is then displayed as a floating toolbar,
    ' and then as a docked toolbar.
    ' To remove the toolbar after execution of this macro, use the Customize Menu
    ' option from the Tools menu.
    
    Dim currMenuGroup As acadMenuGroup
    Set currMenuGroup = ThisDrawing.Application.MenuGroups.Item(0)
    
    ' Create the new toolbar
    Dim newToolBar As AcadToolbar
    Set newToolBar = currMenuGroup.Toolbars.Add("TestToolbar")
    
    ' Add three buttons to the new toolbar.
    ' All three buttons will have the same macro attached.
    Dim newButton1 As AcadToolbarItem
    Dim newButton2 As AcadToolbarItem
    Dim newButton3 As AcadToolbarItem
    Dim openMacro As String
    
    ' Assign the macro string the VB equivalent of "ESC ESC _open "
    openMacro = Chr(3) & Chr(3) & Chr(95) & "open" & Chr(32)
    
    Set newButton1 = newToolBar.AddToolbarButton("", "NewButton1", "Open a file.", openMacro)
    Set newButton2 = newToolBar.AddToolbarButton("", "NewButton2", "Open a file.", openMacro)
    Set newButton3 = newToolBar.AddToolbarButton("", "NewButton3", "Open a file.", openMacro)
    
    ' Display the toolbar
    newToolBar.Visible = True
    
    ' Dock the toolbar to the left of the screen.
    newToolBar.Dock acToolbarDockLeft
    GoSub QUERYSTATUS
    
    ' Float the toolbar
    newToolBar.Float 200, 200, 1
    GoSub QUERYSTATUS
    
    Exit Sub
    
QUERYSTATUS:
    ' Query the toolbar to see if it is docked.
    If newToolBar.DockStatus = acToolbarFloating Then
        MsgBox "The toolbar is floating."
    Else
        MsgBox "The toolbar is docked."
    End If
    Return
    
End Sub

Visual LISP:

(vl-load-com)
(defun c:Example_Float()
    ;; This example creates a new toolbar called "TestToolbar" and inserts three
    ;; buttons into it. The toolbar is then displayed as a floating toolbar,
    ;; and then as a docked toolbar.
    ;; To remove the toolbar after execution of this macro, use the Customize Menu
    ;; option from the Tools menu.
    (setq acadObj (vlax-get-acad-object))
    (setq currMenuGroup (vla-Item (vla-get-MenuGroups acadObj) 0))
  
    ;; Create the new toolbar
    (setq newToolBar (vla-Add (vla-get-Toolbars currMenuGroup) "TestToolbar"))
    
    ;; Add three buttons to the new toolbar.
    ;; All three buttons will have the same macro attached.
    (setq openMacro (strcat (Chr 3) (Chr 3) (Chr 95) "open" (Chr 32)))
    
    (setq newButton1 (vla-AddToolbarButton newToolBar "" "NewButton1" "Open a file." openMacro))
    (setq newButton2 (vla-AddToolbarButton newToolBar "" "NewButton2" "Open a file." openMacro))
    (setq newButton3 (vla-AddToolbarButton newToolBar "" "NewButton3" "Open a file." openMacro))    
    
    ;; Display the toolbar
    (vla-put-Visible newToolBar :vlax-true)
    
    ;; Dock the toolbar to the left of the screen.
    (vla-Dock newToolBar acToolbarDockLeft)

    ;; Query the toolbar to see if it is docked.
    (if (= (vla-get-DockStatus newToolBar) acToolbarFloating)
        (alert "The toolbar is floating.")
        (alert "The toolbar is docked.")
    )
    
    ;; Float the toolbar
    (vla-Float newToolBar 200 200 1)
  
    (if (= (vla-get-DockStatus newToolBar) acToolbarFloating)
        (alert "The toolbar is floating.")
        (alert "The toolbar is docked.")
    )
)