acet-layerp-mark (AutoLISP)

画層復元のために開始マークと終了マークをつけます。

サポートされているプラットフォーム: Windows および Mac OS

構文と要素

(acet-layerp-mark [status])

status

タイプ: T または nil

T -- 開始マークを設定します。

nil -- 終了マークを設定し、開始マークをクリアします。

戻り値

タイプ: T または nil

開始マークが有効な場合は T、それ以外の場合は nil。

status を省略すると、acet-layerp-mark 関数は画層設定の現在のマークの状態を返します。

注意

acet-layerp-mark 関数は複数の LAYER[画層管理]コマンドを 1 つのトランザクションにグループ化できます。したがって、1 回の AutoCAD LAYERP[画層復元]コマンドによって元に戻すことができます。マークを設定するには、LAYERPMODE の設定がオンである必要があります。

例

次のコードは、画層 0 を青にし、開始マークと終了マークの設定している間に、いくつかの追加の画層を作成します。このコードの終了後に、AutoCAD の LAYERP[画層復元]コマンドを実行すると、画層 0 は青に戻ります。

(defun TestLayerP ()
  ;; Turn LAYERPMODE on, if it is not already
  (if (not (acet-layerp-mode))
    (acet-layerp-mode T)
  )

  ;; Set layer 0 to the color blue
  (command "._layer" "_color" "blue" "0" "")

  ;; Set a begin mark
  (acet-layerp-mark T)

  ;; Issue a series of layer commands, and then set an end mark
  (command "._layer" "_color" "green" "0" "")
  (command "._layer" "_thaw" "*" "")
  (command "._layer" "_unlock" "*" "")
  (command "._layer" "_ltype" "hidden" "0" "")
  (command "._layer" "_color" "red" "0" "")

  ;; Set an end mark
  (acet-layerp-mark nil)
 (princ)
)