MaxLiquid: GeometryClass

MaxLiquid - superclass: GeometryClass; super-superclass:node - 28:0 - classID: #(712128612L, 2137014116L)

3ds Max 2018.3 の新機能。液体クラスには、シミュレーション内の液体と相互作用する他のオブジェクト(コライダやキル平面など)への参照を含む流体シミュレーションの設定パラメータが含まれます。

値 > MAXWrapper > ノード > GeometryClass > MaxLiquid

 

   

ジオメトリ オブジェクト - クイック ナビゲーション

コンストラクタ 

MaxLiquid...
例 
-- Max fluid scene set up
resetmaxFile #noPrompt
p = plane()

b = box width:70 length:70 height:20
convertto b editable_poly

subobjectlevel = 4
b.SetSelection #Face #{2}
b.delete #face
addmodifier b (shell outerAmount:3.0)

liquid = maxLiquid pos:[0,0,50]
-- don't do this:
-- append liquid.collider_Meshes b
-- append liquid.killplanes p
liquid.AddCollider b
liquid.AddKillPlane p

-- create a new solver for the liquid and set the master voxel size
liquid.CreateSolver 1
solver = liquid.solvers[1]
solver.masterVoxelSize = 4.0

-- Turn on override for the first collider:
solver.colliderConversionOverrideTab[1] = true
-- Set thickness for the collider
solver.colliderConversionOverrideThicknessTab[1] = 5.0

プロパティ: 

<MaxLiquid>.accelerator_Meshes     ArrayParameter    default: #()   --  node array; SubAnim

将来の使用のために予約されています。 

<MaxLiquid>.cacheOutputFilePattern     String    default: "<ProjectName>\SimCache\<ObjectName>\<SolverName>\"   --  string

将来の使用のために予約されています。 

<MaxLiquid>.collider_Meshes     ArrayParameter    default: #()   --  node array; SubAnim

シミュレーション内の液体とともにコライダとして動作するシーン ノードの配列。

注: この配列は読み取り専用で、直接操作することはできません。コライダ メッシュを操作するには、コライダの Add/Get/Delete メソッドを使用します(以下を参照)。 

<MaxLiquid>.emitter_Meshes     ArrayParameter    default: #()   --  node array; SubAnim

液体エミッタとして動作するシーン ノードの配列。この配列は、エミッタ アイコン タイプが「カスタム」の場合にのみ使用されます。

注: この配列は読み取り専用で、直接操作することはできません。エミッタ メッシュを操作するには、エミッタの Add/Get/Delete メソッドを使用します(以下を参照)。 

<MaxLiquid>.emitterType     Integer    default: 0   --  integer

エミッタ アイコンのタイプ、ここで: 

<MaxLiquid>.emitterHeight     Float    default: 5.0   --  animatable; float
<MaxLiquid>.emitterLength     Float    default: 5.0   --  animatable; float
<MaxLiquid>.emitterWidth     Float    default: 5.0   --  animatable; float

ボックスの場合は、エミッタの高さ、長さ、および幅。球の場合、emitterLength は半径。エミッタが平面の場合は、幅と長さのパラメータのみが使用されます。 

<MaxLiquid>.exportPRTFiles     BooleanClass    default: false   --  Boolean

計算の実行時にボクセルを PRT ファイルとして書き出すかどうかを示します。 

<MaxLiquid>.field_Meshes     ArrayParameter    default: #()   --  node array; SubAnim

モーション フィールドとして動作するシーン ノードの配列。

注: この配列は読み取り専用で、直接操作することはできません。モーション フィールドを操作するには、モーション フィールドの Add/Get/Delete メソッドを使用します(以下を参照)。 

<MaxLiquid>.foammask_Meshes     ArrayParameter    default: #()   --  node array; SubAnim

泡マスクとして動作するシーン ノードの配列。

注: この配列は読み取り専用で、直接操作することはできません。泡マスクを操作するには、泡マスクの Add/Get/Delete メソッドを使用します(以下を参照)。 

<MaxLiquid>.guide_Meshes     ArrayParameter    default: #()   --  node array; SubAnim

ガイド メッシュとして動作するシーン ノードの配列。

注: この配列は読み取り専用で、直接操作することはできません。ガイド メッシュを操作するには、ガイド メッシュの Add/Get/Delete メソッドを使用します(以下を参照)。 

<MaxLiquid>.guideEmitter_Meshes     ArrayParameter    default: #()   --  node array; SubAnim

ガイド エミッタとして動作するシーン ノードの配列。

注: この配列は読み取り専用で、直接操作することはできません。ガイド エミッタ メッシュを操作するには、ガイド エミッタの Add/Get/Delete メソッドを使用します(以下を参照)。 

<MaxLiquid>.iconSize     Float    default: 10.0   --  float

ビューポート内の液体アイコンのサイズ。この単位は、シーンの単位に関係なく常にインチです。 

<MaxLiquid>.killplanes     ArrayParameter    default: #()   --  node array; SubAnim

シミュレーション内のキル平面として動作するシーン ノードの配列。

注: この配列は読み取り専用で、直接操作することはできません。キル平面を操作するには、キル平面の Add/Get/Delete メソッドを使用します(以下を参照)。 

<MaxLiquid>.killVolumeNode     UndefinedClass    default: undefined   --  node

将来のために予約されています。 

<MaxLiquid>.lastSelectedSolverIndex     Integer    default: 1   --  integer

ユーザが最後に選択した計算のソルバ配列のインデックスが含まれます。 

<MaxLiquid>.maxScratchCacheRAM     Float    default: 1.0   --  float

将来の使用のために予約されています。 

<MaxLiquid>.renderSolveIndex     Integer    default: 1   --  integer

最後にレンダリングされたソルバ リストのソルバのインデックスが含まれます。 

<MaxLiquid>.renderSolveLock     BooleanClass    default: false   --  Boolean

レンダリング ロック ボタンの状態を取得または設定します。true の場合は、選択した計算がロックされていることを示します。 

<MaxLiquid>.rootSimDirectory     String    default: "c:\MaxFluidSim\"   --  string

キャッシュ ファイルが保存されているルート フォルダが含まれます。 

<MaxLiquid>.scratchCache     String    default: "c:\MaxFluidScratchCache\"   --  string

将来の使用のために予約されています。 

<MaxLiquid>.showVoxelGrid     BooleanClass    default: true   --  Boolean

ビューポート内のボクセル サイズのビジュアル表現を表示するかどうかを示します。 

<MaxLiquid>.solvers     ArrayParameter    default: #()   --  maxObject array; SubAnim

液体のソルバ オブジェクトの配列。 

<MaxLiquid>.useProjectFolders     BooleanClass    default: false   --  Boolean

ソルバのキャッシュ ファイルを保存するために、rootSimDirectory の代わりに Max プロジェクト フォルダを使用するかどうかを示します。

MaxLiquid インタフェース

インタフェース: MaxFluidLiquidObject

プロパティ:

メソッド: 

    <boolean>CreateSolver <&index>solverIndex
       solverIndex is Out parameter

液体のソルバ配列に新しいソルバを作成し、新規作成されたソルバのインデックスを返します。 

    <boolean>CloneSolver <index>index <&TSTR>cloneName <&index>cloneIndex
       cloneName is Out parameter
       cloneIndex is Out parameter

インデックスで指定されたソルバの新しい複製されたコピーを作成し、新しい名前とインデックスを返します。 

    <boolean>DeleteSolver <index>index

インデックスで指定されたソルバを削除します。 

    <integer>NumberSolvers()

ソルバ配列内のソルバの数を返します。 

    <index>AddEmitter <node>node
    <integer>GetNumberEmitters()
    <node>GetEmitter <index>index
    <boolean>DeleteEmitter <index>index

液体の emitter_Meshes 配列に格納されているエミッタのコレクションを操作します。 

    <index>AddCollider <node>node
    <integer>GetNumberColliders()
    <node>GetCollider <index>index
    <boolean>DeleteCollider <index>index

液体の collider_Meshes 配列に格納されているコライダのコレクションを操作します。 

    <index>AddKillPlane <node>node
    <integer>GetNumberKillPlanes()
    <node>GetKillPlane <index>index
    <boolean>DeleteKillPlane <index>index

液体の killplanes 配列に格納されているキル平面のコレクションを操作します。 

    <index>AddFoamMask <node>node
    <integer>GetNumberFoamMasks()
    <node>GetFoamMask <index>index
    <boolean>DeleteFoamMask <index>index

液体の foammask_Meshes 配列に格納されている泡マスクのコレクションを操作します。 

    <index>AddGuideEmitter <node>node
    <integer>GetNumberGuideEmitters()
    <node>GetGuideEmitter <index>index
    <boolean>DeleteGuideEmitter <index>index

液体の guideEmitter_Meshes 配列に格納されているガイド エミッタのコレクションを操作します。 

    <index>AddMotionField <node>node
    <integer>GetNumberMotionFields()
    <node>GetMotionField <index>index
    <boolean>DeleteMotionField <index>index

液体の field_Meshes 配列に格納されているモーション フィールドのコレクションを操作します。

アクション:

このトピックについてのコメントをお送りください

Creative Commons License 特に明記されている場合以外は、この作業は、Creative Commons 表示 - 非営利 - 継承 3.0 非移植ライセンス のもと認可を受けています。 Autodesk Creative Commons FAQ (英語版) を参照してください。