Arraymodifier: モディファイヤ

Arraymodifier - superclass: modifier; super-superclass:MAXWrapper - 114:0 - classID: #(2394076151L, 1473922114L); creatable: true

ArrayModifier インタフェースは、3ds Max パラメトリック配列モディファイヤへのアクセスを提供します。

コンストラクタ

Arraymod...
Arraymodifier...

例

-- ArrayMod Demo

-- create a spline

resetMaxFile #noprompt

myStar = Star radius1:100 radius2:50
myTeapot = Teapot radius:10
myArray = ArrayMod()

addmodifier myTeapot myArray

-- by default an array is type grid, change this to spline and
-- set the target spline to the star


myArray.type = 2 -- spline
myArray.referenceSpline = myStar
myArray.countX = 30
myArray.splinePercentType = 1 --loop
myArray.randomizationRotationLink = true -- x value applies to all axes
with animate on (
at time 0 (
    myArray.splinePercentAmount = 0
    myArray.randomizationRotationX = 0
    )
at time 80 (
    myArray.splinePercentAmount = 50
    myArray.randomizationRotationX = 60
    )

)
playAnimation()

プロパティ

[分配] (Distribution)領域
[変換] (Transform)領域
[ランダム化] (Randomization)領域
マテリアル ID
[UV] (UV)領域
[除去] (Remove)領域
[作成] (Create)領域
- Arraymodifier インタフェース:
インタフェース: ArrayMod

[分配] (Distribution)領域

<arraymodifier>.arrayRadius     Float    default: 10.0   --  animatable; float

分配タイプが放射状の場合に、配列の半径をシーン単位で取得/設定します。

<arraymodifier>.byElement     BooleanClass    default: false   --  boolean

複数要素オブジェクトの各要素を配列のクローンとしてランダムに使用するかどうかを指定します。

<arraymodifier>.center     BooleanClass    default: false   --  boolean

オリジナルのオブジェクトの位置が中心となるように、配列を再配置するかどうかを指定します。

<arraymodifier>.countX     Integer    default: 5   --  animatable; integer

分配タイプがグリッドの場合に、X 次元のクローンの数を取得/設定します。

<arraymodifier>.countY     Integer    default: 1   --  animatable; integer

分配タイプがグリッドの場合に、Y 次元のクローンの数を取得/設定します。

<arraymodifier>.countZ     Integer    default: 1   --  animatable; integer

分配タイプがグリッドの場合に、Z 次元のクローンの数を取得/設定します。

<arraymodifier>.distributionMethod     Integer    default: 1   --  integer

グリッドの分配方法を設定します。値は次のとおりです。

0 = 合計寸法
1 = 相対オフセット
2 = 塗り潰し

<arraymodifier>.dynamicSpacing     BooleanClass    default: false   --  boolean

ダイナミックスペースを使用するかどうかを指定します。ダイナミックスペースを指定すると、最初と最後のクローンの間にクローンが挿入されます。false の場合、新しいクローンは配列の末尾に追加されます。

<arraymodifier>.elementCenter     BooleanClass    default: true   --  boolean

.byElement が true の場合、x 軸上の各クローンの基点をクローンの中心に設定するかどうかを指定します。

<arraymodifier>.elementSeed     Integer    default: 12345   --  integer

.byElement が true の場合に要素を分配するために使用されるランダムシードを取得/設定します。

<arraymodifier>.endAngle     Float    default: 360.0   --  animatable; float

分配モードが放射状の場合に、配列の終了角度を取得/設定します。

<arraymodifier>.equidistantRings     BooleanClass    default: false   --  boolean

分配モードが放射状で複数のリングがある場合(.rings > 1)に、リングを等距離にするかどうかを指定します。これを行うには、offset および spacing パラメータを使用して、各リングにできるだけ多くのクローンを追加します。

<arraymodifier>.flip     BooleanClass    default: false   --  boolean

配列がスプライン上に分配されている場合に、配列の分配を反転するかどうかを指定します。

<arraymodifier>.height     Float    default: 1.0   --  animatable; float

分配モードがグリッドの場合に、配列の高さを取得/設定します。

<arraymodifier>.length     Float    default: 1.0   --  animatable; float

分配モードがグリッドの場合に、配列の長さを取得/設定します。

<arraymodifier>.offsetRings     Float    default: 1.0   --  animatable; float

分配方法が放射状の場合に、各リングでのクローンの間隔を取得/設定します。

<arraymodifier>.offsetRows     Float    default: 1.0   --  animatable; float

分配方法が放射状の場合に、行の間隔を取得/設定します。

<arraymodifier>.offsetX     Float    default: 1.0   --  animatable; float

分配モードがグリッドの場合に、X 軸オフセットを取得/設定します。

<arraymodifier>.offsetY     Float    default: 1.0   --  animatable; float

分配モードがグリッドの場合に、Y 軸オフセットを取得/設定します。

<arraymodifier>.offsetZ     Float    default: 1.0   --  animatable; float

分配モードがグリッドの場合に、Z 軸オフセットを取得/設定します。

<arraymodifier>.orientation     Float    default: 100.0   --  animatable; float

分配方法が放射状の場合に、オリジナルのオブジェクトの方向を基準にしたクローンの方向を取得/設定します。

<arraymodifier>.packElements     BooleanClass    default: false   --  boolean

分配方法がグリッドの場合に、要素を X 軸に沿ってパックするかどうかを指定します。

<arraymodifier>.radialAxis     Integer    default: 2   --  integer

放射状の分配に使用する軸を指定します。値は次のとおりです。

0 = X 軸
1 = Y 軸
2 = Z 軸

<arraymodifier>.radialCount     Integer    default: 5   --  animatable; integer

分配タイプが放射状の場合に、配列内の(行ごとの)クローンの数を取得/設定します。

オフセット量を取得/設定します

<arraymodifier>.radialPhase     Float    default: 0.0   --  animatable; float

<arraymodifier>.radialScaleMethod     Integer    default: 0   --  integer

<arraymodifier>.referenceSpline     UndefinedClass    default: undefined   --  node

分配方法がスプラインの場合に使用されるスプラインノードを取得/設定します。

<arraymodifier>.retainOrientation     BooleanClass    default: false   --  boolean

分配モードがスプラインまたはサーフェスの場合に、元のオブジェクトの方向を保持するかどうかを指定します。

<arraymodifier>.rings     Integer    default: 1   --  animatable; integer

分配モードが放射状の場合のリング数を取得/設定します。

<arraymodifier>.rows     Integer    default: 1   --  animatable; integer

分配モードが放射状の場合の行数を取得/設定します。

<arraymodifier>.spacingRings     Float    default: 0.0   --  animatable; float

リング間のスペースの量を表示単位で取得/設定します。

<arraymodifier>.spacingRows     Float    default: 0.0   --  animatable; float

行間のスペースの量を表示単位で取得/設定します。

<arraymodifier>.spacingX     Float    default: 0.0   --  animatable; float

分配モードがグリッドで、その後[相対オフセット](Relative Offset)を選択した場合に、X 軸の各クローン間の距離を取得/設定します。

<arraymodifier>.spacingY     Float    default: 0.0   --  animatable; float

分配モードがグリッドで、その後[相対オフセット](Relative Offset)を選択した場合にに、Y 軸の各クローン間の距離を取得/設定します。

<arraymodifier>.spacingZ     Float    default: 0.0   --  animatable; float

分配モードがグリッドで、その後[相対オフセット](Relative Offset)を選択した場合にに、Z 軸の各クローン間の距離を取得/設定します。

<arraymodifier>.splineAxialAngle     Float    default: 0.0   --  animatable; float

分配方法がスプラインの場合に、スプラインの軸を中心としたクローンの配置を度単位で取得/設定します。

<arraymodifier>.splineAxis     Integer    default: 0   --  integer

分配方法がスプラインの場合に、クローン分配の中心となるスプラインの軸を取得/設定します。値は次のとおりです。

0 = X
1 = Y
2 = Z

<arraymodifier>.splineDistributionMethod     Integer    default: 0   --  integer

分配方法がスプラインの場合に、分配方法を取得/設定します。値は次のとおりです。

0 = 数
1 = 相対オフセット
2 = 塗り潰し
3 = ノット
4 = セグメント

<arraymodifier>.splinePercentAmount     Float    default: 0.0   --  animatable; float

分配方法がスプラインの場合に、スプラインに沿ったクローンの位置を取得/設定します。

<arraymodifier>.splinePercentType     Integer    default: 1   --  integer

分配タイプがスプラインの場合に、位置変換方法を取得/設定します。値は次のとおりです。

0 = 続行
1 = ループ
2 = 終了
3 = 削除

<arraymodifier>.splineSurface     UndefinedClass    default: undefined   --  node

配列を投影するシーンオブジェクトを取得/設定します。

<arraymodifier>.splineVariation     Float    default: 0.0   --  animatable; float

分配方法がスプラインの場合に、クローン位置に適用するランダム変動のパーセントを取得/設定します。

<arraymodifier>.splineVariationSeed     Integer    default: 12345   --  integer

変動値の乱数シードを取得/設定します。

<arraymodifier>.staggerRings     BooleanClass    default: false   --  boolean

複数のリングがあり、分配方法が放射状の場合に、リングをスタッガーするかどうかを取得/設定します。

<arraymodifier>.staggerRows     BooleanClass    default: false   --  boolean

複数の行があり、分配方法が放射状の場合に、行をスタッガーするかどうかを取得/設定します。

<arraymodifier>.startAngle     Float    default: 0.0   --  animatable; float

分配方法が放射状の場合に、開始角度を取得/設定します。

<arraymodifier>.strength     Float    default: 100.0   --  animatable; float

分配方法がグリッド、放射状、またはスプラインの場合に、強度値(パーセント)を取得/設定します。

<arraymodifier>.surfaceMethod     Integer    default: 0   --  integer

サーフェスの分配方法を取得/設定します。値は次のとおりです。

0 = 頂点
1 = 面の中心
2 =エッジの中心

<arraymodifier>.surfaceReference     UndefinedClass    default: undefined   --  node

分配方法がサーフェスの場合に、配列を投影するシーンオブジェクトを取得/設定します。

<arraymodifier>.type     Integer    default: 0   --  integer

配列モディファイヤの分配方法を取得/設定します。値は次のとおりです。

０ = グリッド
1 = 放射状
2 = スプライン
3 = サーフェス

<arraymodifier>.useStartEndAngle     BooleanClass    default: false   --  boolean

分配タイプが放射状の場合に、クローンの配置に開始角度値と終了角度値を使用するかどうかを指定します。

<arraymodifier>.width     Float    default: 1.0   --  animatable; float

分配方法がグリッドの場合、配列の幅を取得/設定します。

[変換] (Transform)領域

<arraymodifier>.gridLocalRotationMethod     Integer    default: 0   --  integer

分配方法がグリッドの場合に、ローカル回転方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 交互
3 = ランダムに増分
4 = 軸
5 = 軸で増分

<arraymodifier>.gridPositionMethod     Integer    default: 0   --  integer

分配方法がグリッドの場合に、グリッド配置方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 交互
3 = 軸
4 = Z 軸と Y 軸

<arraymodifier>.gridScaleMethod     Integer    default: 0   --  integer

分配方法がグリッドの場合に、グリッドスケール方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 交互
3 = 軸

<arraymodifier>.localRotationSeed     Integer    default: 12345   --  integer

ローカル回転のランダム化シードを取得/設定します。

<arraymodifier>.localRotationX     Float    default: 0.0   --  animatable; float

X 軸を中心としたローカル回転を度単位で取得/設定します。

<arraymodifier>.localRotationY     Float    default: 0.0   --  animatable; float

Y 軸を中心としたローカル回転を度単位で取得/設定します。

<arraymodifier>.localRotationZ     Float    default: 0.0   --  animatable; float

Z 軸を中心としたローカル回転を度単位で取得/設定します。

<arraymodifier>.posX     Float    default: 0.0   --  animatable; float

分配方法がグリッド、スプライン、またはサーフェスの場合に、X 軸の位置の値を取得/設定します。

<arraymodifier>.posY     Float    default: 0.0   --  animatable; float

分配方法がグリッド、スプライン、またはサーフェスの場合に、Ｙ軸の位置の値を取得/設定します。

<arraymodifier>.posZ     Float    default: 0.0   --  animatable; float

分配方法がグリッド、スプライン、またはサーフェスの場合に、Z 軸の位置の値を取得/設定します。

<arraymodifier>.radialLocalRotationMethod     Integer    default: 0   --  integer

ローカル回転方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 交互
3 = ランダムに増分

<arraymodifier>.radialOffset     Float    default: 0.0   --  animatable; float

放射状オフセット値を取得/設定します。放射状オフセット値は、配列の主軸から接線方向に連続的に各クローンを移動します。

<arraymodifier>.ringOffset     Float    default: 0.0   --  animatable; float

クローンの各リングが配列の軸に沿って連続的に移動する場合の移動量を取得/設定します。

<arraymodifier>.ringPhase     Float    default: 0.0   --  animatable; float

主軸を中心とした他のすべてのリングの回転を度単位で取得/設定します。

<arraymodifier>.scaleLink     BooleanClass    default: false   --  boolean

すべての軸のワールドスケール変換方法を X 軸の値にリンクするかどうかを取得/設定します。

<arraymodifier>.scaleX     Float    default: 100.0   --  animatable; float

X 軸に沿ってクローンのスケールを変更する場合の変更量(パーセンテージ)を取得/設定します。

<arraymodifier>.scaleY     Float    default: 100.0   --  animatable; float

Y 軸に沿ってクローンのスケールを変更する場合の変更量(パーセンテージ)を取得/設定します。

<arraymodifier>.scaleZ     Float    default: 100.0   --  animatable; float

Z 軸に沿ってクローンのスケールを変更する場合の変更量(パーセンテージ)を取得/設定します。

<arraymodifier>.splineLocalRotationMethod     Integer    default: 0   --  integer

分配方法がスプラインの場合に、ローカル回転方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 交互
3 = ランダムに増分

<arraymodifier>.splinePositionMethod     Integer    default: 0   --  integer

分配方法がスプラインの場合に、配置方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 交互

<arraymodifier>.splineScaleMethod     Integer    default: 0   --  integer

分配方法がスプラインの場合に、スケール方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 交互
3 = 軸

<arraymodifier>.worldRotationMethod     Integer    default: 0   --  integer

ワールド回転方法を取得/設定します。値は次のとおりです。

0 = すべて
1 = 増分
2 = 軸
3 = 軸で増分
4 = ベンド

<arraymodifier>.worldRotationSeed     Integer    default: 12345   --  integer

ワールド回転の乱数シードを取得/設定します。

<arraymodifier>.worldRotationX     Float    default: 0.0   --  animatable; float

X 軸を中心に配列のワールド方向を回転する場合の回転量の値を取得/設定します。

<arraymodifier>.worldRotationY     Float    default: 0.0   --  animatable; float

Y 軸を中心に配列のワールド方向を回転する場合の回転量の値を取得/設定します。

<arraymodifier>.worldRotationZ     Float    default: 0.0   --  animatable; float

Z 軸を中心に配列のワールド方向を回転する場合の回転量の値を取得/設定します。

[ランダム化] (Randomization)領域

<arraymodifier>.applyTo     Float    default: 100.0   --  animatable; float

ランダム化が適用されるクローンのパーセンテージを取得/設定します。

<arraymodifier>.applyToSeed     Integer    default: 12345   --  integer

.applyTo 値のランダムシードを取得/設定します。

<arraymodifier>.positionSeed     Integer    default: 12345   --  integer

[回転値](Position value)領域のランダム化シードを取得/設定します。

<arraymodifier>.randomizationPositionLink     BooleanClass    default: false   --  boolean

3 つのすべての軸をコントロールするために X パラメータを使用するかどうかを指定します。UI では、このパラメータはリンクボタンとして表されます。

<arraymodifier>.randomizationPositionX     Float    default: 0.0   --  animatable; float

X 軸に沿ってクローンをランダムに移動する最大量を取得/設定します。

<arraymodifier>.randomizationPositionY     Float    default: 0.0   --  animatable; float

Y 軸に沿ってクローンをランダムに移動する最大量を取得/設定します。

<arraymodifier>.randomizationPositionZ     Float    default: 0.0   --  animatable; float

Z 軸に沿ってクローンをランダムに移動する最大量を取得/設定します。

<arraymodifier>.randomizationRotationLink     BooleanClass    default: false   --  boolean

<arraymodifier>.randomizationRotationX     Float    default: 0.0   --  animatable; float

X 軸に沿ってクローンをランダムに回転する最大量を取得/設定します。

<arraymodifier>.randomizationRotationY     Float    default: 0.0   --  animatable; float

Y 軸に沿ってクローンをランダムに回転する最大量を取得/設定します。

<arraymodifier>.randomizationRotationZ     Float    default: 0.0   --  animatable; float

Z 軸に沿ってクローンをランダムに回転する最大量を取得/設定します。

<arraymodifier>.randomizationScaleLink     BooleanClass    default: false   --  boolean

<arraymodifier>.randomizationScaleX     Float    default: 0.0   --  animatable; float

X 軸に沿ってクローンをランダムにスケール最大量を取得/設定します。

<arraymodifier>.randomizationScaleY     Float    default: 0.0   --  animatable; float

Y 軸に沿ってクローンをランダムにスケールする最大量を取得/設定します。

<arraymodifier>.randomizationScaleZ     Float    default: 0.0   --  animatable; float

Z 軸に沿ってクローンをランダムにスケールする最大量を取得/設定します。

<arraymodifier>.rotationSeed     Integer    default: 12345   --  integer

回転のランダムシードを取得/設定します。

<arraymodifier>.scaleSeed     Integer    default: 12345   --  integer

スケールのランダムシードを取得/設定します。

[マテリアル ID](Material ID)領域

<arraymodifier>.matIDFrom     Integer    default: 1   --  integer

クローンにランダムに適用する最小マテリアル ID を取得/設定します。

<arraymodifier>.matIDSeed     Integer    default: 12345   --  integer

ランダムなマテリアル ID の生成に使用するシード値を取得/設定します。

<arraymodifier>.matIDTo     Integer    default: 1   --  integer

クローンにランダムに適用する最大マテリアル ID を取得/設定します。

[UV] (UV)領域

<arraymodifier>.uvAdditive     BooleanClass    default: true   --  boolean

ソースマップから既存の UVW 値に UVW 値を追加するかどうかを指定します。

<arraymodifier>.uvChannel     Integer    default: 1   --  integer

ターゲット UVW チャネル番号を取得/設定します。

<arraymodifier>.uvMethod     Integer    default: 0   --  integer

UV 方法を取得/設定します。値は次のとおりです。

0 = 既存
1 = クローン XYZ
2 = クローン番号

<arraymodifier>.uvNormalize     BooleanClass    default: true   --  boolean

UVW 値を 0.0 から 1.0 の間で正規化するかどうかを指定します。

<arraymodifier>.uvSource     Integer    default: 1   --  integer

.uvAdditive が true の場合に、ソース UVW マップチャネル番号を取得/設定します。

[除去] (Remove)領域

<arraymodifier>.cullObject     UndefinedClass    default: undefined   --  node

ノードを除去するシーンノード、または結果のカリングに使用するシーンノードを取得/設定します。

<arraymodifier>.invertCull     BooleanClass    default: false   --  boolean

除去/カリング操作を反転するかどうかを指定します。

<arraymodifier>.remove     Float    default: 0.0   --  float

除去するクローンのパーセンテージを取得/設定します。

<arraymodifier>.removeSeed     Integer    default: 12345   --  integer

クローンをランダムに除去するための乱数シードを取得/設定します。

[作成] (Create)領域

<arraymodifier>.useInstances     BooleanClass    default: true   --  boolean

オブジェクトを作成(Create Objects)ボタンをクリックしたときに、新しいインスタンスのセットを作成するかどうかを指定します。

Arraymodifier インタフェース:

インタフェース: ArrayMod

プロパティ:

メソッド:

<integer>version()

配列モディファイヤのバージョン番号を返します。

<void>clearCache()

配列モディファイヤキャッシュをクリアします。

<void>CreateObjects()

配列内のクローンに基づいて、新しいオブジェクトセットを作成します。

アクション: