Szimbólumok importálása

A MAPSYMBOLIMPORTEXPORT vagy egy Microsoft VBA-parancsfájl segítségével egyetlen művelettel importálhat több szimbólumot.

A pont-, vonal- vagy poligonjellemzők stílusának megadásakor a Betöltés opció lehetővé teszi egy szimbólum importálását. A MAPSYMBOLIMPORTEXPORT parancsot is használhatja az alábbiakban leírtak szerint.

Szimbólumok importálása felhasználói felület segítségével

  1. Állítsa be a CMDDIA vagy a FILEDIA rendszerváltozót „1” értékre.
  2. A parancspromptba írja be a MAPSYMBOLIMPORTEXPORT parancsot.
  3. A Szimbólum adattár területen kattintson az Importálás lehetőségre.
  4. A Megnyitás párbeszédpanelen keresse meg és jelölje ki az importálni kívánt fájlt, vagy írja be a fájl nevét a Fájlnév mezőbe, majd kattintson a Megnyitás gombra.

    A DWG-fájlokban található blokkok szimbólumként importálhatók. A szimbólum adattárba szimbólumtárat (*.layer), vektorszimbólumot (*.xml), sraffozási meghatározást (*.pat), vonalstílust (*.lin) vagy raszterképeket (*.gif, *.jpg, *.bmp, *.png) is importálhat.

  5. Kattintson a Bezár gombra.

Szimbólumok importálása felhasználói felület használata nélkül

  1. Állítsa be a CMDDIA és a FILEDIA rendszerváltozót is „0” értékre.
  2. A parancspromptba írja be a MAPSYMBOLIMPORTEXPORT parancsot.
  3. A parancs után válassza az Importálás lehetőséget.
  4. Adja meg az importálni kívánt szimbólumokat tartalmazó szimbólumfájl elérési útját.
  5. Válassza az Igen lehetőséget, ha le szeretné cserélni az azonos névvel rendelkező meglévő szimbólumokat, vagy a Nem lehetőséget, ha nem szeretné felülírni az azonos névvel rendelkező szimbólumokat.
  6. Várjon, amíg megjelenik „A jel importálása sikeresen befejeződött!” üzenet.
Tipp: A fenti lépéseket automatikusan is végrehajthatja egy parancsfájl segítségével. A parancssorban töltse be a parancsfájlt az FKÖNYV paranccsal, és várja meg, amíg befejeződik. Az alábbiakban egy parancsfájlra talál példát. Mentse .scr kiterjesztésű fájlként. 
CMDDIA 0
FILEDIA 0
_MAPSYMBOLIMPORTEXPORT _IMPORT "C:\data\MySymbols.dwg" _YES

VBA-parancsfájl opció

Hogy időt takarítson meg, a szimbólumokat egyetlen művelettel több rajzba is importálhatja egy Microsoft Visual Basic for Applications (VBA) parancsfájl használatával. Az alábbiakban egy minta parancsfájl látható. Ezt használhatja sablonként, végrehajthatja a szükséges módosításokat, majd mentheti .bas fájlként. 

Attribute VB_Name = "ImportSymbolIntoDWG"
Sub ImportSymbolIntoAllDWG()
    Dim fileSystemObject, fileSystemFolder, file, fileCollection
    Dim collectionOfFiles As New Collection
    
    Dim path As String
    ' Define where the DWG files are located
    path = "C:\Autodesk\DWGFiles"
    
    Dim prototypeDWG As String
    ' Define where the symbol(s) should be imported from
    prototypeDWG = "C:\Autodesk\Prototype\Prototype_GA_modified.dwg"
    
    Dim currentSDI As Integer
    currentSDI = ThisDrawing.GetVariable("SDI")
    
    If (currentSDI = 1) Then
        MsgBox "The functions works only with multiple drawings [SDI=0]"
        Exit Sub
    End If
    
    '' use this to request the path
    'path = ThisDrawing.Utility.GetString(1, vbCrLf & "Enter the path of the DWG files to update: ")
    'prototypeDWG = ThisDrawing.Utility.GetString(1, vbCrLf & "Enter the path of the prototype DWG: ")
    
    ThisDrawing.SetVariable "FILEDIA", 0
    ThisDrawing.SetVariable "CMDDIA", 0
    
    Set fileSystemObject = CreateObject("Scripting.FileSystemObject")
    Set fileSystemFolder = fileSystemObject.GetFolder(path)
    Set fileCollection = fileSystemFolder.Files
    
    For Each file In fileCollection
        If UCase(Right(file.Name, 4)) = UCase(".dwg") Then
            collectionOfFiles.Add file.path
        End If
    Next
    
    For Each drawing In collectionOfFiles
        Application.Documents.Open (drawing)
        ThisDrawing.SendCommand "_MAPSYMBOLIMPORTEXPORT" & vbCr & "_IMPORT" & vbCr & prototypeDWG & vbCr & "_YES" & vbCr
        ThisDrawing.Save
        ThisDrawing.Close
    Next drawing
    
End Sub

A példa parancsfájlban található egy „ImportSymbolIntoDWG” nevű modul egy „ImportSymbolIntoAllDWG()” nevű részmodullal. Módosítania kell a „path” változó értékét a rajzok helyére mutató elérési út megadásához, illetve módosítania kell a „prototypeDWG” változót, hogy arra a DWG-fájlra mutasson, amely az importálni kívánt szimbólumokat tartalmazza.

Szimbólumok importálása több rajzba egy VBA-parancsfájl használatával

  1. Tegye az összes olyan rajzot egy mappába, amelyek szimbólumait frissíteni szeretné.
  2. Nyissa meg az AutoCAD Map 3D eszközkészlet parancssort, és írja be a VBAIDE parancsot a Microsoft VBA ablak megnyitásához.

    Ha még nem telepítette az Autodesk AutoCAD VBA Enabler modult, megjelenik egy üzenet, hogy töltse le azt.

  3. A Microsoft VBA ablakban tegye a következőket:
    1. Kattintson a Fájl menüre, és válassza a Fájl importálása lehetőséget.
    2. A Fájl importálása párbeszédpanelen keresse meg és válassza ki a parancsfájlt tartalmazó .bas fájlt.
    3. Kattintson a Megnyitás gombra.
    4. A Microsoft VBA ablakban kattintson a Mentés gombra.
    5. A Mentés másként párbeszédpanelen adja meg az elérési útvonalat és a fájlnevet, majd kattintson a Mentés gombra.
  4. Zárja be a Microsoft VBA ablakot.
  5. A parancssorba írja be a VBABETÖLT parancsot az előzőekben mentett .dvb fájl betöltéséhez.

    Ha a rendszer figyelmeztetést jelenít meg a makrókkal kapcsolatban, kattintson a Makrók engedélyezése lehetőségre.

  6. A parancssorba írja be a VBAFUTTAT parancsot, és válassza a kapcsolódó makró futtatását.

Kapcsolódó feladatok