Использование AutoLISP для установки MODEMACRO

Присвоение значений MODEMACRO в AutoLISP.

Прим.: AutoLISP недоступен в AutoCAD LT. Системная переменная MODEMACRO не поддерживается в Mac OS.

AutoLISP можно использовать, чтобы назначить строковое значение системной переменной MODEMACRO и отобразить результат в строке состояния. Используется функция AutoLISP strcat для создания полной строки MODEMACRO из коротких строк компонентов.

(defun C:ACADMODE()
  (setvar "modemacro"
    (strcat
        "Layer $(substr,$(getvar,clayer),1,8)"
        "$(if,$(getvar,orthomode), Ortho)"
        "$(if,$(getvar,snapmode), Snap)"
        "$(if,$(=,$(getvar,tilemode),0),"
        "$(if,$(=,$(getvar,cvport),1), P)"
        ")"
    )
  )
)

В следующем примере используется функция S::STARTUP для загрузки файла AutoLISP с именем mode1.lsp и установки строкового значения системной переменной MODEMACRO.

;;; S::STARTUP loads the file MODE1.LSP which defines a MODEMACRO string
(defun S::STARTUP ( )
  (load "mode1")
 (princ)
)
;;; Additional AutoLISP files can also be defined or loaded here

Когда файл AutoLISP mode1.lsp загружен, он заставляет системную переменную MODEMACRO отображать сведения в строке состояния. Отображаемый текст начинаются с L:, затем следуют первые восемь символов текущего имени слоя, имени чертежа и часть пути, а также первая буква имени каждого из режимов являющихся на данный момент активными. Независимо от длины имени слоя, положение имени чертежа остается неизменным.

;;; MODE1.LSP
(setvar "modemacro" 
  (strcat
    "L:$(substr,$(getvar,clayer),1,30)"
    "$(substr,        ,1,$(-,30,$(strlen,$(getvar,clayer)))) "
    ;;            ^^^^^^^^ Note the 8 spaces here
    "<.."
      "$(if,$(eq,$(getvar,dwgname),UNNAMED),UNNAMED,"
        "$(substr,$(getvar,dwgname),"
          "$(if,$(>,$(strlen,$(getvar,dwgprefix)),29),"
            "$(-,$(strlen,$(getvar,dwgprefix)),29),1"
          "),"
          "$(strlen,$(getvar,dwgname))"
        ")"
      ")"
    ">"
    "$(if,$(getvar,orthomode), O, )"
    "$(if,$(getvar,snapmode), S, )"
    "$(if,$(and,"
    "$(=,$(getvar,tilemode),0),$(=,$(getvar,cvport),1)),P)"
  )
)

внутри программ на AutoLISP можно вычислять также DIESEL-выражения, используя функцию menucmd .