オフセット基線のリストを取得する

基線リージョンの中に、主基線からオフセットされた補助的な基線を配置できます。オフセット基線のコレクションは、AeccBaselineRegion.OffsetBaselines プロパティに含まれています。 このコレクションには、IAeccBaseBaseline インタフェースから派生した 2 種類の基線が含まれています。 1 つは、ハードコードされたオフセット基線(AeccHardcodedOffsetBaseline クラスのインスタンス)で、その全長にわたって主基線から一定の距離を保持します。 もう 1 つはオフセット基線(AeccOffsetBaseline クラスのインスタンス)で、主基線からの距離は一定ではありません。

注:

Autodesk Civil 3D API には、新しいオフセット基線またはハードコードされたオフセット基線を作成するメソッドは含まれていません。

次のコードでは、基線リージョン内の各オフセット基線を調べます。

Dim oBaseBaseline As IAeccBaseBaseline
For Each oBaseBaseline In oBaselineRegion.OffsetBaselines
   Dim dMainStart As Double ' station on main baseline
   Dim dMainEnd As Double ' station on main baseline
   Dim vOE As Variant
 
   Select Case oBaseline.Type
   Case aeccCorridorOffsetBaseline
      Dim oOffsetBaseline As AeccOffsetBaseline
      Set oOffsetBaseline = oBaseBaseline
 
      ' Report that an offset baseline exists.
      dMainStart = oOffsetBaseline.StartStationOnMainBaseline
      dMainEnd = oOffsetBaseline.EndStationOnMainBaseline
      Debug.Print "Offset baseline, station " & dMainStart & _
         " to " & dMainEnd
 
      ' Report the offset of the baseline at its start and end.
      vOE = oOffsetBaseline. _
         GetOffsetElevationFromMainBaselineStation(dMainStart)
      Debug.Print " is offset by: " & _ 
         vOE(0) & " horizontal and: " & vOE(1) & _
         " vertical at start"
      vOE = oOffsetBaseline. _
         GetOffsetElevationFromMainBaselineStation(dMainEnd)
      Debug.Print " is offset by: " & vOE(0) & _
         " horizontal and: " & vOE(1) & " vertical at end"
 
   Case aeccCorridorHardcodedOffsetBaseline
      Dim oHardcodedOffsetBaseline As AeccHardcodedOffsetBaseline
      Set oHardcodedOffsetBaseline = oBaseBaseline
 
      ' Report that a hardcoded offset baseline exists.
      dMainStart = oHardcodedOffsetBaseline.StartStation
      dMainEnd = oHardcodedOffsetBaseline.EndStation
      Debug.Print "Hardcoded offset baseline, station " _
         & dMainStart & " to " & dMainEnd
      vOE = oHardcodedOffsetBaseline. _
         OffsetElevationFromMainBaseline
      Debug.Print " is offset by: " & vOE(0) & _
         " horizontal and: " & vOE(1) & " vertical"
   End Select
Next