Časté dotazy: Jak lze znovu uložit projekt nebo složku výkresových souborů do aktuální verze?

Projekt nebo adresář výkresových souborů z dřívější verze můžete uložit do aktuální verze pomocí dávkového souboru.

Přeuložení výkresových souborů, uložených v předchozích verzích AutoCAD Architecture 2022 toolset, můžete pomocí dávkového souboru zautomatizovat.

Při spuštění dávkového souboru se vytvoří úplná kopie projektu nebo složky obsahující výkresy předchozí verze. Poté jsou rekurzivně vyhledány všechny soubory DWG, DWT a DWS obsažené v tomto umístění a je vygenerován soubor skriptu.

Jakmile spustíte soubor skriptu, proběhne otevření, uložení a zavření všech zkopírovaných souborů DWG a DWT. Výsledkem je, že jsou všechny soubory DWG a DWT nově uloženy v aktuální verzi.

Skript zobrazí cesty k souborům DWS, které je nutné otevřít a uložit do aktuální verze ručně.

Důležité: Ujistěte se, že jste před spuštěním dávkového souboru nebo souboru skriptu vytvořili zálohu všech souborů. Pokud jste projekt zkopírovali do nového umístění, změňte před spuštěním dávkového souboru cestu projektu pomocí původní AutoCAD Architecture 2022 toolset.

Import souborů do aktuální verze pomocí dávkového souboru

Důležité: Dbejte na to, abyste postupovali přesně podle uvedených kroků.

Spusťte aplikaci Microsoft® Poznámkový blok.
Zkopírujte text (dávkový soubor) mezi dvěma čárkovanými čarami a vložte jej do aplikace Poznámkový blok.
Uložte soubor pod názvem převod.bat a zavřete aplikaci Poznámkový blok.

Na® příkazovém řádku systému Windows spusťte soubor převod.bat pomocí následující syntaxe:

promote.bat [projectName] [projectLocation] [scriptName] [promotionTarget] 
Replace [projectName] with the name of the original folder containing the drawings to be imported to the current version. 
Replace [projectLocation] with the path to the original folder entered as [projectName]. 
Replace [scriptName] with the name of the script that will be generated. The root of the file name can be customized but the file extension must always be .scr. 
Replace [promotionTarget] with a path and folder name of the location where the imported drawings must be copied.

Poznámka: Argumenty obsahující mezery musí být uzavřeny do uvozovek. Pokud jste například výkresy uložené v předchozích verzích uložili ve složce R:\CAD_Files\Projects\2010\Hospital a chcete, aby byly nově uložené soubory vytvořeny ve složce R:\CAD_Files\Projects\2014\Hospital, pak použijte následující syntaxi:

promote.bat Hospital R:\CAD_Files\Projects\2010\ promote.scr R:\CAD_Files\Projects\2014

Po dokončení se ve stejné složce, kde je uložen soubor převod.bat, vytvoří soubor skriptu s názvem, který jste zadali. Spuštěním tohoto souboru skriptu se všechny zkopírované výkresy, které jsou uloženy v umístění [cílovéUmístěníPřevodu], automaticky uloží do aktuální verze.

Dávkový soubor

--------------------------------------------------------------------------------------------
@echo off
SETLOCAL
@rem promote.bat
@rem This script promotes a project to the current DWG format.
:Greeting
echo.
echo This script promotes a project to the current DWG format.
echo For best results, please run this script using administrator privileges in Windows.
echo.
PAUSE
:checkCmdArgs
if [%4] EQU [] goto :badArgCount
if [%3] EQU [] goto :badArgCount
if [%2] EQU [] goto :badArgCount
if [%1] EQU [] goto :badArgCount
if [%5] NEQ [] goto :badArgCount
set prjName=%1
set prjDir=%2
set scrName=%3
set targetDir=%4
goto :checkProject
:getProject
set /P prjName="What is the name of the project?: "
set /P prjDir="Where can it be found?: "
goto :checkProject
:checkProject
set prjNameEsc=%prjName:&=^&%
set firstChar=%prjName:~0,1%
if ^%firstChar% EQU ^" set prjName=%prjNameEsc:~1,-1%
set prjNameDisplay=%prjName:&=^^^&%
set prjDirEsc=%prjDir:&=^&%
set firstChar=%prjDir:~0,1%
if ^%firstChar% EQU ^" set prjDir=%prjDirEsc:~1,-1%
set prjDirDisplay=%prjDir:&=^^^&%
set project="%prjDir%\%prjName%"
if not exist %project% goto :noProject
if not defined scrName (goto :getScript) else (goto :checkScript)
:getScript
set /P scrName="Specify a name for the ACAD script: "
goto :checkScript
:checkScript
set scrNameEsc=%scrName:&=^&%
set firstChar=%scrName:~0,1%
if ^%firstChar% EQU ^" set scrName=%scrNameEsc:~1,-1%
set scrExt=%scrName:~-4%
if /I "%scrExt%" NEQ ".scr" set scrName=%scrName%.scr
set scrNameDisplay=%scrName:&=^^^&%
if exist "%scrName%" goto :scrFound
if not defined targetDir (goto :getTarget) else (goto :checkTarget)
:getTarget
set /P targetDir="Specify a directory to host the promoted project: "
goto :checkTarget
:checkTarget
set targetDirEsc=%targetDir:&=^&%
set firstChar=%targetDir:~0,1%
if ^%firstChar% EQU ^" set targetDir=%targetDirEsc:~1,-1%
set targetDirDisplay=%targetDir:&=^^^&%
set prjDest="%targetDir%\%prjName%"
if not exist "%targetDir%" (
md "%targetDir%"
echo.
echo Created target directory %targetDirDisplay%
goto :copyProject
) else (
if exist %prjDest% (goto :targetFound) else (goto :copyProject)
)
ENDLOCAL
exit /B
:badArgCount
echo.
echo This utility can be run as a single command with the following syntax:
echo.
echo promote.bat [projectName] [projectLocation] [scriptName] [promotionTarget].
echo.
goto :getProject
:noProject
echo.
echo You have specified a project %prjNameDisplay% in the directory %prjDirDisplay%.
echo This could not be found. Please try again.
echo.
goto :getProject
:badScrExt
echo.
echo Your Autocad script must have the extension ".scr" and you specified %scrNameDisplay%.
echo Please try again.
echo.
goto :getScript
:scrFound
echo.
echo An Autocad script with the name %scrNameDisplay% is already present in the working directory.
echo Delete this script or specify a different script name.
echo.
goto :getScript
:targetFound
echo.
echo A project with name %prjNameDisplay% was found in the target area %targetDirDisplay%.
echo Delete this project or specify another target area.
echo.
goto :getTarget
:copyProject
echo.
CLS
echo Copying project %prjNameDisplay%...
xcopy %project% %prjDest% /E /I /Q /H
attrib -A -R %prjDest% /D /S
echo Copied project %prjNameDisplay% to %prjDest%.
echo.
goto :genScript
:genScript
echo.
set count=0
@for /R %prjDest% %%i in (*.dwg) do (
set /a count+=1
echo _open "%%i">>"%scrName%"
echo _qsave>>"%scrName%"
echo _close>>"%scrName%"
)
echo Found %count% DWG files to be updated in the project %prjNameDisplay%.
set /a totalFiles=%count%
set count=0
@for /R %prjDest% %%i in (*.dwt) do (
set /a count+=1
echo _open "%%i">>"%scrName%"
echo _qsave>>"%scrName%"
echo _close>>"%scrName%"
)
echo Found %count% DWT files to be updated in the project %prjNameDisplay%.
echo.
set /a totalFiles=%totalFiles%+%count%
if %totalFiles% == 0 (
echo.
echo No DWG or DWT files were found in the project %prjName%!
echo There is nothing to promote.
echo.
echo Deleting the copy of %prjName% from %targetDir%.
echo The directory %targetDir% has been retained in case other folders or files are present.
echo.
RMDIR /Q/S %prjDest%
) else (
echo.
echo TO COMPLETE THE PROMOTION:
echo.
echo [1] Start ADT and make sure that a project is NOT currently active.
echo [2] Disable the previous version courtesy dialog using the AecFileOpenMessage command.
echo [3] Verify that the copy of the project located at %targetDirDisplay% has the same
echo file count as the original copy located at %prjDirDisplay%.
echo [4] Run the script %scrNameDisplay%.
@for /R %prjDest% %%i in (*.dws) do (
set /a foundDWS=1
goto :break
)
:break
if DEFINED foundDWS (
echo [5] Resave the following DWS file^(s^), making sure to preserve filenames.
echo ^(These cannot be promoted via a script as DWT and DWG files can.^)
echo.
@for /R %prjDest% %%i in (*.dws) do (
echo %%i
)
)
echo.
echo.
echo The project %prjNameDisplay% located in %targetDirDisplay% will then be promoted
echo to the current file format.
echo.
echo After this process is complete you may use this project
echo where it currently resides, or replace the old one with this new copy.
echo.
)
ENDLOCAL
exit /B
------------------------------------------------------------------------------------------------------

Řešení potíží

Pokud se během použití tohoto skriptu při otevření výkresu v předchozí verzi zobrazí dialog, skript je ukončen. Chcete-li pokračovat v uložení zbývajících výkresů do aktuální verze:

Upravte soubor skriptu a odstraňte všechny odkazy až po poslední výkres z předchozí verze, který byl úspěšně uložen.
Zjistěte důvod neočekávaného zobrazení dialogu a proveďte nezbytná opatření, která zabrání jeho opětovnému zobrazení.
Spusťte upravený soubor skriptu. Zbývající zkopírované výkresy by měly být uloženy do aktuální verze.

Pokud je skript často předčasně ukončen kvůli neočekávanému zobrazení dialogu, zadejte na příkazovém řádku v AutoCAD Architecture 2022 toolset text AecFileOpenMessage a změňte hodnotu na Ne.

Důležité: Po dokončení procesu uložení obnovte hodnotu příkazu AecFileOpenMessage na Ano.

Časté dotazy: Jak lze znovu uložit projekt nebo složku výkresových souborů do aktuální verze?

Dávkový soubor

Řešení potíží

Související pojmy