Alembic_Export: ExporterPlugin

Alembic 書き出しプラグインを MAXScript に公開します。3ds Max 2016 以降で使用可能です。

コンストラクタ

Class instances not creatable by MAXScript.

エイリアス:

Alembic_Export
AlembicExport

Alembic_Export インタフェース:

Interface: AlembicExport

プロパティ:

 AlembicExport.CoordinateSystem : enum : Read|Write
CoordinateSystem enums: {#Max|#Maya}

書き出された Alembic ファイルの座標系を設定します。

有効な値は次のとおりです。

#max (既定値) - Z アップ、Autodesk 3dsMax で使用される右手座標系
#Maya - Y アップ、Autodesk Maya で使用される右手座標系

 AlembicExport.ArchiveType : enum : Read|Write
ArchiveType enums: {#HDF5|#Ogawa}

書き出された Alembic ファイルのアーカイブの種類を設定します。

有効な値は次のとおりです。

#HDF5 (既定値) - Alembic バージョン 1.0 の元のストレージフォーマット
#Ogawa - Alembic バージョン 1.5 で導入された改良版ストレージフォーマット

 AlembicExport.ParticleAsMesh : bool : Read|Write

パーティクルシェイプをメッシュとして書き出すかどうかを設定します。

 AlembicExport.CacheTimeRange : enum : Read|Write
   CacheTimeRange enums: {#CurrentFrame|#TimeSlider|#StartEnd}

アニメーションの保存方法を設定します。

有効な値は次のとおりです。

#CurrentFrame (既定) - 現在のフレームを保存します。
#TimeSlider - タイムスライダのアクティブタイムセグメントを保存します。
#StartEnd - [ステップ](Step)で指定した範囲を保存します。

 AlembicExport.StepFrameTime : float : Read|Write

フレームのサンプルレートを設定します。既定では 1.0 フレームおきです。この設定が影響するのは、CacheTimeRange タイプの #TimeSlider および #StartEnd のみです。

 AlembicExport.StartFrameTime : integer : Read|Write

CacheTimeRange が #StartEnd に設定されている場合に、アニメーション範囲の開始フレームを設定します。

 AlembicExport.EndFrameTime : integer : Read|Write

CacheTimeRange が #StartEnd に設定されている場合に、アニメーション範囲の終了フレームを設定します。

 AlembicExport.ShapeName : bool : Read|Write

true に設定した場合は、書き出された各メッシュの名前に文字列「Shape」を追加します。このプロパティは既定で false に設定されています。

メソッド:

メソッドは公開されません。

アクション:

アクションは公開されません。

例

resetMaxFile #noprompt --reset the scene
c = cone() --create a Cone primitive
b = bend() --create a Bend modifier
addModifier c b --add the Bend to the Cone
with animate on (--enable animation
  at time 100 ( --and set on frame 100
    b.angle = 90 --the Bend Angle to 90
    c.pos = [10,20,30] --and move the Cone
  )--end time context
)--end animate on context
AlembicExport.ArchiveType = #hdf5 --force the old file format
AlembicExport.CoordinateSystem = #max --force Z up coordinates
--Export the file without opening the dialog
--The explicit using: argument is not necessary as the export plugin 
--needed will be resolved automatically based on the file extension:
exportFile (GetDir #export +"\\alembictest_hdm5_max.abc") #noPrompt using:AlembicExport

AlembicExport.ArchiveType = #ogawa --force the new file format
AlembicExport.CoordinateSystem = #maya --force Y up coordinates
--Export the file without opening the dialog
--This time we will ommit the explicit using: argument:
exportFile (GetDir #export +"\\alembictest_ogawa_maya.abc") #noPrompt

--RESULT: We now have two files, one using Max Z up and HDF5 storage, 
--and one using Maya Y up and the newer Ogawa storage.

--See the AlembicImport:ImporterPlugin topic for an example
--of importing these files back into 3ds Max.

Alembic_Export: ExporterPlugin

関連事項