SubRollout is a Subclass of RolloutControl. All Rollout User-Interface Controls Common Properties and Rollout User-Interface Controls Common Layout Parameters should apply.

Description

A UI item which you can place rollouts into. No caption is displayed for the UI item. On right side of the UI item, a scrollbar is displayed if the height of the rollout(s) in the item is greater than the height of the item.

You can override the auto resize setting for a SubRollout by specifying autoLayoutOnResize:<boolean> when creating the SubRollout, otherwise it inherits this setting from the parent rollout. Available in 3ds Max 2019 and higher. You can also set scrollbar settings using scrollBar: <on|off|#on|#off|#asNeeded>, where the default is #asNeeded..

Properties

.rollouts

The rollouts installed in the SubRollout control using AddSubRollout (see notes below). Read-only. The names of the installed rollouts are exposed as read-only properties.

Notes on common UI item properties

.caption

None displayed. Read/write.

.text

None displayed. Read/write.

.enabled

Setting has no effect. Always set to true. Read/Write.

.pos

The position of the UI item in the rollout. Read/write.

.align

UI item alignment. Creation only property.

.offset

UI item offset. Creation only property.

.width

Sets the width of the subrollout. Accessible as a property of the UI item.

.height

Sets the height of the subrollout. Accessible as a property of the UI item.

.across

Number of UI items across. Creation only parameter.

Associated Methods

addSubRollout <subrollout> <rollout> [rolledUp:<boolean>]

Adds the rollout to the subrollout. Always returns ok.

removeSubRollout <subrollout> <rollout>

Removes the rollout from the subrollout. Always returns ok.

EXAMPLE

   rollout test "test" height:200 autoLayoutOnResize:true scrollBar:#asNeeded
   (
       subrollout test1 "test1"
       subrollout test2 "test2"
   )
   rollout test1a "test1a"
   (
       spinner test1as "test1as"
   )
   rollout test1b "test1b"
   (
       spinner test1bs "test1bs"
   )
   createdialog test
   AddSubRollout test.test1 test1a
   AddSubRollout test.test1 test1b
   test.test1.height += 100
   test.test2.pos += [0,100]
   rollout test2a "test2a"
   (
       spinner test2as "test2as"
   )
   AddSubRollout test.test2 test2a
   test.test2.height += 50

Changing the height of a subRollout does not change the position of any UI items below it.