BeginFileDrop イベント(ActiveX)

メイン アプリケーション ウィンドウにファイルがドロップされたときに開始されます。

サポートされているプラットフォーム: Windows のみ

構文と要素

VBA:

object.BeginFileDrop(FileName, Cancel)

object

タイプ: Application

有効なコンテナ オブジェクトを評価するオブジェクト式この場合、有効なコンテナはアプリケーションだけです。

FileName

タイプ: 文字列; ハンドラへの入力

メイン アプリケーション ウィンドウにドロップされたファイルの名前

Cancel

タイプ: ブール型; ハンドラからの出力

• True: 図面のロードを中止します。
• False: 図面のロードの続行を許可します。

注意

モーダル ダイアログが表示されている間、イベントは発生しません。

例

VBA:

Public WithEvents ACADApp As AcadApplication    ' Use with Application Event Examples
Sub Example_AcadApplication_Events()
    ' This example intializes the public variable (ACADApp) which will be used
    ' to intercept AcadApplication Events
    '
    ' The VBA WithEvents statement makes it possible to intercept an generic object
    ' with the events associated with that object.
    '
    ' Before you will be able to trigger any of the AcadApplication events,
    ' you will first need to run this procedure.
    
    ' We could get the application from the ThisDocument object, but that would
    ' require having a drawing open, so we grab it from the system.
    Set ACADApp = GetObject(, "AutoCAD.Application.20")
End Sub

Private Sub ACADApp_BeginFileDrop(ByVal FileName As String, Cancel As Boolean)
    ' This example intercepts an Application BeginFileDrop event.
    '
    ' This event is triggered when a drawing file is dragged into AutoCAD.
    '
    ' To trigger this example event:
    '     1) Make sure to run the example that initializes
    '     the public variable (named ACADApp) linked to this event.
    '
    '     2) Drag an AutoCAD drawing file into the AutoCAD application from either
    '     the Windows Desktop or Windows Explorer

    ' Use the "Cancel" variable to stop the loading of the dragged file, and the "FileName"
    ' variable to notifiy the user which file is about to be dragged in.
    If MsgBox("AutoCAD is about to load " & FileName & vbCrLf & _
              "Do you want to continue loading this file?", vbYesNoCancel + vbQuestion) <> vbYes Then
        Cancel = True
    End If
End Sub

Visual LISP:

Not available