fileDialog2

ジャンプ先: 概要. 戻り値. フラグ. MEL 例.

概要

fileDialog2 [-cancelCaption string] [-caption string] [-dialogStyle int] [-fileFilter string] [-fileMode int] [-fileTypeChanged string] [-okCaption string] [-optionsUICommit string] [-optionsUICreate] [-optionsUIInit string] [-returnFilter boolean] [-selectFileFilter string] [-selectionChanged string] [-startingDirectory string]

fileDialog2 は、取り消し可能、照会不可能、および編集不可能です。

戻り値

フラグ

ロング ネーム(ショート ネーム)	引数タイプ	プロパティ
-dialogStyle(-ds)	int
1 は Windows または Mac OS X では、一般的なスタイルのファイル ダイアログが使用されます。 2 はプラットフォーム間で一致したスタイルのカスタム ファイル ダイアログが使用されます。
-caption(-cap)	string
ダイアログのタイトルを設定します。
-startingDirectory(-dir)	string
ダイアログの開始ディレクトリを設定します。
-fileFilter(-ff)	string
ダイアログのファイル タイプ フィルタのリストを設定します。複数フィルタの場合は、二重のセミコロンで分離する必要があります。例を参照してください。
-selectFileFilter(-sff)	string
初期ファイル フィルタを、選択するように指定します。ワイルドカード仕様全体ではなく、開始テキストのみを指定します。
-fileMode(-fm)	int
ダイアログが返す内容を示します。 0 は任意のファイルが存在するかどうか。 1 は 1 つの既存ファイル。 2 はディレクトリ名。ディレクトリとファイルの両方がダイアログに表示されます。 3 はディレクトリ名。ディレクトリのみがダイアログに表示されます。 4 は 1 つ以上の既存ファイル名。
-okCaption(-okc)	string
dialogStyle フラグを 2 に設定すると、ダイアログのボタンに OK または Accept のキャプションが表示されます。
-cancelCaption(-cc)	string
dialogStyle フラグを 2 に設定すると、ダイアログのボタンに Cancel のキャプションが表示されます。
-returnFilter(-rf)	boolean
true の場合、選択したフィルタは選択したファイルとともに、文字配列の最後の項目として返されます。
-optionsUICreate(-ocr)
MEL のみ。文字列は MEL コールバックとして解釈され、ファイル ダイアログの作成時にコールされます。コールバックの形式は次のとおりです。 global proc MyCustomOptionsUISetup(string $parent) 親引数は、コントロールを追加できる親レイアウトです。この親は、ファイル ダイアログの右手のペインです。
-optionsUIInit(-oin)	string
MEL のみ。文字列は MEL コールバックとして解釈され、コントロールを初期化するためにファイル ダイアログの作成直後にコールされます。コールバックの形式は次のとおりです。 global proc MyCustomOptionsUIInitValues(string $parent, string $filterType) 親引数は、optionsUICreate フラグを使用してコントロールが追加された親レイアウトです。filterType 引数は初期ファイル フィルタです。
-fileTypeChanged(-ftc)	string
MEL のみ。文字列は MEL コールバックとして解釈され、ユーザが選択したファイル タイプの変更時にコールされます。コールバックの形式は次のとおりです。 global proc MyCustomFileTypeChanged(string $parent, string $newType) 親引数は、optionsUICreate フラグを使用してコントロールが追加された親レイアウトです。newType 引数は新しいファイル タイプです。
-selectionChanged(-sc)	string
MEL のみ。文字列は MEL コールバックとして解釈され、ユーザがファイル ダイアログでファイルの選択を変更したときにコールされます。コールバックの形式は次のとおりです。 global proc MyCustomSelectionChanged(string $parent, string $selection) 親引数は、optionsUICreate フラグを使用してコントロールが追加された親レイアウトです。selection 引数は新たに選択されたファイルへのフル パスです。
-optionsUICommit(-ocm)	string
MEL のみ。文字列は MEL コールバックとして解釈され、ダイアログの却下に成功するとコールされます。ユーザがダイアログをキャンセルした場合、またはウィンドウ タイトル バーのコントロールかその他のウィンドウ システムの手段を使用してウィンドウを閉じた場合は、コールされません。コールバックの形式は次のとおりです。 global proc MyCustomOptionsUICommit(string $parent) 親引数は、optionsUICreate フラグを使用してコントロールが追加された親レイアウトです。

フラグはコマンドの作成モードで表示できます	フラグはコマンドの編集モードで表示できます
フラグはコマンドの照会モードで表示できます	コマンド内でフラグを複数回使用できます。

MEL 例

// Single file filter with no description.
string $basicFilter = "*.mb";
string $result[] = `fileDialog2 -fileFilter $basicFilter -dialogStyle 2`;

// Single filter with a description.
string $singleFilter = "All Files (*.*)";
string $result[] = `fileDialog2 -fileFilter $singleFilter -dialogStyle 2`;

// Multiple filters separated by double semi-colons. The first filter has multiple file types.
string $multipleFilters = "Maya Files (*.ma *.mb);;Maya ASCII (*.ma);;Maya Binary (*.mb);;All Files (*.*)";
string $result[] = `fileDialog2 -fileFilter $multipleFilters -selectFileFilter "Maya Binary" -dialogStyle 2`;

//
// An example of how to add UI to the Maya file dialog.
//

global proc MyCustomOptionsUISetup(string $parent)
{
setParent $parent;
$parent = `scrollLayout -childResizable true`;

// generate some UI which will show up in the options tab of the Maya file dialog
columnLayout -adj true;
iconTextRadioCollection itRadCollection;
iconTextRadioButton -st "iconAndTextVertical" -i1 "sphere.png" -l "sphere" SphereIconButton;
iconTextRadioButton -st "iconAndTextVertical" -i1 "cone.png" -l "cone" ConeIconButton;
iconTextRadioButton -st "iconAndTextVertical" -i1 "cube.png" -l "cube" -select CubeIconButton;
}

global proc MyCustomOptionsUIInitValues(string $parent, string $filterType)
{
setParent $parent;
if (`optionVar -exists MyCustomUIOptVar`)
{
string $selected = `optionVar -q MyCustomUIOptVar`;
iconTextRadioCollection -edit -select $selected itRadCollection;
}
}

global proc MyCustomOptionsUICommit(string $parent)
{
setParent $parent;
optionVar -sv MyCustomUIOptVar `iconTextRadioCollection -q -select itRadCollection`;
}

global proc MyCustomSelectionChanged(string $parent, string $selection)
{
setParent $parent;
print ("$selection: " + $selection + "\n");
}

global proc MyCustomFileTypeChanged(string $parent, string $newType)
{
setParent $parent;
print ("$newType: " + $newType + "\n");
}

fileDialog2 -fileFilter "Maya Binary (*.mb);;Maya ASCII (*.ma);;All Files (*.*)"
-optionsUICreate "MyCustomOptionsUISetup"
-optionsUIInit "MyCustomOptionsUIInitValues"
-optionsUICommit "MyCustomOptionsUICommit"
-fileTypeChanged "MyCustomFileTypeChanged"
-selectionChanged "MyCustomSelectionChanged";