4.4 エフェクトインタフェース

4.4.1 スクリーンスペースアンビエントオクルージョン(SSAO)コントロール

MPassContext 内の情報は、SSAO (スクリーンスペースアンビエントオクルージョン)をサポートするために要求される特定のパスをレンダリングするためにプラグインがいつ呼び出されるかを示すための十分な情報を提供します。

SSAO の内部アルゴリズムには、中間結果を生成するための特定の法線の深度のパスが必要です。既定では、レンダラは、このパスに使用される特定のシェーダを設定します。プラグインシェーダによってジオメトリがディスプレイスされる、または法線が変更される場合は、この既定値シェーダをオーバーライドすることができます。

この法線の深度パスは、シャドウマップのパスを検出するのと同様の方法で MPassContext 情報を照会することで検出します(セクション 4.2.1 「シャドーイングコントロール」を参照)。このパスでは、パス識別子は MPassContext::kNormalDepthPassSemantic となります。

テッセレーションシェーダが必要な場合、オーバーライドを MShaderInstance ではなく MPxShaderOverride に追加する必要があります。

サポートを追加するには、カスタムシェーダは以下の条件を考慮する必要があります。

2 色のターゲットは、法線の深度のパス中にバインドされます。
- カラーターゲット 0 には、符号なしで固定小数点の RGB フォーマットがあります。
- カラーターゲット 1 には浮動小数点の単一チャネル (R) フォーマットがあります。
- 現在のターゲット情報は、プラグインに利用可能な場合、MFrameContext から利用できるようになります。
ジオメトリ要件:
- オブジェクト空間の法線ストリーム
- オブジェクト空間の位置ストリーム
必要な出力値:
- カラーターゲット 0 に書き込まれた正規化された法線値(符号なし、ワールド空間内)
- カラーターゲット 1 に書き込まれた深度値(ワールド空間内)。

以下に、HLSL で記述された、このパスで使用されるシェーダのサンプルを示します。

// Vertex shader input structure.
struct VS_INPUT_NormalDepth
{
    float3 Pos : POSITION;
    float3 Normal: NORMAL;
};

// Vertex shader output structure.
struct VS_TO_PS_NormalDepth
{
    float4 HPos : SV_Position;
    float4 NormalDepth : TEXCOORD0;
};

// Vertex shader.
VS_TO_PS_NormalDepth VS_NormalDepth(VS_INPUT_NormalDepth In)
{
    VS_TO_PS_NormalDepth Out;
    
    // Transform the vertex from object space to clip space.
    Out.HPos = mul(float4(In.Pos, 1.0f), gWVPXf);
    
    // Record the normal and depth components for the pixel shader.
    Out.NormalDepth.xyz = mul(In.Normal, gWVITXf);
    Out.NormalDepth.w = mul(float4(In.Pos, 1.0f), gWVXf).z;

    return Out;
}

// Pixel shader output structure.
struct PS_OUT
{
    float4 Normal : SV_Target0;
    float4 Depth : SV_Target1;
};

// Pixel shader.
PS_OUT PS_NormalDepth(VS_TO_PS_NormalDepth In)
{
    PS_OUT Out;

    // Set the normal for an unsigned normalized integer target, and depth for a floating-point
    // target.
    Out.Normal = float4((normalize(In.NormalDepth.xyz) + 1.0f) * 0.5f, 0.0f);
    Out.Depth  = In.NormalDepth.wwww;

    return Out;
}

注:上記の説明は、Maya 2014 での内部パスの動作です。

重要:カスタムシェーダに対するジオメトリ要件については、適切な入力ストリームが提供されない場合、レンダラは内部的にそれらを作成しようと試みます。これはフレームごとに発生し、パフォーマンスに影響する場合があります。たとえば、MPxGeometryOverride がカスタムシェーダに対するジオメトリを提供するように書かれている場合、コードが位置のみを返し、法線ストリームを返さない場合、内部的に法線値を派生させようと試みます。

4.4 エフェクト インタフェース

4.4.1 スクリーンスペース アンビエント オクルージョン(SSAO)コントロール

4.4 エフェクトインタフェース

4.4.1 スクリーンスペースアンビエントオクルージョン(SSAO)コントロール