TextureObjMask : textureMap

TextureObjMask - superclass: textureMap; super-superclass:material - 13:0 - classID: #(1398407114L, 2770506888L)

3ds Max 2017 の新機能 : このテクスチャマップはプリミティブコントロールオブジェクトに基づいてさまざまなテクスチャを適用できます(平面の上/下、またはボックスや球の内側/外側)。

コンストラクタ:

TextureObjMask...

プロパティ:

<TextureObjMask>.object     UndefinedClass    default: undefined   --  node

テクスチャマップカラーの分布を定義するコントロールオブジェクトを取得/設定します。

有効なオブジェクトは平面(上/下)、ボックスまたは球(内側/外側)です。

<TextureObjMask>.color0     Color    default: (color 0 0 0)   --  animatable; RGB color; Controller Scaling: ([1,1,1] : (color 255 255 255))

上/内側のカラーを取得/設定します。

<TextureObjMask>.subtex0     UndefinedClass    default: undefined   --  texturemap; SubMat0

上/内側のテクスチャマップを取得/設定します。

<TextureObjMask>.map1Enabled     BooleanClass    default: true   --  boolean; Map0Enable

上/内側のテクスチャマップの有効な状態を取得/設定します。

<TextureObjMask>.color1     Color    default: (color 255 255 255)   --  animatable; RGB color; Controller Scaling: ([1,1,1] : (color 255 255 255))

下/外側のカラーを取得/設定します。

<TextureObjMask>.subtex1     UndefinedClass    default: undefined   --  texturemap; SubMat1

下/外側のテクスチャマップを取得/設定します。

<TextureObjMask>.map2Enabled     BooleanClass    default: true   --  boolean; Map1Enable

下/外側のテクスチャマップの有効な状態を取得/設定します。

<TextureObjMask>.transitionrange     Float    default: 1.0   --  animatable; float

[トランジションの範囲](Transition Range)値を取得/設定します。

<TextureObjMask>.transitionbias     Float    default: 0.0   --  animatable; float

[トランジションのバイアス](Transition Bias)値を取得/設定します。

<TextureObjMask>.displaceamount     Float    default: 1.0   --  animatable; float

[トランジションのディスプレイスメントの量](Transition Displacement Amount)値を取得/設定します。

<TextureObjMask>.displacetex     UndefinedClass    default: undefined   --  texturemap

[トランジションのディスプレイスメント](Transition Displacement)テクスチャマップを取得/設定します。

<TextureObjMask>.displaceEnabled     BooleanClass    default: true   --  boolean; DisplaceEnable

[トランジションのディスプレイスメント](Transition Displacement)テクスチャマップの有効な状態を取得/設定します。

<TextureObjMask>.coords     StandardXYZGen    default: MtlBase:Placement   --  maxObject; Coordinates; SubAnim

既定の座標プロパティについては、XYZGenClass を参照してください。

例:

(
resetMaxFile #noprompt --reset the scene

local s = sphere radius:50 segs:32 --create a sphere (note that geosphere is NOT supported!)
local p = plane width:200 length:200 --create a plane

local tom = TextureObjMask() --create a object mask texture 
tom.object = s --assign the sphere as the control object of the texture

local ct = cellular() --create a cellular map
ct.cellColor = red --set the 3 colors of the map to bright colors
ct.divColor1 = yellow
ct.divColor2 = blue
tom.subtex0 = ct --assign the cellular map to the Outside texture

tom.subtex1 = noise size:5.0 --assign a Noise to the Inside texture
tom.transitionrange = 25.0 --set the Transition range to more than zero to create a smooth transition

local pmat = standard() --create a standard material for the plane
pmat.diffusemap = tom --assign the texture to the diffuse map slot
p.material = pmat --assign the material to the plane

local smat = standard diffuse:red --create a standard material for the sphere
s.material = smat --assign it to the sphere
smat.opacity = 25.0 --set it to 1/4 opacity
smat.wire = true --set the material to wire so we can peek inside the sphere

meditMaterials[1] = pmat --set the first slot of the Material Editor to the plane's material
render() --render the scene
)