Alembic_Export: ExporterPlugin

Alembic 書き出しプラグインを MAXScript に公開します。3ds Max 2016 以降で使用可能です。

コンストラクタ

Class instances not creatable by MAXScript.

エイリアス:

Alembic_Export
AlembicExport

Alembic_Export インタフェース:

Interface: AlembicExport

プロパティ:

3ds Max 2019 の新機能: いくつかのプロパティが名前変更、新規作成、または削除されました。

 AlembicExport.CoordinateSystem : enum : Read|Write
CoordinateSystem enums: {#Max|#Maya|#ZUp|#YUp}

書き出された Alembic ファイルの座標系を設定します。

有効な値は次のとおりです。

• #max (または #ZUp) (既定値) - Z アップ、Autodesk 3dsMax で使用される右手座標系
• #Maya (または #YUp) - Y アップ、Autodesk Maya で使用される右手座標系

 AlembicExport.ArchiveType : enum : Read|Write
ArchiveType enums: {#HDF5|#Ogawa}

書き出された Alembic ファイルのアーカイブの種類を設定します。

有効な値は次のとおりです。

• #HDF5 (既定値) - Alembic バージョン 1.0 の元のストレージ フォーマット
• #Ogawa - Alembic バージョン 1.5 で導入された改良版ストレージ フォーマット

 AlembicExport.ParticleAsMesh : bool : Read|Write

パーティクル シェイプをメッシュとして書き出すかどうかを設定します。

 AlembicExport.AnimTimeRange : enum : Read|Write
   CacheTimeRange enums: {#CurrentFrame|#TimeSlider|#StartEnd}

アニメーションの保存方法を設定します。

有効な値は次のとおりです。

• #CurrentFrame - 現在のフレームを保存します。
• #TimeSlider (既定) - タイム スライダのアクティブ タイム セグメントを保存します。
• #StartEnd - [ステップ](Step)で指定した範囲を保存します。

 AlembicExport.StartFrame : integer : Read|Write

CacheTimeRange が #StartEnd に設定されている場合に、アニメーション範囲の開始フレームを設定します。

 AlembicExport.EndFrame : integer : Read|Write

CacheTimeRange が #StartEnd に設定されている場合に、アニメーション範囲の終了フレームを設定します。

 AlembicExport.ShapeSuffix : bool : Read|Write

true に設定した場合は、書き出された各メッシュの名前に文字列「Shape」を追加します。このプロパティは既定で false に設定されています。

 AlembicExport.SamplesPerFrame : integer : Read|Write	 

AnimTimeRange #TimeSlider および #StartEnd のフレームごとのアニメーション サンプル数を設定します。

 AlembicExport.Hidden : bool : Read|Write	 

true の場合は、非表示のジオメトリを書き出します。

 AlembicExport.UVs : bool : Read|Write	 

true の場合は、メッシュの UV マップ チャネルを書き出します。

 AlembicExport.Normals : bool : Read|Write	 

true の場合は、メッシュの法線を書き出します。

 AlembicExport.VertexColors : bool : Read|Write	 

true の場合は、メッシュの頂点カラー マップ 0 を書き出します。現在の頂点カラーの表示データがこれと異なる場合は、現在の表示データも書き出します。

 AlembicExport.ExtraChannels : bool : Read|Write	 

true の場合は、メッシュの追加マップ チャネル(チャネル 1 より大きいマップ チャネル)を書き出します。

 AlembicExport.Velocity : bool : Read|Write	 

true の場合は、メッシュの頂点およびパーティクルの速度データを書き出します。

 AlembicExport.MaterialIDs : bool : Read|Write	 

true の場合は、メッシュのマテリアル ID を Alembic フェース セットとして書き出します。

 AlembicExport.Visibility : bool : Read|Write	 

true の場合は、ノードの可視性データを書き出します。

 AlembicExport.LayerName : bool : Read|Write	 

true の場合は、ノード レイヤの名前を Alembic オブジェクトのプロパティとして書き出します。

 AlembicExport.MaterialName : bool : Read|Write	 

true の場合は、ジオメトリ ノード マテリアルの名前を Alembic オブジェクトのプロパティとして書き出します。

 AlembicExport.ObjectID : bool : Read|Write	 

true の場合は、ジオメトリ ノードの G-バッファ オブジェクト ID を Alembic オブジェクトのプロパティとして書き出します。

 AlembicExport.CustomAttributes : bool : Read|Write	 

true の場合は、ノードおよびそのモディファイヤのカスタム アトリビュートを Alembic オブジェクトのコンパウンド プロパティに書き出します。

メソッド:

    <void>setDefaults()
       setDefaults - no automatic redraw after invoked

AlembicExport のすべてのプロパティを既定値にリセットします。

アクション:

アクションは公開されません。

resetMaxFile #noprompt --reset the scene
c = cone() --create a Cone primitive
b = bend() --create a Bend modifier
addModifier c b --add the Bend to the Cone
with animate on (--enable animation
  at time 100 ( --and set on frame 100
    b.angle = 90 --the Bend Angle to 90
    c.pos = [10,20,30] --and move the Cone
  )--end time context
)--end animate on context
AlembicExport.ArchiveType = #hdf5 --force the old file format
AlembicExport.CoordinateSystem = #max --force Z up coordinates
--Export the file without opening the dialog
--The explicit using: argument is not necessary as the export plugin 
--needed will be resolved automatically based on the file extension:
exportFile (GetDir #export +"\\alembictest_hdm5_max.abc") #noPrompt using:AlembicExport

AlembicExport.ArchiveType = #ogawa --force the new file format
AlembicExport.CoordinateSystem = #maya --force Y up coordinates
--Export the file without opening the dialog
--This time we will ommit the explicit using: argument:
exportFile (GetDir #export +"\\alembictest_ogawa_maya.abc") #noPrompt

--RESULT: We now have two files, one using Max Z up and HDF5 storage, 
--and one using Maya Y up and the newer Ogawa storage.

--See the AlembicImport:ImporterPlugin topic for an example
--of importing these files back into 3ds Max.

 特に明記されている場合以外は、この作業は、Creative Commons 表示 - 非営利 - 継承 3.0 非移植ライセンス のもと認可を受けています。 Autodesk Creative Commons FAQ (英語版) を参照してください。