3ds Max 2024.2 Update の新機能: コンフォーム モディファイヤ機能を MAXScript に公開します。

Conformmodifier(Conform) : modifier {b00,57da4442}

コンストラクタ

ConformModifier ...

例

-- conform example

resetMaxFile #noprompt
b = box width:100 length:100 height:5
t = teapot pos:[0,0,4]
c = ConformModifier()
addModifier t c
c.appendTarget b
c.method = 1 -- shrink wrap
c.shrinkDirection = 4 -- closest point
c.strength = 50 -- 50%
el = Ellipse length:100 width:80
pc = Path_Constraint()
t.position.controller = pc
pc.path = el
playAnimation ()

プロパティ

<Conformmodifier>.AdoptNormal     Float    default: 0.0   --  animatable; float

採用するターゲット法線の割合を取得/設定します。

<Conformmodifier>.ApplyToWholeObject     BooleanClass    default: false   --  boolean

スタック選択に関係なく、すべての頂点にモディファイヤを適用するかどうかを取得/設定します。

<Conformmodifier>.axisDirection     Integer    default: 2   --  integer

投影方法が「ボリューム」の場合、軸方向を指定します。値は次のとおりです。

• 0 = X
• 1 = Y
• 2 = Z

<Conformmodifier>.axisSign     Integer    default: 0   --  integer

軸の方向の記号です。値は次のとおりです。

• 0 = 負
• 1 = 正
• 2 = 最も近い

<Conformmodifier>.BetterNormals     BooleanClass    default: true   --  boolean

true の場合、コンフォーム オブジェクトはサーフェスからの補間された法線を使用して、より正確な変形を行います。

<Conformmodifier>.BlendNormals     BooleanClass    default: false   --  boolean

法線をブレンドするかどうかを指定します。

<Conformmodifier>.clearSpecifiedNormals     BooleanClass    default: true   --  boolean

true の場合、サーフェス オブジェクト上の既存の法線をクリアします。

<Conformmodifier>.ignoreSelectionMisses     BooleanClass    default: false   --  boolean

true の場合、選択がターゲットを下回ると、頂点はオリジナルの位置に戻ります。

<Conformmodifier>.lookAtHelper     UndefinedClass    default: undefined   --  node

投影方向が「ヘルパー原点」の場合に使用されるルックアット ヘルパー オブジェクトを取得/設定します。

<Conformmodifier>.     BooleanClass    default: false   --  boolean

選択でターゲットを外した場合に、頂点をオリジナルの位置に戻すかどうかを取得/設定します。

<Conformmodifier>.method     Integer    default: 0   --  integer

使用するコンフォーム方法です。値は次のとおりです。

• 0 = ボリューム
• 1 = シュリンクラップ

<Conformmodifier>.MoveMissesToClosest     BooleanClass    default: false   --  boolean

true の場合、欠落した投影をターゲット オブジェクト上の最も近いポイントに移動します。

<Conformmodifier>.normalizeSelection     BooleanClass    default: true   --  boolean

true の場合、選択法線を 0 から 1 に正規化します。

<Conformmodifier>.Offset     Float    default: 0.0   --  animatable; float

適用するオフセットです。投影法線に沿ってサーフェスに対してオブジェクトを移動する量です。

<Conformmodifier>.OffsetBlended     BooleanClass    default: true   --  boolean

オフセット方向を投影方向(true)にするか法線のブレンドにするかを指定します。

<Conformmodifier>.selectionAmount     Float    default: 25.0   --  animatable; float

コンフォーム方法が「ボリューム」の場合に、ターゲット サーフェスに適合するオブジェクトの割合を取得/設定します。これは、UI の影響設定です。

<Conformmodifier>.selectionFalloff     Float    default: 25.0   --  animatable; float

ターゲット サーフェスに適合するオブジェクトの追加ソフト選択の割合を取得/設定します。

<Conformmodifier>.SelectionOutput     Integer    default: 0   --  integer

選択出力を取得/設定します。値は次のとおりです。

• 0 = 既存
• 1 = 選択
• 2 = 見つかりません
• 3 = レイの距離
• 4 = 最小/最大ヒット距離

<Conformmodifier>.ShrinkDirection     Integer    default: 3   --  integer

投影方法が[シュリンク ラップ](Shrink Wrap)の場合の投影方向を取得/設定します。値は次のとおりです。

• 0 = 軸
• 1 = ターゲットの方向
• 2 = ヘルパー方向
• 3 = 頂点法線
• 4 = 最近接ポイント

<Conformmodifier>.strength     Float    default: 100.0   --  animatable; float

オリジナルのオブジェクト位置に対する Conform の強度を割合で取得/設定します。

<Conformmodifier>.Targets     ArrayParameter    default: #()   --  paramBlock2 array; SubAnim

コンフォームされたオブジェクトのターゲットであるオブジェクトの配列を格納します。

<Conformmodifier>.UseCache     BooleanClass    default: false   --  boolean

キャッシュを使用するかどうかを指定します。このキャッシュは、有効になっているフレームで変形結果をキャッシュします。

<Conformmodifier>.VolumeAmount     Float    default: 100.0   --  animatable; float

コンフォームのボリュームを取得/設定します。0 の場合、すべての頂点がサーフェスに投影され、100 の場合、確認されたオブジェクトはボリューム全体を保持します。

<Conformmodifier>.VolumeDirection     Integer    default: 0   --  integer

ボリューム投影の方向を取得/設定します。値は次のとおりです。

• 0 = 軸
• 1 = サーフェス方向
• 2 = ヘルパー原点

インタフェースの Conform メソッド

<integer>version()

ConformModifier バージョンを返します。

<integer>targetCount()

ターゲット配列のターゲットの数を返します。

<boolean>appendTarget <node>target

指定した target をターゲット配列に追加します。ターゲットは既定で有効な状態で追加されます。

<node>getTarget <index>index

指定したインデックスのターゲット配列内のターゲット ノードを返します。このインデックスにターゲットがない場合は、undefined を返します。

<boolean>removeTarget <index>index

指定したインデックスにあるターゲットをターゲット配列から削除し、成功した場合は true、失敗した場合は false を返します。

<void>removeAllTargets()

ターゲット配列からすべてのターゲットを削除します。

<boolean>enableTarget <index>index

指定したインデックスのターゲットを有効にし、成功した場合は true、失敗した場合は false を返します。

<boolean>disableTarget <index>index

指定したインデックスでターゲットを無効にし、成功した場合は true、失敗した場合は false を返します。

<boolean>isTargetEnabled <index>index

指定したインデックスにあるターゲットの有効状態を返します。なお、このメソッドは、指定したインデックスにターゲットがない場合にも false を返します。