The following functions provide access to File Dialog, Color Management Settings and Meta Data of Render Elements. Available in 3ds Max 2015 and higher.

ElementFileDialog <render_element>

Opens the Save File Dialog of the specified render element instance.

ElementGetCustomGamma <render_element>

Returns the Custom Gamma value of the specified render element instance.

If no custom Gamma has been defined, returns 0.0.

ElementSetCustomGamma <render_element> <gamma>

Sets the Custom Gamma value of the specified render element instance to the float value given by the second argument.

<enum> ElementSetOutputColorConversion <RenderElement> (#automatic | #noConversion)    
<enum> ElementSetOutputColorConversion <RenderElement> #colorSpaceConversion [outputColorSpace:<string>]
<enum> ElementSetOutputColorConversion <RenderElement> #displayViewTransform [outputDisplay:<string> outputViewTransform:<string>] 

Available in 3ds Max 2026.2 and higher. Sets the output color conversion parameters of the bitmap that's associated with the render element. Returns the result of the operation as one of these enums:

• #notSet
• #Normal
• #forcedDefault
• #Invalid

<enum> ElementGetOutputColorConversion <RenderElement> [outputColorSpace:&<var>] [outputDisplay:&<var>] [outputViewTransform:&<var>]

Available in 3ds Max 2026.2 and higher. Gets the output color conversion parameters of the bitmap that's associated with the render element. Returns the output conversion type enum and fills the variables with the details if they are passed. Return value can be one of these enums:

• #automatic
• #noConversion
• #colorSpaceConversion
• #displayViewTransform

EXAMPLE

-- get the element manager
re = maxOps.GetCurRenderElementMgr() 
re.removeallrenderelements() 

-- create few render elements
el_specular = specular()
re.addrenderelement el_specular
el_diffuse = diffuse()
re.addrenderelement el_diffuse
el_depth = z_depth()
re.addrenderelement el_depth

-- Set output color conversions
-- Note: Adding render elements to the element manager can reset the bitmap information associated with the 
-- render element. Bitmap related properties should be set after adding the render element to the element manager.
ElementSetOutputColorConversion el_specular #displayViewTransform outputDisplay:"sRGB" outputViewTransform:"un-tone-mapped" 
ElementSetOutputColorConversion el_diffuse #colorSpaceConversion outputColorSpace:"sRGB"
ElementSetOutputColorConversion el_depth #noConversion

-- read back output color conversions
for n = 0 to (re.numrenderelements () - 1) do
(
    el = re.getrenderelement n
    res = ElementGetOutputColorConversion el outputColorSpace:&cs outputDisplay:&ds outputViewTransform:&vt
    format "element:% res:% outputColorSpace:% outputDisplay:% outputViewTransform:%\n" el res cs ds vt
)

ElementGetMetaData <render_element>

Returns an array containing the Meta Data of the specified render element instance.

If no Meta Data is defined, returns an empty array #().

ElementSetMetaData <render_element> <metaData_array>

Sets the Meta Data of the specified render element instance to the array values given by the second argument.