このインタフェースは、[シーンをレンダリング](Render Scene)ダイアログ ボックスのレンダリング要素リストにアクセスし操作するためのメソッドを公開します。

これは、MaxOps.GetCurRenderElementMgr () メソッドによって返されるもので、MAXScript で作成することはできません。このページの一番下にある例を参照してください。

RenderElementMgr インタフェース:

Interface: RenderElementMgr 

メソッド:

<boolean><RenderElementMgr>.AddRenderElement <maxObject>element  

特定のレンダリング要素を追加します。

成功した場合は True、それ以外の場合は False を返します。

 <boolean><RenderElementMgr>.RemoveRenderElement <maxObject>element 

特定のレンダリング要素を削除します。

成功した場合は True、それ以外の場合は False を返します。

 <void><RenderElementMgr>.RemoveAllRenderElements() 

リスト内のすべての要素を削除します。

 <integer><RenderElementMgr>.NumRenderElements() 

リスト内の要素の数を返します。

 <maxObject><RenderElementMgr>.GetRenderElement <integer>index 

特定のレンダリング要素を返します。インデックスの基数は 0 です。

 <void><RenderElementMgr>.SetElementsActive <boolean>active 

レンダリング要素の使用可能状態を設定します。

True に設定すると、リスト上のアクティブな要素がすべてレンダリング中に作成されます。

False に設定すると、レンダリング要素は作成されません。

 <boolean><RenderElementMgr>.GetElementsActive() 

要素がアクティブであるかどうか、つまり、レンダリング中に作成されるかどうかを示すブール値を返します。

 <void><RenderElementMgr>.SetDisplayElements <boolean>display 

要素が作成された後に表示されることを示すブール値を設定します。

 <boolean><RenderElementMgr>.GetDisplayElements() 

要素が作成された後に表示されることを示すブール値を取得します。

 <void><RenderElementMgr>.SetCombustionOutputEnabled <boolean>enabled 

combustion .cws ファイルへの出力の有効と無効を切り替えます。

 <boolean><RenderElementMgr>.GetCombustionOutputEnabled() 

combustion .cws ファイルへの出力が有効になっているブール値を取得します。

 <void><RenderElementMgr>.SetCombustionOutputPath <filename>pathname 

SetCombustionOutoutEnabled() が True に設定されている場合は、書き込み先の Combustion .cws ファイルのファイル名を設定します。

 <filename><RenderElementMgr>.GetCombustionOutputPath() 

Combustion .cws ファイルのファイル名を返します。

 <void><RenderElementMgr>.SetRenderElementFilename <integer>index <filename>filename 

インデックスで指定されたレンダリング要素の出力ファイル名を指定したファイル名文字列に設定します。

インデックスの基数は 0 です。

 <filename><RenderElementMgr>.GetRenderElementFilename <integer>index 

インデックスで指定されたレンダリング要素の出力ファイル名を取得します。

インデックスの基数は 0 です。

例

   -- set a list of render elements.
   elementlist = #(specular, diffuse, self_illumination, reflection,refraction, shadowrenderelement, atmosphere, blend, z_depth, alpha, backgroundrenderelement)

   re = maxOps.GetCurRenderElementMgr() -- get the current render element manager
   re.removeallrenderelements() -- remove all renderelements
   re.numrenderelements() -- get number of render elements

   theManager = maxOps.GetRenderElementMgr #Production
   theManager.numrenderelements()
   rendoutputfilename = "c:\\test.tga"
   -- adds all renderelements to be rendered.
   for n in elementlist do
   (
   re.addrenderelement (n elementname:("foo_"+ (n as string)))
   format "\nAdded % renderelement" n
   )
   rendsavefile = true
   setsilentmode true -- used to avoid error message when checking the filename of element
   renderSceneDialog.open() -- open Render Dialog
   -- get all render elements set and return name of render element and output filename
   for n = 0 to (theManager.numrenderelements () - 1) do
   (
   el = re.getrenderelement n
   format "\nGetting % render element" el.elementname
   format "\nRender element outputfilename: %" (re.GetRenderElementFileName n)
   )