永続グローバル変数

MAXScript では、特定の種類のクラスに限り、存続グローバル変数がサポートされています。グローバルを存続グローバル変数として宣言すると、この変数を含む値が、シーン ファイルを開くたびにシーン ファイルから復元され、閉じるたびにシーン ファイルに保存されます。こうしておくと、シーン内のオブジェクトへの直接参照を変数に保存することができ、シーンの保存や再読み込みを行っても参照が維持されます。

グローバル変数を存続グローバル変数として宣言するには、予約語 persistent を指定します。

persistent global foo, baz, bar

変数 foo 、 baz 、および bar を存続変数として宣言します。これ以降、 foo 、 baz 、および bar の値は、シーンの保存時に .max シーン ファイルに保存されます。このファイルを再度開くと、 foo 、 baz 、 bar に保存されている値が復元されます。これらの変数がまだ宣言されていない場合は、暗黙的に存続グローバル変数として宣言されます。

存続グローバル変数の現在の制限は、特定の種類の値しかシーン ファイルに保存できないことと、シーン ファイルへ保存する値やシーン ファイルからロードする値もこれらのタイプに限られることです。

サポートされている値のクラスは、AngleAxis、Array、Boolean、Color、Double、EulerAngles、Float、Integer、Integer64、IntegerPtr、Interval、Matrix3、Name、OK、Point2、Point3、Point4、Quat、Ray、String、Struct、Time、Undefined、Unsupplied およびすべての MAXWrapper クラス(ノード、モディファイヤ、コントローラ、マテリアルなど)です。これ以外のタイプの値は、 undefined として復元されます。

配列の場合には、配列内の上記にリストした値のみが適切に保存され復元されます。その他の値は、保存された配列内で undefined として表示されます。

IntegerPtr の読み込みおよび保存のサポートが 3ds Max 2015 に追加されました。以前の 3ds Max バージョンに保存する場合、IntegerPtr の値は Integer64 の値として格納されます。

存続グローバル変数は、[ファイル](File) > [リセット](Reset)、[ファイル](File) > [新規](New)、または[ファイル](File) > [開く](Open)を実行したときに存続グローバル変数プールから削除されますが、その MAX セッションの間は、通常の非存続グローバル変数としてメモリに残っています。その後、MAX セッション中に宣言された存続グローバル変数は「存続」しなくなり、そのセッション中に他のファイルが保存されるごとに格納されます。

必要であれば、 #filePreSave コールバックを使用して、新規ファイルごとに存続グローバル変数をインストールできます。詳細は、「一般イベント コールバック機能」を参照してください。

ただし、この動作は、元々存続グローバル変数として宣言された変数が、スクリプトの作成または実行中に複数のシーンにわたって通常のグローバル変数として定義されたままでも、これらの保存したシーンが別の MAX セッションで再び開かれたときには、undefined として表示されるということも意味します。

以下に、コールバックを使用してこのような場合を処理する 2 つの例を示します。

callbacks.addscript #systemPostNew "persistent global myVar" id:#myTools
callbacks.addscript #systemPostReset "persistent global myVar" id:#myTools
callbacks.addscript #filePostOpen "persistent global myVar" id:#myTools

重要な変数は宣言され直すだけで、その値は影響されないまま、存続グローバル変数としてシーン内に保存されます。

callbacks.addscript #systemPostReset "persistent global myVar=0.0" id:#myTools
callbacks.addscript #systemPostNew "persistent global myVar=0.0" id:#myTools
callbacks.addscript #filePreOpen "myVar=undefined" id:#myTools
callbacks.addscript #filePostOpen "if myVar==undefined do (persistent global myVar=0.0)" id:#myTools

[ファイル](File) > [リセット](Reset)および[ファイル](File) > [新規](New)のイベントでは、重要な変数は宣言し直され既定値が割り当てられますが、[ファイル](File) > [開く](Open)のイベントでは、変数は最初に undefined になってから、ファイルが開いた後でテストされます。この存続グローバル変数が開かれているシーン内ですでに存在し定義されている場合、この変数は、古い値を持つ存続グローバル変数としてすでに復元されています。この場合、すでに存続グローバル変数プールに入っており、明示的に削除するまで存続し続けるため、存続グローバル変数として宣言し直す必要はありません。

on myToolsUtility close do (callbacks.removeScripts id:#myTools)

存続グローバル変数を作成、収集、テスト、表示、および削除するためのメソッドについては、「Persistents 構造体」を参照してください。

-- persistents - node only
persistent global global_array = #() 
global_array[1] = b= box() 
global_array[2] = bm= bend() 
global_array[3] = sm= standard() 
global_array[4] = fog() 
global_array[5] = area() 
global_array[6] = bezier_float() 
global_array[7] = br= bricks() 
global_array[8] = lookat() 
global_array[9] = blur() 
global_array[10] = MapScaler() 
--b.material=sm 
--addmodifier b bm 
--sm.diffusemap=br 
persistents.show() 
max hold 
max fetch
persistents.show()