例: ActiveX のメソッドが返したエラーをトラップする(AutoLISP/ActiveX)

vl-catch-all-apply 関数を使用することにより、ActiveX のメソッドが返したエラーをトラップし、プログラムをどのように継続すべきかを決定することができます。

注: AutoLISP での ActiveX のサポートは Windows のみに制限されています。

新しい AutoLISP ソースコードファイルを作成する

Visual LISP で、[ファイル] [ファイルを新規作成]をクリックします。
[ファイル] [名前を付けて保存]をクリックします。
[名前を付けて保存]ダイアログボックスで、
- 新しい AutoLISP ソースファイルの場所を指定します。
- [ファイル名]ボックスに、interceptActiveXErrors と入力します。
- [ファイルの種類]ドロップダウンリストで、[LISP ソースファイル]を選択します。
- [保存]をクリックします。

モデル空間に放射線オブジェクトを作成する

新しい Visual LISP テキストエディタウィンドウで、次のように入力します。

(defun init-motivate ()
  (vl-load-com)
  (setq mspace
    (vla-get-modelspace
      (vla-get-activedocument (vlax-get-acad-object))
    )
  )
  (vla-addray mspace (vlax-3d-point 0 0 0) (vlax-3d-point 1 1 0))
)

モデル空間に最後に追加されたオブジェクトの境界ボックスを取得する

Visual LISP テキストエディタウィンドウで、次のように入力します。

(defun bnddrop (/ bbox)
  (setq bbox (vla-getboundingbox
    (vla-item mspace (- 1 (vla-get-count mspace)))
      'll
      'ur
    )
  )
  (list "Do something with bounding box." bbox)
)

コードをロードして実行する

[ツール] [エディタ内のテキストをロード]をクリックします。
AutoCAD のコマンドプロンプトに対して (bnddrop) と入力します。
放射線は無限に延びているため、ボックスで囲むことはできません。このため、GetBoundingBox メソッドは次のエラーになります。
```
; error: Automation Error. Invalid extents
```
このコードをアプリケーションプログラムの一部にすると、この時点で実行が停止します。

vla-GetBoundingBox 関数によって作成されたエラーを取得する

Visual LISP テキストエディタウィンドウで、次のように入力します。
```
(defun bndcatch (/ bbox)
  (setq bbox (vl-catch-all-apply
    'vla-getboundingbox
      (list (vla-item mspace (- 1 (vla-get-count mspace)))
        'll
        'ur
      )
    )
  )
  (if (vl-catch-all-error-p bbox)
    (list "Exception: " (vl-catch-all-error-message bbox))
    (list "Do something with bounding box." bbox)
  )
)
```
この関数は、vl-catch-all-apply 関数を使用して vla-getboundingbox 関数を呼び出します。vl-catch-all-apply 関数には 2 つの引数を指定します。1 つは ('vla-getboundingbox) を呼び出す関数の名前を指定するシンボルで、もう 1 つは vla-getboundingbox 関数に渡される引数のリストです。GetBoundingBox メソッドが正常に終了すると、vl-catch-all-apply 関数が戻り値を変数 bbox に格納します。呼び出しに失敗すると、vl-catch-all-apply 関数が bbox にエラーオブジェクトを格納します。

vl-catch-all-error-p 関数の呼び出しは、vl-catch-all-apply 関数からの戻り値をチェックして、それがエラーオブジェクトである場合は T を返し、エラーオブジェクトでない場合は nil を返します。この例でのように戻り値がエラーオブジェクトの場合、関数は vl‑catch‑all‑error‑message 関数を呼び出してエラーオブジェクトからメッセージを取得します。この時点からプログラムが続けて実行されます。