Alembic_Import: ImporterPlugin

Alembic 読み込みプラグインを MAXScript に公開します。3ds Max 2016 以降で使用可能です。

3ds Max 2019 の新機能: 2019 では、いくつかのプロパティが追加、削除、または変更されました。

コンストラクタ

Class instances not creatable by MAXScript.

エイリアス:

Alembic_Import
AlembicImport

Alembic_Import インタフェース:

Interface: AlembicImport

プロパティ:

AlembicImport.CoordinateSystem : enum : Read|Write
CoordinateSystem enums: {#Max|#Maya|#ZUp|#YUp}

読み込まれた Alembic ファイルの座標系を設定します。

AlembicImport.ImportToRoot : boolean : Read|Write

Alembic の読み込みオプションの[ルートに読み込み](Import To Root)の状態をコントロールします。

False (既定値)に設定すると、読み込まれた Alembic オブジェクトは Alembic コンテナの親になります。1 つのオブジェクトとして読み込まれた Alembic を変換または選択する場合に便利です。

True に設定すると、読み込まれた Alembic オブジェクトは親を持たないワールドの子になります。

AlembicImport.FitTimeRange : bool : Read|Write

true の場合は、読み込まれた Alembic アニメーションの時間範囲に合わせてシーンの時間範囲を更新します。

AlembicImport.SetStartTime : bool : Read|Write

true の場合は、読み込まれた Alembic アニメーションの開始時間に合わせて現在のシーン時刻を設定します。

AlembicImport.UVs : bool : Read|Write

true の場合は、メッシュの UV マップ チャネルを読み込みます。このグローバル読み込みオプションは、作成された Alembic ノードにローカルにコピーされます。

AlembicImport.Normals : bool : Read|Write

true の場合は、メッシュの法線を読み込みます。このグローバル読み込みオプションは、作成された Alembic ノードにローカルにコピーされます。

AlembicImport.VertexColors : bool : Read|Write

true の場合は、メッシュの頂点カラー マップ 0 を読み込みます。このグローバル読み込みオプションは、作成された Alembic ノードにローカルにコピーされます。

AlembicImport.ExtraChannels : bool : Read|Write

true の場合は、メッシュの追加マップ チャネルを読み込みます。このグローバル読み込みオプションは、作成された Alembic ノードにローカルにコピーされます。

AlembicImport.Velocity : bool : Read|Write

true の場合は、メッシュの頂点速度データを読み込みます。このグローバル読み込みオプションは、作成された Alembic ノードにローカルにコピーされます。

AlembicImport.MaterialIDs : bool : Read|Write

true の場合は、Alembic フェース セットからメッシュのマテリアル ID を読み込みます。このグローバル読み込みオプションは、作成された Alembic ノードにローカルにコピーされます。

AlembicImport.Visibility : bool : Read|Write

true の場合は、ノードの可視性データを読み込みます。このグローバル読み込みオプションは、作成された Alembic ノードにローカルにコピーされます。

AlembicImport.ShapeSuffix : boolean : Read|Write

true に設定した場合、読み込まれたオブジェクトの名前から「Shape」サフィックスが取り除かれます。このプロパティは既定で false に設定されています。

メソッド:

<void>setDefaults()

AlembicImport のすべてのプロパティを既定値にリセットします。

<TSTR by value>Inspect <TSTR by value>alembicFile

<integer>GetNumChildren <TSTR by value>pathToNode

<TSTR by value>GetParent <TSTR by value>pathToNode

<TSTR by value>GetChild <TSTR by value>pathToNode <integer>index

<TSTR by value>GetABCNodeName <TSTR by value>pathToNode

<boolean>IsPropertyNode <TSTR by value>pathToNode

<enum>GetABCNodeType <TSTR by value>pathToPropNode
       GetABCNodeType enums: {#Compound|#Scalar|#Array

<enum>GetABCNodeDataType <TSTR by value>pathToPropNode
       GetABCNodeDataType enums: {#Bool|#Int8|#UInt8|#Int16|#UInt16|#Int32|#UInt32|#Int64|#UInt64|#Float16|#Float32|#Float64|#String|#WString|#Unknown

<integer>GetABCNodeExtent <TSTR by value>pathToPropNode

    <void>CA_AddProperty <enum>location <TSTR by value>alembicObjectPath <TSTR by value>propertyPath
       CA_AddProperty - no automatic redraw after invoked
       location enums: {#Modifier|#BaseObject}

    <void>CA_Build()
       CA_Build - no automatic redraw after invoked 

<void>CA_SetNode <node>node <TSTR by value>alembicFile

    <bool>OA_SetBool <node>node <TSTR by value>name <bool>val
    <bool>OA_SetInt <node>node <TSTR by value>name <integer>val
    <bool>OA_SetFloat <node>node <TSTR by value>name <float>val
    <bool>OA_SetPoint3 <node>node <TSTR by value>name <point3>val
    <bool>OA_SetString <node>node <TSTR by value>name <TSTR by value>val

アクション:

アクションは公開されません。

--This example uses the files created in the 
--AlembicExport:ExporterPlugin topic:  
resetMaxFile #noprompt --reset the scene
AlembicImport.ZUp = true --tell the importer to expect Z up (Max mode)
AlembicImport.ImportToRoot = false --parent to an Alembic Container
importFile (GetDir #export +"\\alembictest_hdm5_max.abc") #noPrompt using:AlembicImport
--RESULT: The loaded Cone matches the original animation

resetMaxFile #noprompt --reset the scene
--note that the importer is still in Max Z up mode
importFile (GetDir #export +"\\alembictest_ogawa_maya.abc") #noPrompt 
--RESULT: The Cone will be imported with the wrong orientation 
--because the file contains Y up data.

resetMaxFile #noprompt --reset the scene
AlembicImport.ZUp = false --tell the importer the file is not Z-up
AlembicImport.ImportToRoot = true --import as Child Of The World
--import the Maya file with Z up disabled:
importFile (GetDir #export +"\\alembictest_ogawa_maya.abc") #noPrompt 
--RESULT: The Cone will now be oriented correctly

pathToParent = AlembicImport.Inspect @"C:\My Documents\helicopter.ABC"

fn getAllChildren pathToParent =
(
    numChildren = AlembicImport.GetNumChildren pathToParent

    for i = 1 to numChildren do
    (
        pathToChild = AlembicImport.GetChild pathToParent (i-1)
        
        // Also possible to get the parent by calling
        // pathToParent = AlembicImport.GetParent pathToChild 
        
        nodeName = AlembicImport.GetABCNodeName pathToChild

        if AlembicImport.IsPropertyNode pathToChild then
        (
            nodeType = AlembicImport.GetABCNodeType pathToChild
            dataType = AlembicImport.GetABCNodeDataType pathToChild
            extent = AlembicImport.GetABCNodeExtent pathToChild
        )

      getAllChildren pathToChild
   )
)

getAllChildren pathToParent

 特に明記されている場合以外は、この作業は、Creative Commons 表示 - 非営利 - 継承 3.0 非移植ライセンス のもと認可を受けています。 Autodesk Creative Commons FAQ (英語版) を参照してください。