庭園の歩道内にタイルを描く

タイルは、歩道の境界の長さと幅、およびユーザが指定したタイルの半径と間隔に基づいて、庭園の歩道の境界内に描画されます。

庭園の歩道の境界の計算と描画に使用する関数を定義したら、次の手順は、庭園の歩道の境界内のタイルの計算と配置に使用する関数を定義することです。タイルの描画関連のタスクを完了するためには、次の 3 つのカスタム関数を使用します。

gp:calcTiles: 境界内に配置する列数を計算し、1 列に配置するタイル数を計算する gp:calcTileRow 関数を呼び出します。
gp:calcTileRow: 庭園の歩道の境界に沿ったタイルの列数を計算します。
gp:drawTile: ユーザが指定したオプションに基づいて、円形タイルまたは六角タイルを描画します。

gpdraw.lsp ファイルを開く

庭園の歩道のタイルの計算と描画に使用する関数を、gpdraw.lsp ファイルに追加します。このファイルには、庭園の歩道の境界の計算と描画に使用される関数も含まれます。次に、gpdraw.lsp ファイルを開く方法を説明します。

次のいずれかの操作を行います。

(Windows) gpdraw.lsp ファイルをダブルクリックして、メモ帳でこのファイルを開きます。
(Windows 7) [スタート]ボタン [すべてのプログラム] [アクセサリ] [メモ帳]をクリックします。[ファイル]メニュー、[開く]の順に選択します。[ファイルの種類]ドロップダウンリストから[すべてのファイル(*.*)]を選択します。gpdraw.lsp ファイルを参照して選択し、[開く]を選択します。
(Windows 8) [スタート]画面で、note と入力し、[メモ帳]をクリックします。[ファイル]メニュー、[開く]の順に選択します。[ファイルの種類]ドロップダウンリストから[すべてのファイル(*.*)]を選択します。gpdraw.lsp ファイルを参照して選択し、[開く]を選択します。
(Mac OS) gpdraw.lsp ファイルをダブルクリックして、テキストエディットで開きます。
注: アプリケーションの指定を求めるプロンプトが表示されたら、[アプリケーションを選択]をクリックします。[アプリケーションを選択]ダイアログボックスで、[テキストエディット]を選択し、[開く]をクリックします。
(Mac OS) [Finder]で、Mac OS メニューバーから[移動]メニュー、[アプリケーション]の順に選択します。[アプリケーション]ウィンドウで、[テキストエディット]をダブルクリックします。テキストエディットで、Mac OS メニューバーから[ファイル]、[開く]の順に選択します。gpdraw.lsp ファイルを参照して選択し、[開く]を選択します。

タイルの配置を計算する

次の手順では、gp: calcTiles という名前の関数を定義できます。この関数は、庭園の歩道の境界に沿った列数を計算します。

gp:calcTiles 関数は、次の単一の引数を受け入れます。

boundaryData: ユーザが指定した値、および庭園の歩道の境界のサイズと配置を決定するために計算された値を表すドットペアのリストです。リストは、主に、gp:getPathInput、gp:getTileInput、gp:getBorderStyleInput 関数によって返される値で構成されます。

gp:calcTiles 関数は、庭園の歩道の境界に追加されるすべてのタイルのリストを返します。

gpdraw.lsp ファイルをまだ開いていない場合は、メモ帳またはテキストエディットで開きます。

メモ帳またはテキストエディットのエディタ領域で、gp:drawPathBoundary 関数の最後の右括弧の後ろで、[Enter]を 2 回押します。その後、次のように入力します。

(defun gp:calcTiles (boundaryData /
                     pathLength tileSpace tileRadius
                     spaceFilled spaceToFill rowSpacing
                     offsetFromCenter rowStartPoint
                     pathWidth pathAngle tileList
                    )

  (setq
    ;;; Get values from the BoundaryData list
    pathLength       (cdr (assoc 41 boundaryData))
    tileSpace        (cdr (assoc 43 boundaryData))
    tileRadius       (cdr (assoc 42 boundaryData))
    spaceToFill      (- pathLength tileRadius)
    rowSpacing       (* (+ tileSpace (* tileRadius 2.0))
                        (sin (Degrees->Radians 60))
                     )
    spaceFilled      rowSpacing
    offsetFromCenter 0.0
    offsetDistance   (/ (+ (* tileRadius 2.0) tileSpace) 2.0)
    rowStartPoint    (cdr (assoc 10 boundaryData))
    pathWidth        (cdr (assoc 40 boundaryData))
    pathAngle        (cdr (assoc 50 boundaryData))
  )

  ;; Compensate for the very first Start Point!
  (setq	rowStartPoint
        (polar rowStartPoint
               (+ pathAngle pi)
               (/ tileRadius 2.0)
        )
  )
  
  ;; Draw each row of tiles
  (while (<= spaceFilled spaceToFill)
    ;; Get the list of tiles created, adding them to our list
    (setq tileList (append tileList
                           (gp:calcTileRow
                               boundaryData
                               (setq rowStartPoint
                                     (polar rowStartPoint
                                            pathAngle
                                            RowSpacing
                                     )
                               )
                               offsetFromCenter
                           )
                   )

          ;; Calculate the distance along the path for the next row
          spaceFilled (+ spaceFilled rowSpacing)

          ;; Alternate between a zero and a positive offset
          ;; (causes alternate rows to be indented)
          offsetFromCenter (if (= offsetFromCenter 0.0)
                             offsetDistance
                             0.0
                           )
    )
  )
  
  ;; Return the list of tiles created
  tileList
)

LSP ファイルを保存します。

タイルの列数を計算する

次の手順では、gp:calcTileRow という名前の関数を定義できます。この関数は、gp calcTiles 関数によって計算された列のタイル数を計算します。

gp:calcTileRow 関数は、次の 3 つの引数を受け入れます。

boundaryData: ユーザが指定した値、および庭園の歩道の境界のサイズと配置を決定するために計算された値を表すドットペアのリストです。リストは、主に、gp:getPathInput、gp:getTileInput、gp:getBorderStyleInput 関数によって返される値で構成されます。
startPoint: 次のタイルの列の中心と、この列に配置される最初のタイルの点を表す点のリストです。
offsetFromCenter: タイルを 1 列おきに交互に配置するための、庭園の歩道の中心からのオフセット距離です。

gp:calcTileRow 関数は、庭園の歩道の境界内の 1 つの列に追加されるすべてのタイルのリストを返します。

メモ帳またはテキストエディットのエディタ領域で、gp:calcTiles 関数の最後の右括弧の後ろで、[Enter]を 2 回押します。その後、次のように入力します。

(defun gp:calcTileRow (boundaryData startPoint offsetFromCenter /
                       halfWidth tileSpacing angp90 angm90
                       firstCenterPt tileCenterPt tileList
                       pathWidth pathAngle tileRadius tileSpace
                       tileShape
                      )

  ; Extract values from the list boundaryData
  (setq	pathAngle     (cdr (assoc 50 boundaryData))
        pathWidth     (cdr (assoc 40 boundaryData))
        tileRadius    (cdr (assoc 42 boundaryData))
        tileSpace     (cdr (assoc 43 boundaryData))
        tileShape     (cdr (assoc 5  boundaryData))
  )

  ; Calculate values for placing tiles along in the garden path boundary
  (setq	halfWidth     (- (/ pathWidth 2.00) tileRadius)
        tilespacing   (+ (* TileRadius 2.0) tileSpace)
        angp90        (+ pathAngle (Degrees->Radians 90))
        angm90        (- pathAngle (Degrees->Radians 90))
        firstCenterPt (polar startPoint angp90 offsetFromCenter)
        tileCenterPt  firstCenterPt
  )
  
  ; Draw the circles to the left of the center
  (while (< (distance startPoint tileCenterPt) HalfWidth)
    ; Add each tile to the list to return
    (setq tileList
          (cons (gp:drawTile tileCenterPt tileRadius tileShape pathAngle)
                tileList
          )
    )

    ; Calculate the center point for the next tile
    (setq tileCenterPt (polar tileCenterPt
                              angp90
                              tileSpacing
                       )
    )
  )

  ; Draw the circles to the right of the center
  (setq	tileCenterPt (polar firstCenterPt
                            angm90
                            tileSpacing
                     )
  )
  
  (while (< (distance startPoint tileCenterPt) HalfWidth)
    ; Add each tile to the list to return
    (setq tileList (cons (gp:drawTile tileCenterPt tileRadius tileShape pathAngle)
                         tileList
                   )
    )

    ; Calculate the center point for the next tile
    (setq tileCenterPt (polar tileCenterPt
                              angm90
                              tileSpacing
                       )
    )
  )

  ; Return a list containing the tiles drawn
  tileList
)

LSP ファイルを保存します。

円形タイルまたは六角タイルを描く

次の手順では、gp:drawTile という名前の関数を定義できます。この関数は、gp:calcTileRow によって計算されたタイルを描画します。

gp:drawTile 関数は、次の 3 つの引数を受け入れます。

centerPoint: 描画されるタイルの中心を表す点のリストです。
tileRadius: 描画されるタイルの半径を表す実数です。
tileShape: 描画されるタイルのタイプを表す文字列です。有効な値は、Circular または Hexagon です。

gp:drawTile 関数は、描画される円オブジェクトまたはポリラインオブジェクトの図形名を返します。

メモ帳またはテキストエディットのエディタ領域で、gp:calcTileRow 関数の最後の右括弧の後ろで、[Enter]を 2 回押します。その後、次のように入力します。

(defun gp:drawTile (centerPoint tileRadius tileShape tileRotation / )
  (if (= (strcase tileShape) "CIRCULAR")
    (command "._CIRCLE" centerPoint tileRadius)
    (progn
      (command "._POLYGON" 6 centerPoint "_I" tileRadius)
      (command "._ROTATE" (entlast) "" centerPoint (Radians->Degrees tileRotation))
    )
  )
  (entlast)
)

LSP ファイルを保存します。