SubRollout は RolloutControl のサブクラスです。すべてのロールアウト ユーザ インタフェース コントロールの共通プロパティとロールアウト ユーザ インタフェース コントロールの共通レイアウト パラメータが適用されます。

説明

ロールアウトを配置できる UI 項目。UI 項目のキャプションは表示されません。項目内のロールアウトの高さが項目の高さより大きい場合は、UI 項目の右側にスクロールバーが表示されます。

SubRollout の自動サイズ変更設定を上書きするには、SubRollout を作成するときに autoLayoutOnResize:<boolean> を指定します。これを指定しない場合は、親ロールアウトからこの設定が継承されます。3ds Max 2019 以降で使用可能です。 scrollBar: <on|off|#on|#off|#asNeeded> を使用してスクロールバーを設定することもできます。既定値は #asNeeded です。

プロパティ

.rollouts

AddSubRollout を使用して SubRollout コントロール内にインストールされたロールアウト(以下のノートを参照)。キュー内のジョブの数を返します。インストールされたロールアウトの名前は、読み込み専用プロパティとして表示されます。

共通 UI 項目のプロパティのノートは次のとおりです。

.caption

非表示。読み込み/書き込み。

.text

非表示。読み込み/書き込み。

.enabled

設定効果なし。常に true に設定。読み込み/書き込み。

.pos

ロールアウト内の UI 項目の位置。読み込み/書き込み。

.align

UI 項目の位置合わせ。作成専用プロパティ。

.offset

UI 項目のオフセット。作成専用プロパティ。

.width

サブロールアウトの幅を設定します。UI 項目のプロパティとしてアクセス可。

.height

サブロールアウトの高さを設定します。UI 項目のプロパティとしてアクセス可。

.across

UI 項目 across の数。作成専用パラメータ。

関連するメソッド

addSubRollout <subrollout> <rollout> [rolledUp:<boolean>]

ロールアウトをサブロールアウトに追加します。常に ok を返します。

removeSubRollout <subrollout> <rollout>

サブロールアウトからロールアウトを削除します。常に ok を返します。

例

    rollout test "test" height:200 autoLayoutOnResize:true scrollBar:#asNeeded
    (
      subrollout test1 "test1"
      subrollout test2 "test2"
    )
    rollout test1a "test1a"
    (
      spinner test1as "test1as"
    )
    rollout test1b "test1b"
    (
      spinner test1bs "test1bs"
    )
    createdialog test
    AddSubRollout test.test1 test1a
    AddSubRollout test.test1 test1b
    test.test1.height += 100
    test.test2.pos += [0,100]
    rollout test2a "test2a"
    (
      spinner test2as "test2as"
    )
    AddSubRollout test.test2 test2a
    test.test2.height += 50

subRollout の高さを変更しても、その下にある UI 項目の位置は変わりません。