[トラックビュー選択](Track View Pick)ダイアログボックス

[トラックビュー選択](Track View Pick)ダイアログボックスには、3ds Max シーンの階層が[トラックビュー]( Track View)と同じ手法で表示されます。ユーザは、このダイアログから 1 つ以上の項目を選択できます。[トラックビュー選択](Track View Pick)ダイアログボックスは次のメソッドによって表示されます。

trackView.pickTrackDlg [#multiple][<filter function>] [options:<integer>]

このメソッドは[トラックビュー選択](Track View Pick)ダイアログボックスを表示し、ユーザがトラックを選択して[OK]をクリックしたときには TrackViewPick 値、[キャンセル](Cancel)をクリックしたときには undefined を返します。

オプションの #multiple 引数を渡した場合は、ダイアログボックスで複数のトラックを選択でき、単独の値ではなく TrackViewPick 値の配列が返されます。

オプションの filter_function を指定すると、それぞれのトラックが TrackViewPick 値として関数に渡されます。関数が true を返す場合は、[トラックビュー選択](Track View Pick)ダイアログボックスでトラックを選択できます。

オプションのキーワード引数 options : が指定された場合、整数値のビットは[トラックビュー選択](Track View Pick)ダイアログボックスに表示される内容を定義します。各ビットの定義内容は次のとおりです。

各ビットの定義内容は次のとおりです。

1: turn on display of animated tracks only
2: turn off display of node Visibility track
3: turn on display of only selected nodes
4: turn off display of World Space Modifiers
5: turn off display of Object Space Modifiers
6: turn off display of node Transform track
7: turn off display of node base object
8: turn off display of controller types
9: turn off display of note tracks
10: turn off display of the sound track
11: turn off display of maps in materials
12: turn off display of material parameters
13: turn on display of hidden nodes
14: turn off display of hierarchy
15: turn off display of non-keyable tracks
16: turn off display of nodes
17: turn off display of geometry nodes
18: turn off display of shape nodes
19: turn off display of light nodes
20: turn off display of camera nodes
21: turn off display of helper nodes
22: turn off display of warp nodes
23: turn off display of position controllers
24: turn off display of rotation controllers
25: turn off display of scale controllers
26: turn off display of bone nodes
27: set focus to first selected node found

例:

theInt = 0 
theInt = bit.set theInt 1 true --animated tracks only
theInt = bit.set theInt 3 true --display selected nodes only
theInt = bit.set theInt 10 true --hide sound track
theTrack = trackView.pickTrackDlg options:theInt --open dialog

また、次の関数を使用すると、上で説明されているフラグに従い、bitarray をビットセットを持つ整数にすることができます。結果の整数は、名前付き options : パラメータに渡すことができます。

fn bitArrayToInt theBitArray = (
local theInt = 0
for i in theBitArray do theInt = bit.set theInt i true
theInt
)
theInt =bitArrayToInt #{1,3,10}
theTrack = trackView.pickTrackDlg options:theInt

TrackViewPick: Value

TrackViewPick クラスのインスタンスは[トラックビュー選択](Track View Pick)ダイアログボックスでの選択結果を格納します。TrackViewPick 値には次のプロパティがあります。

<trackViewPick>.name : string

[トラックビュー選択](Track View Pick)ダイアログボックスに表示される選択項目の名前です。

<trackViewPick>.anim : subAnim

ユーザが選択した項目の subAnim です。

<trackViewPick>.client : MAXWrapper

ユーザが選択した項目の subAnim の所有者です。所有者が MAXWrapper のサブクラスの場合は所有者の MAXWrapper 値が返されます。それ以外の場合には undefined 値が返されます。

<trackViewPick>.subNum: integer

client 内の anim の subAnim インデックス。

例:

-- Create a sphere, apply a bend modifier and execute:
s=sphere()
b=bend()
addmodifier $Sphere001 b
tvp=trackview.pickTrackDlg()
-- pick objects->Sphere01->Modified object->Bend->Angle
tvp.anim -- returns SubAnim:Angle
tvp.client -- returns Bend:Bend
tvp.subNum -- returns 3
tvp.name -- returns "Angle"
tvp.client[tvp.subNum] -- returns SubAnim:Angle

[トラック ビュー選択](Track View Pick)ダイアログ ボックス

TrackViewPick: Value

[トラックビュー選択](Track View Pick)ダイアログボックス