Alembic_Export : ExporterPlugin

Exposes the Alembic Exporter plugin to MAXScript. Available in 3ds Max 2016 and higher.

Constructor

Class instances not creatable by MAXScript.

Aliases:

Alembic_Export
AlembicExport

Alembic_Export interfaces:

Interface: AlembicExport

Properties:

 AlembicExport.CoordinateSystem : enum : Read|Write
CoordinateSystem enums: {#Max|#Maya}

Sets the coordinate system of the exported Alembic file.

Possible values are:

#Max (default) - Z-up, right-handed coordinate system used by Autodesk 3dsMax
#Maya - Y-up, right-handed coordinate system used by Autodesk Maya

 AlembicExport.ArchiveType : enum : Read|Write
ArchiveType enums: {#HDF5|#Ogawa}

Sets the archive type of the exported Alembic file.

Possible values are:

#HDF5 (default) - the original storage format of Alembic version 1.0
#Ogawa - the improved storage format introduced in Alembic version 1.5

 AlembicExport.ParticleAsMesh : bool : Read|Write

Sets whether particle shapes are exported as meshes.

 AlembicExport.CacheTimeRange : enum : Read|Write
   CacheTimeRange enums: {#CurrentFrame|#TimeSlider|#StartEnd}

Sets how the animation is saved.

Possible values are:

#CurrentFrame (default) - saves the current frame.
#TimeSlider - saves the active time segments on the time slider.
#StartEnd - saves a range specified by the Step

 AlembicExport.StepFrameTime : float : Read|Write

Sets the frame sample rate, which by default is every 1.0 frames. This setting only affects CacheTimeRange types of #TimeSlider and #StartEnd.

 AlembicExport.StartFrameTime : integer : Read|Write

Sets the start frame for an animation range, when CacheTimeRange is #StartEnd.

 AlembicExport.EndFrameTime : integer : Read|Write

Sets the end frame for an animation range, when CacheTimeRange is #StartEnd.

 AlembicExport.ShapeName : bool : Read|Write

When set to true, appends the string "Shape" to the name of each exported mesh. This property is set to false by default.

Methods:

No methods exposed.

Actions:

No actions exposed.

EXAMPLE

resetMaxFile #noprompt --reset the scene
c = cone() --create a Cone primitive
b = bend() --create a Bend modifier
addModifier c b --add the Bend to the Cone
with animate on (--enable animation
  at time 100 ( --and set on frame 100
    b.angle = 90 --the Bend Angle to 90
    c.pos = [10,20,30] --and move the Cone
  )--end time context
)--end animate on context
AlembicExport.ArchiveType = #hdf5 --force the old file format
AlembicExport.CoordinateSystem = #max --force Z up coordinates
--Export the file without opening the dialog
--The explicit using: argument is not necessary as the export plugin 
--needed will be resolved automatically based on the file extension:
exportFile (GetDir #export +"\\alembictest_hdm5_max.abc") #noPrompt using:AlembicExport

AlembicExport.ArchiveType = #ogawa --force the new file format
AlembicExport.CoordinateSystem = #maya --force Y up coordinates
--Export the file without opening the dialog
--This time we will ommit the explicit using: argument:
exportFile (GetDir #export +"\\alembictest_ogawa_maya.abc") #noPrompt

--RESULT: We now have two files, one using Max Z up and HDF5 storage, 
--and one using Maya Y up and the newer Ogawa storage.

--See the AlembicImport:ImporterPlugin topic for an example
--of importing these files back into 3ds Max.

Alembic_Export : ExporterPlugin

See Also