showMetadata

ジャンプ先: 概要. 戻り値. キーワード. 関連. フラグ. MEL 例.

概要

showMetadata [-auto] [-dataType string] [-interpolation boolean] [-isActivated] [-listAllStreams] [-listMembers] [-listValidMethods] [-listVisibleStreams] [-member string] [-method string] [-off] [-range float float] [-rayScale float] [-stream string]

showMetadata は、取り消し可能、照会可能、および編集不可能です。

このコマンドは、指定したチャネル「vertex」、「edge」、「face」、および「vertexFace」内のメタデータ値をビューポートに表示する場合に使用します。データは次の 3 つの方法で表示できます。

1. 「color」: コンポーネント上にカラーを描画します。
2. 「ray」: コンポーネント上にレイを描画します。
3. 「string」: コンポーネント上に 2D 文字列を描画します。

「color」や「ray」モードを使用するには、float[3]のように項目数が 3 以下のデータ構造のメンバーを作成する必要があります。3 つの項目は、カラーとして「RGB」にマップされるか、ベクトルとして「XYZ」にマップされます。この構造は、2 つの項目でも同様に機能します。唯一の違いは、3 番目の値が常に 0 になることです。ただし、構造内の項目が 1 つのみの場合は、この値が 3 つの変数すべてにマップされます。つまり、構造が「int」で値が 1 の場合、カラーは白(1, 1, 1)になり、ベクトルは(1, 1, 1)になります。

照会モードの場合は、フラグの現在のステータスを取得できます(「-query」を使用)。ただし、1 つのコマンドで照会できるのは 1 つのフラグのステータスのみです。照会モードで値を設定することはできません。

指定された一部のオブジェクトにコマンドを使用したり、引数を指定しないでコマンドを実行して、シーン内のすべてのオブジェクトを変更することができます。オブジェクトにはメッシュ シェイプを指定する必要があります。コンポーネントはコマンドの引数として使用できません。

戻り値

照会モードでは、戻り値のタイプは照会されたフラグに基づきます。

キーワード

関連

フラグ

ロング ネーム(ショート ネーム)	引数タイプ	プロパティ
-auto(-a)
「-range」フラグと似ていますが、指定された入力値でなく、同じストリームおよびメンバー内のメタデータの最大/最小値を使用します。照会モードでは、このフラグを使用して「auto」がオンであるかどうかを照会できます。
-dataType(-dt)	string
作成モードで、「stream」および「member」フラグと併用した場合は、表示するメンバーを指定します。「off」フラグを使用する場合は、オフにするメンバーを指定します。照会モードで、「stream」および「member」フラグと併用した場合は、指定したメンバーの視覚化状態を照会します。1 回に視覚化できるのは、各シェイプの 1 つのメンバーのみです。 照会モードでは、このフラグは値を受け入れることができます。
-interpolation(-i)	boolean
作成モードでは、「カラー」メソッドの補間を有効/無効にします。補間をオンにすると、メタデータ値の平均を取って計算された補間カラーを使用してコンポーネントが表示されます。照会モードでは、選択されたオブジェクトの補間フラグの現在の状態を照会します。
-isActivated(-ia)
指定されたストリームがアクティブかどうかを確認します。いくつかのシェイプを選択した場合は、その状態を照会します。シェイプが選択されていない場合は、シーンのすべてのシェイプの状態を照会します。
-listAllStreams(-las)
オブジェクト名と一緒に使用すると、指定されたオブジェクトのすべてのストリームをリストできます。ビューポートに表示されているかどうかは関係ありません。また、このフラグを個別に使用すると、シーン内のすべてのストリームをリストできます。複数のオブジェクトに同じストリーム名が設定されている可能性があるため、返されたリストでは複製されたストリーム名が自動的にマージされます。
-listMembers(-lm)
「stream」フラグを指定して使用すると、指定されたストリームのメンバー リストを取得できます。
-listValidMethods(-lvm)
現在のストリームおよびメンバーに設定できる有効な表示方法をリストします。方法によっては、表示できないデータ型があります。たとえば、データ型が「string」の場合、「color」または「ray」では表示できません。つまり、方法をリストすると、「string」方法のみが返されます。
-listVisibleStreams(-lvs)
オブジェクト名と一緒に使用すると、指定したオブジェクトの現在の可視ストリーム名をリストできます。また、オブジェクト名を指定しないでフラグを使用すると、シーン内のすべての可視ストリームをリストできます。
-member(-mb)	string
作成モードで、「stream」および「dataType」フラグと併用した場合は、表示するメンバーを指定します。「off」フラグがオンの場合は、オフにするメンバーを指定します。照会モードで、「stream」および「dataType」フラグと併用した場合は、指定したメンバーの視覚化状態を照会します。1 回に視覚化できるのは、各シェイプの 1 つのメンバーのみです。 照会モードでは、このフラグは値を受け入れることができます。
-method(-m)	string
視覚化の方法を決定します。「color」はメタデータをカラー値に変換して、そのカラーでコンポーネントを描画します。「ray」はメタデータをベクトルに変換して、そのコンポーネントの中心を起点とするベクトル線を描画します。「string」はビューポート内のコンポーネントの横に 2D 文字列を使ってメタデータを表示します。引数には、これらの 3 つのワードの 1 つを文字列で指定する必要があります。既定の方法は「color」です。データ型が文字列である場合は、「string」方法を使用した場合のみ表示することができます。照会モードで、引数を指定しないでこのフラグを使用すると、指定したストリームおよびメンバーの方法を照会できます。
-off(-)
作成モードでは、「stream」、「member」、および「dataType」フラグで指定されたメンバーをオフにします。
-range(-r)	float float
使用するデータの範囲を指定します。範囲外の値は、最小/最大値にクランプされます。視覚化の方法が「color」の場合、範囲はカラーにマップされます。つまり、最小値は黒で、最大値は白で表示されます。照会モードでは、このフラグを個別に使用して現在の範囲を照会できます。
-rayScale(-rs)	float
適切な長さで表示するには、レイの尺度を指定します。
-stream(-s)	string
作成モードで、「member」および「dataType」フラグと併用した場合は、表示するメンバーを指定します。「off」フラグを使用する場合は、オフにするメンバーを指定します。照会モードで、「member」および「dataType」フラグと併用した場合は、指定したメンバーの視覚化状態を照会します。または、「listMembers」フラグと併用した場合は、指定されたストリームのメンバーを照会します。1 回に視覚化できるのは、各シェイプの 1 つのメンバーのみです。 照会モードでは、このフラグは値を受け入れることができます。

フラグはコマンドの作成モードで表示できます	フラグはコマンドの編集モードで表示できます
フラグはコマンドの照会モードで表示できます	コマンド内でフラグを複数回使用できます。

MEL 例

//Create a scene
file -force -new ;
dataStructure -format "raw" -asString "name=StructOne:int32=MemberOne";
polyPlane -constructionHistory false -name "mesh";

//Add Metadata
addMetadata -streamName "StreamOne" -channelName "vertex" -structure "StructOne" meshShape ;
editMetadata -streamName "StreamOne" -channelName "vertex" -memberName "MemberOne" -value 1 meshShape.vtx[1];
select -clear;

showMetadata -stream "StreamOne" -member "MemberOne" -dataType "int32" meshShape;
//Show metadata for which the member is "MemberOne" and the stream is "StreamOne"

showMetadata -stream "StreamOne" -member "MemberOne" -dataType "int32" -method "color" meshShape;
//StreamOne will be visualized by Component Color method. The other two visualization methods are
//"string" and "ray". If "-method" flag is not defined, "color" will be used by default

showMetadata -off;
//Deactivate all streams to turn off metadata visualization

showMetadata -stream "StreamOne" -member "MemberOne" -dataType "int32" -method "color" -interpolation true meshShape;
//Enable interpolation on "color" mode. Interpolation must be used with "color" method

showMetadata -range 0 10 -stream "StreamOne" -member "MemberOne" -dataType "int32" meshShape;
//Show metadata between a specified range from 0 to 10. If the method is "color",
// the value 0 will be displayed in black, while the value 10 will be displayed
// in white. The value beyond the range will be clamped to 0 or 10.

showMetadata -auto -stream "StreamOne" -member "MemberOne" -dataType "int32" meshShape;
//Show metadata between the dynamic range, which is computed by the current min/max value.

showMetadata -query -listAllStreams;
//Return all streams in the scene, no matter if they are activated

showMetadata -query -listAllStreams meshShape;
//Return all streams of meshShape, no matter if they are activated

showMetadata -query -listVisibleStreams;
//Return the stream name(s) being visualized in the scene

showMetadata -query -listVisibleStreams meshShape;
//Return the stream name being visualized that is attached to meshShape

showMetadata -query -stream "StreamOne" -listMembers;
//Return the member names and types in the specified stream and member
//The names and types are returned in pair, such as "MemberOne int32 MemberTwo float"

showMetadata -query -stream "StreamOne" -member "MemberOne" -dataType "int32" -method;
//Return the visualization method of the visualized StreamOne and MemberOne

showMetadata -query -stream "StreamOne" -member "MemberOne" -dataType "int32" -listValidMethods;
//Return the valid visual methods of the activated stream and member that can be set

showMetadata -query -stream "StreamOne" -member "MemberOne" -dataType "int32" -range;
//Return the current range of visible metadata

showMetadata -query -stream "StreamOne" -member "MemberOne" -dataType "int32" -auto;
//Return the current state of the auto flag