Chamfer : Modifier

Chamfer - superclass: modifier; super-superclass:MAXWrapper - 20:0 - classID: #(858559760, 951800972)

The Chamfer Modifier allows procedural chamfer operations on polygon meshes, including an option for Quad Chamfer. Available in 3ds Max 2015 and higher.

In addition to this procedural modifier implementation, the new Quad Chamfer option is also available as a mode of the existing Chamfer operation in the Editable_Poly base object - see the properties .edgeChamferType , .edgeChamferTension and .edgeChamferInvert introduced in 3ds Max 2015.

Constructors:

Chamfer... 
ChamferMod...

Properties:

<Chamfer>.chamfertype     Integer    default: 0   --  integer

Get/set the state of the "Operation" radio buttons.

Possible values are:

0 - Quad Chamfer (default)

1 - Standard Chamfer

<Chamfer>.amount     worldUnits    default: 1.0   --  animatable; worldUnits

Get/set the "Amount" value in world units.

Default is 1.0.

<Chamfer>.segments     Integer    default: 1   --  animatable; integer

Get/set the "Segments" value.

Default is 1.

The spinner range in the User Interface is from 1 to 99.

Values higher than 99 can be set via MAXScript.

<Chamfer>.tension     Float    default: 1.0   --  animatable; float

Get/set the "Tension" value.

Possible values in the User Interface are between 0.0 and 1.0.

Values outside of this valid range can be set via MAXScript, but can lead to unexpected results.

<Chamfer>.openchamfer     BooleanClass    default: false   --  boolean; Open_Chamfer

Get/set the state of the "Open Chamfer" checkbox.

When set to False (default), new faces will be created from the selected chamfered edges.

When set to True, the new faces or the original faces will be removed depending on the value of the .invert property.

<Chamfer>.invert     BooleanClass    default: false   --  boolean

Get/set the state of the "Invert" checkbox.

Only used when .openchamfer is set to True.

When set to False (default), the new chamfer faces will be skipped to create opening in the mesh.

When srt to True, the rest of the object will be skipped, creating only the new chamfer faces.

<Chamfer>.limiteffect     BooleanClass    default: true   --  boolean

Get/set the state of the "Limit Effect" checkbox.

Available in 3ds Max 2016 and higher.

<Chamfer>.quadintersectionmode     BooleanClass    default: false   --  boolean

Get/set the state of the "Quad Intersection" checkbox.

Available in 3ds Max 2018 and higher.

<Chamfer>.selectionoption     Integer    default: 0   --  integer

Get/set the selection of the "Selection" drop-down list.

Possible values are:

0 - From Stack (default)

1 - Selected Edges

2 - Selected Faces Edges

3 - Selected Faces Borders

4 - Edge Verts Selected

5 - All Edges

6 - Selected Vertices

7 - All Vertices

<Chamfer>.smoothingoption     Integer    default: 0   --  integer

Get/set the selection of the "From Smoothing" drop-down list.

Possible values are:

0 - Off (default)

1 - Smoothed Edges

2 - Unsmoothed Edges

<Chamfer>.materialoption     Integer    default: 0   --  integer

Get/set the selection of the "From Material ID" drop-down list.

Possible values are:

0 - Off (default)

1 - Different Materials

2 - Same Materials

<Chamfer>.useminangle     BooleanClass    default: true   --  boolean

Get/set the state of the "Min. Angle" checkbox.

When set to True (default), the .minangle value will be used to define the beginning of the Smoothing Angle range.

When set to False, the min. angle will be assumed 0.0.

Available in 3ds Max 2016 and higher.

<Chamfer>.minangle     Float    default: 5.0   --  float

Get/set the "Min. Angle" value.

Defines the beginning of the Smoothing Angle range.

Used only when .useminangle is set to True.

Available in 3ds Max 2016 and higher.

<Chamfer>.usemaxangle     BooleanClass    default: false   --  boolean

Get/set the state of the "Max. Angle" checkbox.

When set to True (default), the .maxangle value will be used to define the end of the Smoothing angle range.

When set to False, the max. angle will be assumed 180.0.

Available in 3ds Max 2016 and higher.

<Chamfer>.maxangle     Float    default: 90.0   --  float

Get/set the "Max. Angle" value.

Defines the end of the Smoothing Angle range.

Used only when .usemaxangle is set to True.

Available in 3ds Max 2016 and higher.

<Chamfer>.setmaterial     BooleanClass    default: false   --  boolean

Get/set the state of the "Set Chamfer Material" checkbox.

When set to False (default), the newly created chamfer polygons will inherit the Material IDs of the adjacent polygons.

When set to True, the newly created chamfer polygons will be assigned the Material ID specified by the .materialid property below.

<Chamfer>.materialid     Integer    default: 1   --  integer

Get/set the value of the "Material ID" spinner.

This value is used when the .setmaterial property is set to True and defines the Material ID to assign to the newly created chamfer polygons.

<Chamfer>.smooth     BooleanClass    default: true   --  boolean

Get/set the state of the "Smooth" checkbox.

When set to True (default), the newly created chamfer polygons will be smoothed with the rest of the polygons according to the .smoothtype and .smooththreshold properties.

When set to False , the newly created chamfer polygons will inherit the Smoothing Groups of their neighbor polygon.

<Chamfer>.smoothtype     Integer    default: 0   --  integer

Get/set the state of the smooth type radio buttons.

Possible values are:

0 - Smooth Entire Object (default)

1 - Smooth Chamfers Only

<Chamfer>.smoothtoadjacent     BooleanClass    default: false   --  boolean

Get/set the state of the "Smooth to Adjacent" checkbox.

Available in 3ds Max 2016 and higher.

<Chamfer>.smooththreshold     Float    default: 30.0   --  float

Get/set the value of the "Threshold" spinner.

This value is used when the .smooth property is set to True.

When the angle between two polygons is below this value, the two polygons will receive the same smoothing group to produce a smooth edge.

<Chamfer>.miteringType : Integer    default: 1    -- integer

The mitering type for corners, where:

0 = Quad
1 = Uniform
4 = Tri

Available in 3ds Max 2020 and higher.

<Chamfer>.amountType : Integer    default: 0 -- integer

The Amount Type under Chamfer Options in the Chamfer Modifier UI, where:

0 = Fixed
1 = By Crease Weight
2 = Legacy
3 = By Weight

Available in 3ds Max 2020 and higher.

<Chamfer>.minAmount : worldUnits default: 0.0
<Chamfer>.maxAmount : worldUnits     default: 1.0

The minimum and maximum chamfer amount values, when the amountType is By Crease Weight.

Available in 3ds Max 2020 and higher.

<Chamfer>.addinset : boolean    default: false

Indicates whether to add an inset to the chamfer. This corresponds to the Inset checkbox in the Chamfer Modifier UI.

Available in 3ds Max 2020 and higher.

<Chamfer>.insetamount : float default: 0.5

The inset amount to apply, when addinset is true.

Available in 3ds Max 2020 and higher.

<Chamfer>.insetsegments : integer default: 0

The number of segments to apply to the inset, when addinset is true.

Available in 3ds Max 2020 and higher.

<Chamfer>.insetoffset : float    default: 0.0

The amount of offset to apply to the inset, when addinset is true.

Available in 3ds Max 2020 and higher.

<Chamfer>.forcePositiveOffset : boolean    default: false

For internal use only.

<Chamfer>.miterEndBias (EndBias) : float    default: 0.5

The end bias amount to apply when the corner options are Default or Uniform.

Available in 3ds Max 2020 and higher.

<Chamfer>.useConstantOffset : boolean    default: false

For internal use only.

<Chamfer>.depth : float    default: 0.5

Gets or sets the depth value when Amount Type is Fixed or By Crease Weight.

Available in 3ds Max 2020 and higher.

<Chamfer>.presetOptionsComboBox : integer

For internal use only.

<Chamfer>.biasEndPoints     BooleanClass    default: true   --  boolean

For internal use only.

<Chamfer>.depthType     Integer    default: 0   --  integer

Gets or sets the Depth Type option, where:

0 = Fixed
1 = By Weight

Available in 3ds Max 2020 and higher.

<Chamfer>.insetType     Integer    default: 0   --  integer

Gets or sets the Inset Type option, where:

0 = Face Inset
1 = Flow Loop

Available in 3ds Max 2020.1 Update and higher.

<Chamfer>.radiusBias     Float    default: 0.0   --  animatable; float

Gets or sets the Radius Bias, in the range of 0.0 to 1.0.

Available in 3ds Max 2020.1 Update and higher.

<Chamfer>.scale     Float    default: 1.0   --  animatable; float

Gets or sets the Scale option, which has an effect when .amountType = 3, "By Weight".

Available in 3ds Max 2020.1 Update and higher.

Interfaces:

Interface: ChamferModifier

Methods:

<boolean>SetVersion <enum>version
       version enums: {#Ver2015|#Ver2016|#Ver2018|#Ver2020|#Ver2020_1}

Sets the options available on the modifier to match those available in the specified version. When called, re-evaluates the chamfer modifier based on the capabilities of the specified version. This is to provide backward compatibility.

Available in 3ds Max 2020 and higher.

EXAMPLE

   b = box()  --create a default Box
   c = chamfer() --create a Chamfer modifier
   addModifier b c --add the Chamfer to the Box
   c.amount = 5.0 --set the Amount to 5.0
   c.segments = 5 --set the Segments to 5
   c.tension = 0.5 --set the Tension to 0.5 to curve the new faces
   c.openChamfer = true --remove the new faces
   c.Invert = true --invert to remove the old faces instead
   s = shell() --create a Shell modifier
   s.outerAmount = 4.0 --set its Outer Amount (Thickness) to 4.0
   addModifier b s --add the Shell modifier to the Box above the Chamfer modifier

RESULT:

 ![](../../../../../images/GUID-60F91FF0-2B35-4FA4-946E-F8B4FD8DBFB4-low.png)

EXAMPLE

   b = box()  --create a default Box
   c = chamfer() --create a Chamfer modifier
   addModifier b c --add the Chamfer to the Box
   c.amount = 2.0 --set the Amount to 2.0
   c.segments = 2 --set the Segments to 2
   c.tension = 0.0 --set the Tension to 0.0 to add new edges without changing the existing shape
   t = turboSmooth() --create a TurboSmooth modifier
   addModifier b t --add the TurboSmooth modifier to the Box
   --Try turning off the Chamfer modifier to see the difference (second image)...

RESULTS:

 ![](../../../../../images/GUID-EE649D62-A589-482B-B36D-D7F8723E8C1B-low.png) ![](../../../../../images/GUID-3BAD7726-6C02-4B72-B6F4-8E6FEA3C55EE-low.png)