Turn_To_gPoly : モディファイヤ

Turn_To_gPoly - superclass: modifier; super-superclass:MAXWrapper - 0:0 - classID: #(103372589, 1504512992)

値 > MAXWrapper > モディファイヤ > Turn_to_gPoly

モディファイヤクラス - クイックナビゲーション

このモディファイヤは、ジオメトリオブジェクトをモディファイヤスタックの gPoly クラスに変換します。

3ds Max 2013 以降で使用可能です。

コンストラクタ:

Turn_To_gPoly...
TurnTogPoly...

プロパティ:

プロパティは公開されていません。

次のスクリプトは、移動および変更するティーポットプリミティブを持つ単純なシーンを作成します。再生時間は gPoly 変換なしで測定され、その後、Turn_To_gPoly モディファイヤが基本オブジェクトとベンドモディファイヤの間に挿入され、再度時間が測定されます。このスクリプトは、両方の実行の時間およびFPS、および速度上昇比をリスナーに出力します。

gPoly ベンチマーク

(
resetMaxFile #noprompt	
theObj = teapot segs:64
theBend = bend()
addModifier theObj theBend
with animate on (
	at time 50 theObj.pos = [50,0,10]
	at time 100 (
		theObj.pos = [100,0,0]
		theObj.rotation = eulerangles 90 0 0
		theBend.angle = 90
	)
)

theStart = animationrange.start
theEnd = animationrange.end 
theLength = theEnd - theStart + 1

st = timestamp()
for i = theStart to theEnd do sliderTime = i
theTime = ((timestamp()-st)/1000.0)
format "Teapot Primitive: % seconds (% FPS).\n" theTime (theLength/theTime)

addModifier theObj (turnTogPoly()) before:1
	
st = timestamp()
for i = animationrange.start to animationrange.end do sliderTime = i
theTime2 = ((timestamp()-st)/1000.0)
format "Teapot gPoly: % seconds (% FPS).\n" theTime2 (theLength/theTime2)

format "gPoly Speed Up: %x\n" (theTime/theTime2)
)

結果

Teapot Primitive: 29.074 seconds (3.4375f FPS).
Teapot gPoly: 12.769 seconds (7.83125f FPS).
gPoly Speed Up: 2.27692x
OK