rootScene System Global Variable

The rootScene is a system global variable that represents the Scene Root. It is available in 3ds Max 2011 and higher.

Its subAnims can be used to access various elements of the scene hierarchy including:

• Sound

• Video Post

• Global Tracks

• Biped

• Animation Layer Control Manager

• Schematic Material Editor

• Environment

• Render Effects

• Render Elements

• Renderers

• Global Shadow Parameters

• Scene Materials

• Medit Materials

• World

The rootScene is used by the Macro Recorder to emit script code relative to the scene root.

Below are some examples of accessing the rootScene and its subAnims:

rootScene
-->$<rootScene>
 
getsubanimnames rootScene
-->#(#Sound, #Video_Post, #Global_Tracks, #biped, #Anim_Layer_Control_Manager, #SME, #Environment, #Render_Effects, #Render_Elements, #renderer, #Global_Shadow_Parameters, 
-->#Scene_Materials, #Medit_Materials, #world)
 
w=rootscene[#world]
-->SubAnim:World
 
w.object
-->$<root>
 
classof rootScene
-->Scene
 
weaponDataCA = attributes weaponData
(
parameters main rollout:params
(
hitPoints type:#float ui:hits default:10
cost type:#float ui:cost default:100
sound type:#string
)
rollout params "Weapon Parameters"
(
spinner hits "Hit Points" type:#float
spinner cost "Cost" type:#float
dropdownlist sound_dd "Sound" items:#("boom", "sparkle", "zap", "fizzle")
on sound_dd selected i do sound = sound_dd.items[i]
)
)
CustAttributes.add rootnode weaponDataCA
CustAttributes.add rootscene weaponDataCA
createdialog rootnode.weapondata.params
--Playing with parameters generates clean macro recorder output
 
--Close dialog before running next line:
 
createdialog rootscene.weapondata.params
--Playing with parameters generates clean macro recorder output