Interface: maxOps

Version and License Info

Back To Topic Navigation

Properties:

maxOps.IsRenderActive : boolean : Read 

Returns True if the renderer is active.

Available in 3ds Max 2016 and higher.

maxOps.productAppID: enum : Read 		

productAppID enums: {#max} 	 

Returns the application ID.

The enum value returned is:

#max - 3ds Max

maxOps.productID : enum : Read   

productID enums: {#3dsMax} 

Available prior to 3ds Max 2017. Returns the 3ds Max "flavour".

The enum value returned is:

#3dsMax - 3ds Max Entertainment Version

maxOps.productVersion : enum : Read 

productVersion enums: {#productVersionDevel|#productVersionTrial|#productVersionOrdinary|#productVersionEdu|#productVersionNFR} 

Available prior to 3ds Max 2017. Returns the Product Version type.

The enum values returned are as follows:

#productVersionDevel - debug build, or licensed in-house

#productVersionTrial - trial license

#productVersionOrdinary - commercial license

#productVersionNFR - not for resale

#productVersionEdu - educational or student license

maxOps.licenseBehavior : enum : Read 

licenseBehavior enums: {#licenseBehaviorPermanent|#licenseBehaviorExtendable|#licenseBehaviorNonextendable} 

Available prior to 3ds Max 2017. Returns the License Behavior.

The enum values returned are as follows:

#licenseBehaviorPermanent - permanent license, or hardware lock

#licenseBehaviorExtendable - term license, can be extended

#licenseBehaviorNonextendable - term license, cannot be extended

maxOps.licenseDaysLeft : integer : Read 

Available prior to 3ds Max 2017. Its return value is an integer indicating the number of full days left in the term of the license. A value of 0 means that today is the last day of validity. For permanent licenses, a fixed value is returned indicating greater than 10 years are left.

maxOps.isNetworkLicense 

The property is read-only with a boolean value: true means a network license, and false means a local license.

--This example displays the values of your Cdilla license:
rollout CdillaOPS "License Properties" width:220 height:270
(
groupBox grp1 "License Values" pos:[18,18] width:180 height:265
button btn5 "Days until Expiration" pos:[50,45] width:119 height:18
editText edt5 "" pos:[50,75] width:119 height:18
button btn6 "License Version" pos:[50,105] width:119 height:18
editText edt6 "" pos:[50,135] width:119 height:18
button btn7 "License Behavior" pos:[50,165] width:119 height:18
editText edt7 "" pos:[50,195] width:119 height:18
button btn8 "Hardware Lock ID" pos:[50,225] width:119 height:18
editText edt8 "" pos:[50,255] width:119 height:18
on btn5 pressed do
(
edt5.text = (maxOps.licenseDaysLeft as string)
)
on btn6 pressed do
(
version = maxOps.productVersion as string
edt6.text = substring version 15 version.count
)
on btn7 pressed do
(
version = maxOps.licenseBehavior as string
edt7.text = substring version 16 version.count
)
on btn8 pressed do
edt8.text = (hardwarelockid as string)
)
rof = newRolloutFloater "License Status" 230 380
addRollout CdillaOPS rof

Methods:

maxOps.isFeatureLicensed <integer>featureNumber 

Returns true if the given feature is licensed, false otherwise.

Trackbar, Controllers

Back To Topic Navigation

Properties:

maxOps.trackbar : Interface : Read 

Contains the Trackbar Interface.

maxOps.overrideControllerRangeDefault : boolean : Read|Write 

When set to true, new procedural controllers that normally require a range will be set to infinite range. When set to false (default behavior prior to 3ds Max 8), the range of such controllers will be set explicitly to the current animation range, causing the controllers to stop updating after the last frame of the range if the scene animation range is increased later. Available in 3ds Max 8 and higher.

maxOps.springQuickEditMode : boolean : Read|Write 

Get/set Spring Quick Edit mode on and off. Corresponds to the checkbox in the Animation tab of the Preferences dialog.

maxOps.springRollingStart : integer : Read|Write 

Get/set the Spring Controller's Rolling Start value. Corresponds to the Rollback value in the Animation tab of the Preferences dialog.

Methods:

maxOps.getTrackBar() 

Returns the interface to the trackbar. See Trackbar Interface for details.

Progressive Mode

Back To Topic Navigation

Properties:

maxOps.inProgressiveMode : boolean : Read 

Returns true if 3ds Max is in Progressive mode, false otherwise.

When a time sequence of matrices is computed and has to be assigned to the transformation matrix of a node that employs the standard PRS controller and the standard Euler XYZ controller for the rotation, we can achieve a better animation result if the euler angles for the current frame are calculated based on the angles from the previous frame. The Progressive Mode tells the Euler controller to derive angles based on the previous frame. It is assumed that in this mode, the node transformation is set in strictly forward time order.

Also, see beginProgressiveMode() and endProgressiveMode() methods below.

Methods:

<void>maxOps.beginProgressiveMode() 

Enables Progressive mode. See also maxOps.inProgressiveMode property above.

<void>maxOps.endProgressiveMode() 

Disables Progressive mode. See also maxOps.inProgressiveMode property above.

Delete Animation

Back To Topic Navigation

Methods:

<void>deleteSelectedAnimation() 

Deletes the selected animation.

Ribbon

Back To Topic Navigation

Methods:

<boolean>maxOps.isRibbonSupportEnabled()

Returns true if the ribbon is supported, false otherwise. The ribbon may be disabled in the 3dsmax.ini file, under the section "Performance", by setting the "DisableRibbon" key to 1. Available in 3ds Max 2018 and higher.

Create Tab

Back To Topic Navigation

Properties:

maxOps.autoGrid : boolean : Read|Write 

Enable/Disable the AutoGrid option.

maxOps.startNewShapeLock : boolean : Read|Write 

Enable/Disable the Start New Shape option checkbox.

Methods:

<void>startNewShape() 

Start the creation of a new Shape.

Hierarchy Tab

Back To Topic Navigation

Properties:

maxOps.pivotMode : enum : Read|Write 

pivotMode enums: {#none | #pivotOnly | #objectOnly | #hierarchyOnly} 

This property corresponds to the pivot buttons in the Pivot subpanel of the Hierarchy Panel.

Motion Tab > Motion Paths

Back To Topic Navigation

Properties:

maxOps.trajectoryMode : bool : Read|Write 					 

When set to true , the Hierarchy tab of the Command Panel will be switched to Motion Paths mode.

When set to false , the Hierarchy tab of the Command Panel will be switched to Parameters mode.

If the Command Panel is not in the Hierarchy tab, it will be switched to it automatically.

Available in 3ds Max 2008 and higher.

maxOps.trajectoryKeySubMode : bool : Read|Write 				  

When set to true , the Motion Paths mode will be switched to Key Sub-Object mode.

If the Command Panel is not in the Hierarchy tab, it will be switched to it automatically.

If the Hierarchy has not been set to Trajectories mode by setting maxops.trajectoryMode=true or by manually switching with the mouse , it will be set to Trajectories mode automatically.

Available in 3ds Max 2008 and higher.

maxOps.trajectoryAddKeyMode : bool : Read|Write 				

When set to true, the Add Key mode in the Trajectories rollout of the Hierarchy tab of the Command Panel will be turned on. When false, it will be turned off.

If the Command Panel is not in the Hierarchy tab, it will be switched to it automatically.

If the Hierarchy has not been set to Trajectories mode by setting maxops.trajectoryMode=true or by manually switching with the mouse , it will be set to Trajectories mode automatically.

If the Trajectories mode is not in Key Sub-Object mode by setting maxops.trajectoryKeySubMode=true or by manually switching with the mouse, the Sub-Object mode will be set automatically.

Available in 3ds Max 2008 and higher.

maxOps.trajectoryPathGradation: enum : Read|Write

trajectoryPathGradation enums: {#speed|#wirecolor|#uicolor|#none}

Sets the gradation mode of the displayed motion paths. Available in 3ds Max 2018 and higher.

maxOps.selTrajectoryDrawFrameTicks: bool : Read|Write

When set to true, the frame ticks will be displayed along the selected motion paths. Available in 3ds Max 2018 and higher.

maxOps.unselTrajectoryDrawFrameTicks: bool : Read|Write

When set to true, the frame ticks will be displayed along the unselected motion paths. Available in 3ds Max 2018 and higher.

maxOps.unselTrajectoryDrawKeys: bool : Read|Write

When set to true, the keys will be displayed along the unselected motion paths. Available in 3ds Max 2018 and higher.

maxOps.trimTrajectories: bool : Read|Write

When set to true, trims the displayed motion paths. The motion paths are trimmed based on the value of fixedTrimRange. Available in 3ds Max 2018 and higher.

maxOps.fixedTrimRange: bool : Read|Write

When set to true, the motion paths are trimmed based on the frame range, and use the values stored in trimTrajectoriesStart, and trimTrajectoriesEnd. When set to false, the motion paths are trimmed based on the value stored in trimTrajectoriesOffset. Motion path trimming is enabled or disabled based on the value of trimTrajectories. Available in 3ds Max 2018 and higher.

maxOps.trimTrajectoriesOffset: integer : Read|Write

Defines the frame offset applied when trimTrajectories is on, and when fixedTrimRange is set to false. Available in 3ds Max 2018 and higher.

maxOps.trimTrajectoriesStart: integer : Read|Write

Defines the start of the frame range applied when trimTrajectories is on, and when fixedTrimRange is set to false. Available in 3ds Max 2018 and higher.

maxOps.trimTrajectoriesEnd: integer : Read|Write

Defines the end of the frame range applied when trimTrajectories is on, and when fixedTrimRange is set to false. Available in 3ds Max 2018 and higher.

maxOps.drawAllHandles: bool : Read|Write

When set to true, both the keys and the tangents are drawn along the motion path. When set to false, only the keys are displayed. Available in 3ds Max 2018 and higher.

maxOps.drawGradientTicks: bool : Read|Write

When set to true, both the keys and the tangents are drawn along the motion path. When set to false, only the keys are displayed. Available in 3ds Max 2018 and higher.

Methods:

<void>maxOps.deleteSelectedTrajectoryKey() 

Deletes the selected trajectory key. Available in 3ds Max 2008 and higher.

<void>maxOps.breakSelectedKeyTangent() 

Breaks the selected trajectory key's tangent handles. This allows the individual control of the two tangent handles. Available in 3ds Max 2018 and higher.

<void>maxOps.unifySelectedKeyTangent() 

Unifies the selected trajectory key's tangent handles. This allows the movement of one handle to affect the relative position of the other handle. Available in 3ds Max 2018 and higher.

<void>maxOps.setSelectedKeyTangentToAuto() 

Unifies the selected trajectory key's tangent handles, and ensures both tangent handle reside on the same line. Available in 3ds Max 2018 and higher.

Display Tab

Back To Topic Navigation

Properties:

maxOps.hideFrozenObjects : boolean : Read|Write 

Gets/Sets the state of the Hide Frozen Objects checkbox in the Display tab.

Set Key Mode

Back To Topic Navigation

Properties:

maxOps.setKeyMode : boolean : Read|Write 

Get/set the SetKey mode state.

maxOps.setKeySuspend : boolean : Read|Write 

Get/set the SetKey Suspend mode state.

maxOps.setKeyFilters : enum by value array : Read 

setKeyFilters enums: {#all | #position | #rotation | #scale | #ikParams | #objParams | #custAttribs | #modifiers | #materials|#other} 

Always returns the fixed list of the filter names.

maxOps.setKeyNodeSets : String array : Read 

Returns an array of node sets.

maxOps.setKeyNodeSetCurrent : String : Read|Write 

Returns "" if the current setKey node set is "Selected". Setting it to "" sets the current setKey node set to "Selected".

Methods:

<boolean>maxOps.getSetKeyMode() 

This method returns true if Set Key mode is active, false if not active.

maxOps.getSetKeyFilterState <enum>filter 

filter enums: {#position | #rotation | #scale | #ikParams | #objParams | #custAttribs | #modifiers | #materials} 

Returns the state of the specified SetKey filter.

maxOps.setSetKeyFilterState <enum>filter <bool>onOff 

filter enums: {#position | #rotation | #scale | #ikParams | #objParams | #custAttribs | #modifiers | #materials} 

Sets the state of the specified SetKey filter.

-- print SetKey Filters state
for filter in maxops.setKeyFilters do
format "% : %\n" (filter as string) (maxops.getSetKeyFilterState filter)
-- turn all on
for filter in maxops.setKeyFilters do
maxops.setSetKeyFilterState filter true

<void>maxOps.getDefaultTangentType<&enum>dfltInTangentType <&enum>dfltOutTangentType 

dfltInTangentType enums: {#smooth|#linear|#step|#fast|#slow|#custom|#flat} 
dfltInTangentType is Out parameter 
dfltOutTangentType enums: {#smooth|#linear|#step|#fast|#slow|#custom|#flat} 
dfltOutTangentType is Out parameter 

Returns the default In and Out tangent types into the two Out parameters passed by-reference.

Available in 3ds Max 8 and higher.

<void>maxOps.setDefaultTangentType <enum>dfltInTangentType <enum>dfltOutTangentType writeInCfgFile:<boolean> 

dfltInTangentType enums: {#smooth|#linear|#step|#fast|#slow|#custom|#flat} 
dfltOutTangentType enums: {#smooth|#linear|#step|#fast|#slow|#custom|#flat} 
writeInCfgFile default value: true 

Sets the default In and Out tangent types. When writeInCfgFile: is set to true (default), the changes will also be recorded in the configuration file, making them sticky between 3ds Max sessions.

Available in 3ds Max 8 and higher.

maxops.setDefaultTangentType #slow #fast
--> OK
maxops.getDefaultTangentType &inTangent &outTangent
--> OK
inTangent
--> #slow
outTangent
--> #fast

AutoKey Default Key

Back To Topic Navigation

Properties:

maxOps.autoKeyDefaultKeyOn: boolean : Read|Write 

When this option is set to true (default), creating a key in AutoKey mode on a frame other than the one specified by maxops.autoKeyDefaultKeyTime will create a key on the frame specified by maxops.autoKeyDefaultKeyTime with the initial value of the animated property. This is the default behavior of 3ds Max since its first release.

When this option is set to false , no key other than the one on the current frame will be created by the AutoKey feature.

See also preferences.autoKeyDefaultKeyOn for a System Global that exposes the same property.

Available in 3ds Max 2008 and higher.

maxOps.autoKeyDefaultKeyTime : time : Read|Write 

When maxops.autoKeyDefaultOn is set to true , a key will be created automatically on the frame defined by this time value.

NEW in 3ds Max 2017: The value can be set to any valid time value. In versions prior to 3ds Max 2017, the only possible values were 0f and 1f. See also preferences.autoKeyDefaultKeyTime for a System Global that exposes the same property as an integer value.

Available in 3ds Max 2008 and higher.

Paint Selection Brush

Back To Topic Navigation

Properties:

maxOps.paintSelBrushSize : integer : Read|Write 

Get/Set the size of the Paint Selection brush. The Paint Selection is a selection mode accessible through the Selection Region flyout. The value corresponds to the "Paint Selection Brush Size" value under Customize > Preferences > General > Scene Selection. Note that right-clicking the Paint Selection icon in the main toolbar will open the Preferences dialog.

Bitmap Importer

Back To Topic Navigation

Methods:

<bool>maxOps.canImportBitmap <filename>fileName 

Returns true if a bitmap importer is present for the extension in the file name, false otherwise. Does not check to see if the file exists or if it is a valid bitmap file.

Viewport Display

Back To Topic Navigation

Methods:

bool>maxOps.displayActiveCameraViewWithMultiPassEffect() 

If the active view is a Camera view and a multi-pass effect is turned on in the camera's properties, then this function returns true . Otherwise, it does nothing and returns false .

maxOps.setActiveViewportTransparencyDisplay <integer>transparencyLevel 

Takes a single integer argument:

0 - turns off transparency in the active viewport.

1 - sets it to screendoor.

2 - sets it to blended transparency.

<IObject>maxops.getViewportShadingSettings() 

Returns an <IObject:ViewportShadingSettings> object exposing several interfaces related to advanced viewport shading controls.

See Viewport Shading Settings for details.

Available in 3ds Max 2010 and higher.

vss = maxops.getViewportShadingSettings()
<IObject:ViewportShadingSettings>
showInterfaces vss

Custom User Interface

Back To Topic Navigation

Methods:

<bool>maxOps.loadCUIFile <filename>fileName 

Returns true if successful and false otherwise.

Iterative Rendering

Back To Topic Navigation

Properties:

<bool>maxOps.rendUseIterative 

Get/set the Iterative Rendering mode in 3ds Max 2009 and higher.

When set to true , only the current frame will be rendered and no file will be saved to disk.

When set to false , the Render Dialog settings for Time Output and File Saving will be respected (this is the default and the only behavior in releases prior to 3ds Max 2009).

Render Element Manager

Back To Topic Navigation

Methods:

maxOps.GetCurRenderElementMgr() 

Returns the current render element manager.

maxOps.GetRenderElementMgr <enum> 

{#Production|#Draft}

Gets a specific render element manager.

Node Name Suffix Length

Back To Topic Navigation

Properties:

<integer>maxOps.nameSuffixLength 

Controls the number of digits appended as suffix to the name of newly created scene nodes, layers, and others.

Available in 3ds Max 2011 and higher.

Collapse and Clone Nodes

Back To Topic Navigation

Methods:

<bool>maxOps.CollapseNode <node>node <boolean>noWarning 

Collapses the complete modifier stack of the node.

When noWarning is set to true, no prompt will be issued. Returns true if successful and false otherwise.

<bool>maxOps.CollapseNodeTo <node>node <index>modIndex <boolean>noWarning 

Collapses the modifier stack up to the indexed modifier.

The modifiers are counted from top of the stack. All modifiers below and including the specified one will be collapsed.

When noWarning is set to true, no prompt will be issued.

Returns true if successful and false otherwise.

<bool>maxOps.CloneNodes <&node array>nodes offset:<point3> expandHierarchy:<boolean> cloneType:<enum> actualNodeList:<&node array> newNodes:<&node array> 

This method will return true if successful, otherwise it will return false .

<&node array>nodes 

This is the list of nodes that you want to clone. nodes is In parameter.

<&point3>offset 

The positional offset that will be applied to the cloned nodes. offset is In parameter.

expandHierarchy:<boolean> 

expandHierarchy default value: false 

Indicates if children will be cloned in hierarchies.

cloneType:<enum> 

cloneType enums: {#copy|#instance|#reference} 
cloneType default value: #copy

Specifies the clone type - Copy, Instance, or Reference.

 actualNodeList:<&node array> 

actualNodeList default value: #() 

This node array will be filled in with the original nodes to be cloned. The reason for this is that there can be dependencies between nodes that causes other nodes to be added to the list. For example light/camera targets, nodes part of systems, part of groups or expanded hierarchies, and others.

newNodes:<&node array> newNodes default value: #() 

This node array will be filled in with the new cloned nodes. There is a one to one relationship between the nodes returned in the actualNodeList array and the newNodes array.

s=sphere()

-- variables not passed by reference, does not work right
maxops.clonenodes s actualNodeList:a newNodes:b
a --> undefined
b --> undefined

-- variables passed by reference without initializing, works right
maxops.clonenodes s actualNodeList:&c newNodes:&d
c --> #($sphere01)
d --> #($sphere03)

Also note that the first argument type is specified as <&node array>nodes , In parameter. Because it is an In parameter, we know that the method does not change the contents of the array passed, so there is no point in passing this array by reference.

In addition, MAXScript automatically wraps the single argument passed into a temporary array, so we can use s instead of #(s) to supply the node array.

Window/Crossing Selection Type

Back To Topic Navigation

Methods:

maxOps.setSelectionType <boolean>auto <enum>method 

method enums: {#window|#crossing|#leftToRight|#rightToLeft} 

Controls the window/crossing modes of the selection tool.

When the first argument is set to true, it enables the Customize>Preferences>General tab>Auto Window/Crossing By Direction option. The second argument can be either 0 or 1 or the equivalent enums #leftToRight and #rightToLeft.

When the first argument is set to false, it sets the state of the Window/Crossing icon in the Main Toolbar, while disabling the Customize > Preferences > General tab > Auto Window/Crossing By Direction. The second argument can be either 0 or 1 or the equivalent enums #window and #crossing.

In other words,

true 1 : Enables auto Window/Crossing: moving left-to-right is crossing selection

true 0 : Enables auto Window/Crossing: moving right-to-left is crossing selection

false 1 : Disables auto Window/Crossing, turns ON crossing selection

false 0 : Disables auto Window/Crossing, turns OFF crossing selection

The method returns true if successful, false otherwise.

Node Handle

Back To Topic Navigation

Methods:

maxOps.getNodeByHandle <DWORD>handle 

Returns a node associated with a given handle.

Color By ID

Back To Topic Navigation

Methods:

<void>maxOps.colorById <DWORD>id <&color>color 

color is Out parameter   

Returns a specific color for each unique ID passed. The result is written to the Out parameter by reference.

This method is used internally to generate colors representing Material and Object IDs in the respective RenderElements.

Available in 3ds Max 8 and higher.

for i = 0 to 9 do
(
 maxops.colorById i &theColor
 format "ID:% Color:%\n" i theColor
)

ID:0 Color:(color 100 100 100)
ID:1 Color:(color 213 16 100)
ID:2 Color:(color 70 188 100)
ID:3 Color:(color 183 104 100)
ID:4 Color:(color 40 20 100)
ID:5 Color:(color 153 192 100)
ID:6 Color:(color 10 108 100)
ID:7 Color:(color 123 24 100)
ID:8 Color:(color 236 196 100)
ID:9 Color:(color 93 112 100)

Find Nodes

Back To Topic Navigation

Methods:

<void>maxOps.findNodes <&node array>templateNodes <&node array>foundNodes nodePropsToMatch:<&enum array> 

templateNodes is In parameter 
foundNodes is Out parameter 
nodePropsToMatch enums: {#nodePropMaterial|#nodePropLayer} 
nodePropsToMatch default value: #() 
nodePropsToMatch is In parameter 

Finds nodes similar to the ones specified in the template. Optionally, matches material and layer properties.

Available in 3ds Max 2008 and higher.

(
resetMaxFile #noPrompt --reset max file
--create 10 boxes and 10 spheres:
for i = 1 to 10 do box pos:[i*50,0,0]
for i = 1 to 10 do sphere pos:[i*50,100,0]
$Box*.material = standard() --assign standard material to all boxes
$Box001.material = multiMaterial() --change material of first box
--find all objects similar to the Box01 and Sphere01
--that have the same material as the template object
maxOps.findNodes #($Box001,$Sphere001) &foundNodes nodePropsToMatch:#(#nodePropMaterial)
print foundNodes --print the resulting array
)

$Box:Box001 @ [50.000000,0.000000,0.000000]
$Sphere:Sphere001 @ [50.000000,100.000000,0.000000]
$Sphere:Sphere002 @ [100.000000,100.000000,0.000000]
$Sphere:Sphere003 @ [150.000000,100.000000,0.000000]
$Sphere:Sphere004 @ [200.000000,100.000000,0.000000]
$Sphere:Sphere005 @ [250.000000,100.000000,0.000000]
$Sphere:Sphere006 @ [300.000000,100.000000,0.000000]
$Sphere:Sphere007 @ [350.000000,100.000000,0.000000]
$Sphere:Sphere008 @ [400.000000,100.000000,0.000000]
$Sphere:Sphere009 @ [450.000000,100.000000,0.000000]
$Sphere:Sphere010 @ [500.000000,100.000000,0.000000]
OK

Material Editor Mode

Back To Topic Navigation

Properties:

maxOps.mtlDlgMode 

Get/set the Material Editor Mode in 3ds Max 2011 and higher.

If a Material Editor is already open, setting this property immediately switches the Editor to the given mode.

Possible values are:

#basic(0) - Compact Material Editor mode

#advanced(1) - Slate Material Editor mode

See also the MatEditor - Open and Close the Material Editor topic for more related methods.

The maxOps.mtlDlgMode property described above is also available through the MatEditor struct for convenience.

3ds Max Batch Command Line Arguments

Back To Topic Navigation

Properties:

maxOps.mxsCmdLineArgs 

Gets the dictionary of values passed from 3dsmaxbatch.exe in the -mxsString and -mxsValue command-line arguments.

D:<3dsmaxpath>3dsmaxbatch demo_mxscmdline.ms -mxsString string1:"Hello"  -mxsValue value1:"[3,12,22]" -mxsValue value2:"Point3 3 8 2.3"

opts = maxOps.mxsCmdLineArgs

for k in opts.keys do (
	format "% == % class: %\n" k opts[k] (classOf opts[k])
)
-- output:
-- #string1 == Hello class: String
-- #value2 == [3,8,2.3] class: Point3
-- #value1 == [3,12,22] class: Point3

For more information on the 3ds Max Batch command-line arguments, see the 3ds Max Batch help topic.

Available in 3ds Max 2018 Update 4 and higher.