新しいスクリプト定義アニメーション コントローラ プラグイン

plugin FloatController FloatController_example
name:"FloatController Example"
classID:#(0x47db14fe, 0x4e9b5f90)
(
	local first = true -- used for debug tracing of 'commit' handling
	local useCachedValue = false -- set when have SetValue with commit == false
	local cachedValue = undefined -- set when have SetValue with commit == false
	local inMouseCycle = false -- true when within mouseCycleStarted/mouseCycleCompleted
	local inMouseCycleControllerAssigned = false -- true when controller assigned within mouseCycleStarted/mouseCycleCompleted
	local inMouseCycleSetValue = false -- true when setValue w/o holdRestore occurred within mouseCycleStarted/mouseCycleCompleted
	
	parameters pblock rollout:params
	(
		value type:#float animatable:true ui:value
		valueController type:#maxobject
	)
	rollout params "FloatController Test Parameters"
	(
		Spinner value "Value:" 
	)
	on getValue do 
	(
		format "getValue - useCachedValue: %; value: %; cachedValue: %\n" useCachedValue value cachedValue
		if useCachedValue then cachedValue else value
	)
	on setValue val relVal commit do 
	(
		format "setValue - val: %; commit: %; useCachedValue: %; value: %; cachedValue: %\n" val commit useCachedValue value cachedValue
		if not commit and first do
		(
			print (CaptureCallStack())
			first = false
			messagebox "setValue called with commit = false - see listener for stack trace"
		)
		if commit then
		(
			useCachedValue = false
			cachedValue = undefined
			if inMouseCycle do
				inMouseCycleSetValue = true
			value = val
		)
		else
		(
			useCachedValue = true
			cachedValue = val
		)
		SetControllerValue valueController val commit #absolute
	)
	on commitValue do
	(
		format "commitValue - useCachedValue: %; value: %; cachedValue: %\n" useCachedValue value cachedValue
		if first do
		(
			print (CaptureCallStack())
			first = false
			messagebox "commitValue called - see listener for stack trace"
		)
		useCachedValue = false
		value = cachedValue
		cachedValue = undefined
		CommitControllerValue valueController
	)
	on restoreValue do
	(
		format "restoreValue - useCachedValue: %; value: %; cachedValue: %\n" useCachedValue value cachedValue
		if first do
		(
			print (CaptureCallStack())
			first = false
			messagebox "restoreValue called - see listener for stack trace"
		)
		useCachedValue = false
		cachedValue = undefined
		RestoreControllerValue valueController
	)
	on mouseCycleStarted do 
	(
		format "mouseCycleStarted - holding: %; value.controller: %\n" (theHold.Holding()) value.controller
		inMouseCycle = true
		inMouseCycleControllerAssigned = false
	)
	on mouseCycleCompleted do 
	(
		format "mouseCycleCompleted - holding: %; value.controller: %\n" (theHold.Holding()) value.controller
		inMouseCycle = false
		inMouseCycleControllerAssigned = false
	)
	on holdBegin do 
	(
		format "holdBegin\n" 
		if inMouseCycle and animateMode and value.controller == undefined and (currenttime != 0) do
		(
			inMouseCycleControllerAssigned = true
			with undo off value.controller = NewDefaultFloatController()
		)
	)
	on holdEnd do 
	(
		format "holdEnd - inMouseCycleControllerAssigned: %; inMouseCycleSetValue: %\n" inMouseCycleControllerAssigned inMouseCycleSetValue
		if inMouseCycleControllerAssigned and not inMouseCycleSetValue do
			with undo off value.controller = undefined
	)
	on holdRestore do 
	(
		format "holdRestore\n" 
		if inMouseCycle do
			inMouseCycleSetValue = false
	)
	on holdRedo do format "holdRedo\n" 

	on create do
	(
		valueController = NewDefaultFloatController()
		isLeaf=true
	)
)
/*  Test case:
t = teapot isselected:true
t.radius.controller = FloatController_test()
t.pos.controller.x_position.controller = FloatController_example()
*/

plugin FloatController FloatController_simplified_example
name:"Simplified FloatController Example"
usePBValidity:false -- false because time dependent
classID:#(0xc1dbcd6, 0x70ecb08a)
(	
	parameters pblock rollout:params
	(
		offset_value type:#float animatable:true ui:offset_value
  valueController type:#maxobject subAnim:true
	)
	rollout params "FloatController Test Parameters"
	(
		Spinner offset_value "Offset Value:" range:[0, 1e9, 40]
	)
	on getValue do 
	(
		valueController.value +offset_value + currentTime as integer / framerate
	)
	on setValue val relVal commit do 
	(
		val -= ( offset_value+ currentTime as integer / framerate)
		SetControllerValue valueController val commit #absolute
	)	
	on create do
	(
		valueController = NewDefaultFloatController()
		isLeaf=true
	)
)
/*  Test case:
t = teapot isselected:true
t.radius.controller = c = FloatController_simplified_example()
c.isKeyable = true
c.isleaf = false
*/

plugin Point3Controller Point3Controller_example
name:"Point3Controller Example"
classID:#(0x47db14ff, 0x4e9b5f9f)
(
	parameters pblock 
	(
		offset_value type:#point3 animatable:true 
		valueController type:#maxobject subAnim:true
	)
	on getValue do 
	(
		valueController.value + offset_value
	)
	on setValue val relVal commit do 
	(
		val -= offset_value
		SetControllerValue valueController val commit #absolute
	)

	on create do
	(
		valueController = NewDefaultPoint3Controller()
		isLeaf=true
	)
)
/*  Test case:
t = teapot isselected:true
t.material = standard diffusemap:(cellular())
t.material.diffusemap.coords.offset.controller = Point3Controller_example()
c = t.material.diffusemap.coords.offset.controller
meditmaterials[1] = t.material.diffusemap
max mtledit
t.pos.controller = Point3Controller_example()  -- will give: -- Runtime error: Incompatible controller type for property: position
*/

plugin Point4Controller Point4Controller_example
name:"Point4Controller Example"
classID:#(0x47db14ff, 0x4e9b5f9f)
(
	parameters pblock 
	(
		offset_value type:#point4 animatable:true 
		valueController type:#maxobject subAnim:true
	)
	on getValue do 
	(
		valueController.value + offset_value
	)
	on setValue val relVal commit do 
	(
		val -= offset_value
		SetControllerValue valueController val commit #absolute
	)

	on create do
	(
		valueController = NewDefaultPoint4Controller()
		isLeaf=true
	)
)
/*  Test case:
c = Point4Controller_example()
at time 100 with animate on c.offset_value =[100,200,300,400]
slidertime = 50f
c.offset_value 
c.value += [10,20,30,40]
c.offset_value 
c.value 
c.valueController.value
*/

plugin ColorController ColorController_example
name:"ColorController Example"
classID:#(0x47db14ba, 0x4e9b5f9f)
(
	parameters pblock 
	(
		offset_value type:#color animatable:true 
		valueController type:#maxobject subAnim:true
	)
	on getValue do 
	(
		valueController.value + offset_value
	)
	on setValue val relVal commit do 
	(
		val -= offset_value
		SetControllerValue valueController val commit #absolute
	)
	on create do
	(
		valueController = NewDefaultColorController()
		isLeaf=true
	)
)
/*  Test case:
t = teapot isselected:true
t.material = standard ()
t.material.diffuse.controller = ColorController_example()
c = t.material.diffuse.controller
meditmaterials[1] = t.material
max mtledit
*/

plugin PositionController PositionController_example
name:"PositionController Example"
classID:#(0x47db14fa, 0x4e9b5f9f)
(
	parameters pblock 
	(
		offset_value type:#point3 animatable:true 
		valueController type:#maxobject subAnim:true
	)
	on getValue do 
	(
		res = valueController.value + offset_value
		res
	)
	on setValue val relVal commit do 
	(
		val -= offset_value
		format "committing val: %\n" val
		SetControllerValue valueController val commit #absolute
	)
	
	on create do
	(
		valueController = NewDefaultPositionController()
		isLeaf=true
	)
)

/*  Test case:
t = teapot isselected:true
t.pos.controller = PositionController_example()
c = t.pos.controller 

*/

plugin RotationController RotationController_example
name:"RotationController Example"
classID:#(0x47db14ac, 0x4e9b5f9f)
(
	parameters pblock 
	(
		offset_value type:#matrix3 animatable:true 
		valueController type:#maxobject subAnim:true
	)
	on getValue do 
	(
		res = valueController.value + offset_value.rotationpart
		res
	)
	on setValue val relVal commit do 
	(
		val -= offset_value.rotationpart
		SetControllerValue valueController (val as matrix3) commit #absolute
	)

	on create do
	(
		valueController = NewDefaultRotationController()
		isLeaf=true
	)
)

/*  Test case:
t = teapot isselected:true 
t.rotation.controller = RotationController_example()
c = t.rotation.controller 
*/

plugin ScaleController ScaleController_example
name:"ScaleController Example"
classID:#(0x7fa4db14, 0x4e5f9b9f)
(
	parameters pblock 
	(
		offset_value type:#point3 animatable:true 
		valueController type:#maxobject subAnim:true
	)
	on getValue do 
	(
		res = valueController.value + offset_value
		res
	)
	on setValue val relVal commit do 
	(
		val -= offset_value
		SetControllerValue valueController val commit #absolute
	)

	on create do
	(
		valueController = NewDefaultScaleController()
		isLeaf=true
	)
)

/*  Test case:
t = teapot isselected:true
t.scale.controller = ScaleController_example()
c = t.scale.controller 
c.value = [.9,.9,.9]

*/

plugin TransformController TransformController_example
name:"TransformController Example"
classID:#(0x47db1cad, 0x4e9b5f9c)
(
	parameters pblock 
	(
		offset_value type:#matrix3
		valueController type:#maxobject subAnim:true
	)
	on getValue do 
	(
		res = valueController.value * offset_value
		res
	)
	on setValue val relVal commit do 
	(
		val = val * inverse offset_value
		SetControllerValue valueController val commit #absolute
	)
	on create do
	(
		valueController = NewDefaultMatrix3Controller()
		isLeaf=true
	)
)

/*  Test case:
t = teapot isselected:true
t.transform.controller = TransformController_example()
c = t.transform.controller 

at time 100 c.value
c.value = matrix3 1


*/