Particle_View : ヘルパー

Particle_View - superclass: helper super-superclass:node - classID: #(1962490631, 515064576)

値 > MAXWrapper > ノード > ヘルパー > Particle_View

パーティクルフロークイックナビゲーション

説明:

この内部クラスのインスタンスはパーティクルフローによって作成され、 particleFlow.OpenParticleView() メソッドによって返されます。これらのインスタンスは[パーティクルビュー](Particle View)ユーザインタフェースを表します。詳細については、「particleFlow グローバルインタフェース」を参照してください。

コンストラクタ:

Not creatable by MAXScript

プロパティ:

<Particle_View>.origin Point3

スクリーンピクセル座標におけるパーティクルビューの原点を、デスクトップの左上隅を基準に取得/設定します。

<Particle_View>.width Integer

パーティクルビューの幅をピクセル単位で取得/設定します。

<Particle_View>.height Integer

パーティクルビューの高さをピクセル単位で取得/設定します。

<Particle_View>.divider Point3

パーティクルビューの分割場所を取得/設定します。

<Particle_View>.selected Node Array

パーティクルビュー内で選択したノードの配列を取得/設定します。

<Particle_View>.Show_Parameters Boolean default:true

パーティクルビューの右側の[パラメータ](Parameters)パネルの表示/非表示をコントロールします。

<Particle_View>.Show_Action_Depot Boolean default:true

パーティクルビューの下部のアクションコンテナの表示/非表示をコントロールします。

<Particle_View>.Show_Action_Description Boolean default:true

パーティクルビューの右下隅のアクション説明の表示/非表示をコントロールします。

<Particle_View>.show_Particle_Count Integer default: 0

1 の場合、パーティクル数が表示されます。[パーティクルビュー](Particle View) > [オプション](Options) > [経過を更新](Track Update) > [パーティクル数](Particle Count)メニュー項目のチェック済みの状態をコントロールします。

<Particle_View>.show_Action_Update Integer default: 0

1 の場合、アクション更新が表示されます。[パーティクルビュー](Particle View) > [オプション](Options) > [経過を更新](Track Update) > [進行を更新](Update Progress)メニュー項目のチェック済みの状態をコントロールします。

<Particle_View>.use_Dynamic_Names Integer default: 1

1 の場合、パーティクルビューはダイナミック名を使用します。[パーティクルビュー](Particle View) > [オプション](Options) > [ダイナミックを使用](Use Dynamic Names)メニュー項目のチェック済みの状態をコントロールします。

例と結果:

--Open a Particle View
pv = particleFlow.openParticleView()
--> $Particle_View:Particle View 001 @ [0.000000,0.000000,0.000000]
 
pv.name--since it is a helper, it has all node properties
--> "Particle View 001"
 
pv.Origin
--> [9,77,0]
pv.Origin = [100,0,0]
--> [100,0,0]
pv.Origin = [0,0,0]
--> [0,0,0]
 
--Get the current size of the Particle View
pv.Width
--> 549
pv.Height
--> 852
--Set the size of the Particle View to 800 x 600
pv.Width = 800
--> 800
pv.Height = 600
--> 600
 
pv.Divider
--> [1,261,0]
--Move the divider down to set Depot height to 100 pixels
pv.Divider = [1,100,0]
--> [1,100,0]
 
pv.Show_Particle_Count
--> 0
pv.Show_Particle_Count = 1
--> 1
 
pv.Show_Action_Update
--> 0
pv.Show_Action_Update = 1
--> 1
 
pv.Use_Dynamic_Names
--> 1
pv.Use_Dynamic_Names = 0
-->0

次の MacroScript は、デスクトップの右半分にパーティクルビューを表示します。単一のデスクトップにデュアルモニタをセットアップしている場合、右側のモニタにパーティクルビューを表示します。

スクリプト:

macroScript PView_TwoMonitors
category: "Particle View"
buttontext: "PView Half"
tooltip: "Open Particle View on Right Half of Desktop"
(
-- open Particle View, get the Particle View object
pv =ParticleFlow.openParticleView()
 
-- get desktop size
winsize = getMaxWindowSize()
 
-- set Origin of PView to half desktop width and 0 height
pv.origin = [winsize.x/2, 0,0]
-- set Width to half desktop width
pv.width = winsize.x/2
-- set Height to full desktop height
pv.height = winsize.y
)

Particle_View : ヘルパー

関連事項