概要 - 引出線の関連付け(ActiveX/VBA)

引出線は、注釈に関連付けられています。そのため、注釈を移動すると、引出線の終点もそれに応じて移動します。

文字および公差記入枠の注釈を移動すると、最後の引出線セグメントは、注釈と最後から 2 番目の引出線の点との関係に応じて、注釈の右側または左側に変更されます。注釈の中点が引出線の最後から 2 番目の点の右側にある場合は、引出線は右側に付きます。そうでない場合は、左側に付きます。

Delete、Add (ブロックを追加)、または WBlock メソッドのいずれかを使用して図面からオブジェクトを削除すると、関連付けが失われます。引出線とその注釈を 1 回の操作でまとめて複写した場合は、関連付けが保持されます。別々にコピーした場合、関連付けは失われます。引出線オブジェクトのみを複写したり、注釈を削除するなどして、両者の関連付けが失われた場合は、その理由に関わらず、フック ラインが引出線から除去されます。

引出線を注釈に関連付ける

次の例は、MText オブジェクトを作成します。次に、この MText オブジェクトを注釈にして引出線を記入します。

Sub Ch5_AddAnnotation()
    Dim leaderObj As AcadLeader
    Dim mtextObj As AcadMText
    Dim points(0 To 8) As Double
    Dim insertionPoint(0 To 2) As Double
    Dim width As Double
    Dim leaderType As Integer
    Dim annotationObject As Object
    Dim textString As String, msg As String

    ' Create the MText object in model space
    textString = "Hello, World."
    insertionPoint(0) = 5
    insertionPoint(1) = 5
    insertionPoint(2) = 0
    width = 2
    Set mtextObj = ThisDrawing.ModelSpace. _
 AddMText(insertionPoint, width, textString)

    ' Data for Leader
    points(0) = 0: points(1) = 0: points(2) = 0
    points(3) = 4: points(4) = 4: points(5) = 0
    points(6) = 4: points(7) = 5: points(8) = 0
    leaderType = acLineWithArrow

    ' Create the Leader object in model space and associate
    ' the MText object with the leader
    Set annotationObject = mtextObj
    Set leaderObj = ThisDrawing.ModelSpace. _
 AddLeader(points, annotationObject, leaderType)
    ZoomAll
End Sub