Sobre como usar o AutoLISP para definir MODEMACRO

Definir valores de MODEMACRO com o AutoLISP.

Nota: O AutoLISP não está disponível no AutoCAD LT for Mac OS e a variável de sistema MODEMACRO não está disponível no Mac OS.

É possível usar o AutoLISP para atribuir uma sequência de caracteres para a variável de sistema MODEMACRO e exibir os resultados para a barra de status. Use a função strcat do AutoLISP para montar a sequência de caracteres MODEMACRO completa com base na sequências de caracteres de componentes menores.

(defun C:ACADMODE()
  (setvar "modemacro"
    (strcat
        "Layer $(substr,$(getvar,clayer),1,8)"
        "$(if,$(getvar,orthomode), Ortho)"
        "$(if,$(getvar,snapmode), Snap)"
        "$(if,$(=,$(getvar,tilemode),0),"
        "$(if,$(=,$(getvar,cvport),1), P)"
        ")"
    )
  )
)

O seguinte exemplo usa a função S::STARTUP para carregar um arquivo AutoLISP nomeado mode1.lsp e define uma sequência de caracteres para a variável de sistema MODEMACRO.

;;; S::STARTUP loads the file MODE1.LSP which defines a MODEMACRO string
(defun S::STARTUP ( )
  (load "mode1")
 (princ)
)
;;; Additional AutoLISP files can also be defined or loaded here

Quando o arquivo AutoLISP mode1.lsp é carregado, ele define a variável de sistema MODEMACRO para exibir informações na barra de status. O texto exibido começa com L: seguido pelos primeiros oito caracteres do nome da camada atual, o nome do desenho e uma parte do caminho e a primeira letra de cada nome dos modos atuais ativos. A posição do nome do desenho permanece constante, independentemente do comprimento do nome da camada.

;;; MODE1.LSP
(setvar "modemacro" 
  (strcat
    "L:$(substr,$(getvar,clayer),1,30)"
    "$(substr,        ,1,$(-,30,$(strlen,$(getvar,clayer)))) "
    ;;            ^^^^^^^^ Note the 8 spaces here
    "<.."
      "$(if,$(eq,$(getvar,dwgname),UNNAMED),UNNAMED,"
        "$(substr,$(getvar,dwgname),"
          "$(if,$(>,$(strlen,$(getvar,dwgprefix)),29),"
            "$(-,$(strlen,$(getvar,dwgprefix)),29),1"
          "),"
          "$(strlen,$(getvar,dwgname))"
        ")"
      ")"
    ">"
    "$(if,$(getvar,orthomode), O, )"
    "$(if,$(getvar,snapmode), S, )"
    "$(if,$(and,"
    "$(=,$(getvar,tilemode),0),$(=,$(getvar,cvport),1)),P)"
  )
)

Também é possível avaliar as expressões DIESEL pelas rotinas AutoLISP com o uso da função menucmd do AutoLISP.