スクリプト SimpleMeshMod プラグイン

3ds Max 2016 の新機能 : SimpleMeshMod プラグインは、取り込みメッシュのトポロジを変更し、修正結果を出力できるジオメトリモディファイヤです。

類似したモディファイヤの例として、ミラーおよびシンメトリがあります。

これらの種類のモディファイヤには modifyMesh ハンドラが必要になります。内部のメッシュ値には、モディファイヤの TriMesh が含まれています。取り込み TriMesh 値に設定されているため、修正結果を生成するために新しい TriMesh 値に設定できます。

内部の owningNode 値には、モディファイヤを適用するノードが含まれています。モディファイヤが複数のノードに渡ってインスタンス化されている場合は、それらの 1 つのみにアクセスできます。

SimpleMeshMod プラグインは、スクリプト化された Geometry プラグインと同様に動作しますが、新しい Geometry オブジェクトを作成する代わりに、モディファイヤスタックから取り込む TriMesh 上で動作します。

スクリプト化された単純なメッシュモディファイヤプラグインを宣言するには、<superclass> を simpleMeshMod として指定します。

スクリプト

plugin simpleMeshMod TestCloneModifier
	name:"TestCloneMod"
	classID:#(0x3a4087e9, 0x2c2fdff7)
	category:"MXS Help"
(
	parameters main rollout:params
	(
		nCopies ui:spn_nCopies default:2 type:#integer animatable:true
		X_Offset ui:spn_X_Offset default:10 type:#float animatable:true
		Y_Offset ui:spn_Y_Offset default:10 type:#float animatable:true
		Z_Offset ui:spn_Z_Offset default:10 type:#float animatable:true
	) 

	rollout params "Parameters"
	(
		spinner spn_nCopies "# Copies:" range:[1, 1000, 1] type:#integer
		spinner spn_X_Offset "X Offset:" range:[-1000, 1000, 1] type:#float
		spinner spn_Y_Offset "Y Offset:" range:[-1000, 1000, 1] type:#float
		spinner spn_Z_Offset "Z Offset:" range:[-1000, 1000, 1] type:#float
	) 

	on modifyMesh do
	(
		local inMesh = copy mesh --make a copy of the incoming mesh
		for n = 2 to nCopies do --repeat N-1 times 
		(
			local currentMesh = copy inMesh --copy the incoming mesh value
			meshop.moveVert currentMesh #{1..currentMesh.numverts} ([X_Offset,Y_Offset,Z_Offset]*(n-1))
			mesh = mesh + currentMesh --accummulate the moved value into the output mesh
		)
	)
)

上の例では、単純な線形クローンモディファイヤを実装します。これには、作成するコピーの数と 3 軸それぞれに沿ったオフセットの 4 つのパラメータが含まれます。

on modifyMesh do ハンドラは、モディファイヤ出力を更新する必要がある場合に呼び出されます。内部メッシュ値は、スタックから取り込む TriMesh に設定されます。スクリプトはこの TriMesh のローカルコピーを作成します。次に、N-1 回ループしてコピーされた TriMesh をコピーし、コピー数から 1 を引いた数で乗算されたオフセット値に応じて、すべての頂点を移動します。最後に、取り込みメッシュの結果として生じるオフセットコピーは、内部メッシュ値に追加されます。ハンドラの最後では、元の TriMesh と 1 つにまとめられたすべてのコピーがメッシュ値に含まれます。

スクリプト SimpleMeshMod プラグイン

関連事項