rootScene システム グローバル変数

rootScene は、 シーン ルートを表すシステム グローバル変数です。3ds Max 2011 以降で使用可能です。

その subAnims は次のシーンの階層のさまざまな要素にアクセス可能です。

• サウンド

• ビデオ ポスト

• グローバル トラック

• Biped:

• アニメーション レイヤ コントロール マネージャ

• スケマティク マテリアル エディタ

• 環境

• レンダリング効果

• レンダリング要素

• レンダラー

• グローバル シャドウ パラメータ

• シーン マテリアル

• マテリアル エディタ マテリアル

• ワールド

マクロ レコーダにより rootScene が使用され、シーン ルートに相対的なスクリプト コードを発行します。

以下は、rootScene およびその subAnims へのアクセスの例です。

rootScene
-->$<rootScene>
 
getsubanimnames rootScene
-->#(#Sound, #Video_Post, #Global_Tracks, #biped, #Anim_Layer_Control_Manager, #SME, #Environment, #Render_Effects, #Render_Elements, #renderer, #Global_Shadow_Parameters, 
-->#Scene_Materials, #Medit_Materials, #world)
 
w=rootscene[#world]
-->SubAnim:World
 
w.object
-->$<root>
 
classof rootScene
-->Scene
 
weaponDataCA = attributes weaponData
(
parameters main rollout:params
(
hitPoints type:#float ui:hits default:10
cost type:#float ui:cost default:100
sound type:#string
)
rollout params "Weapon Parameters"
(
spinner hits "Hit Points" type:#float
spinner cost "Cost" type:#float
dropdownlist sound_dd "Sound" items:#("boom", "sparkle", "zap", "fizzle")
on sound_dd selected i do sound = sound_dd.items[i]
)
)
CustAttributes.add rootnode weaponDataCA
CustAttributes.add rootscene weaponDataCA
createdialog rootnode.weapondata.params
--Playing with parameters generates clean macro recorder output
 
--Close dialog before running next line:
 
createdialog rootscene.weapondata.params
--Playing with parameters generates clean macro recorder output