Edit_Poly: モディファイヤ

Edit_Poly -superclass: modifier; super-superclass:MAXWrapper - classID:#(2041212445, 1906341303)

ポリゴンを編集モード
選択
ソフト選択
頂点/エッジ/縁取り/ポリゴン/要素を編集
ジオメトリを編集する
[ポリゴン: マテリアル ID]
ポリゴン: スムージンググループ
ペイント変形
- その他のプロパティ
ポリゴン編集インタフェース:
選択メソッド
演算メソッド
トポロジ編集メソッド
ジオメトリデータメソッド
その他のメソッド

プロパティ:

ポリゴンを編集モード

<Edit_Poly>.animationMode Integer default: 0 -- integer; Animation_Mode

[ポリゴンを編集モード](Edit Poly Mode)ロールアウトの[モデル] (Model)、[アニメーション] (Animation)のラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - モデル

1 - アニメート

<Edit_Poly>.currentOperation Integer default: 0 -- integer; Edit_Type

モディファイヤの現在の編集操作を取得/設定します。

有効な値は次のとおりです。


1	頂点を非表示	2	ポリゴンを非表示	3	頂点を表示
4	ポリゴンを表示	5	未選択の頂点を非表示	6	未選択のポリゴンを非表示
7		8		9	キャップホール
10	頂点を削除	11	ポリゴンを削除	12	頂点をデタッチ
13	ポリゴンをデタッチ	14	エッジを分割	15	頂点をブレーク
16	頂点を集約	17	エッジを集約	18	ポリゴンを集約
19		20	スライス	21	ポリゴンをスライス
22	頂点を連結	23	エッジを連結	24
25	平面化	26	分離した頂点を削除	27	メッシュスムーズ
28	面分割	29	再三角形化	30	法線を反転
31	法線を反転	32	ポリゴンをベベル	33	頂点を面取り
34	エッジを面取り	35	切り取り	36
37		38	ポリゴンを挿入	39	頂点を押し出し
40	エッジを押し出し	41	ポリゴンを押し出し	42	スプラインに沿って押し出し
43	エッジを接続	44	頂点を接続	45	エッジからヒンジ
46		47		48	未使用のマップ頂点を削除
49	頂点の削除	50	エッジを削除	51	ポリゴンのアウトラインを作成
52		53	変換	54	エッジを削除
55		56	作成	57	配置
58	アタッチ	59	ターゲットの連結頂点	60	ターゲットの連結エッジ
61	三角形化を編集	62	エッジを作成	63	頂点をクローン
64	エッジをクローン	65	面をクローン	66	エッジに頂点を挿入
67	ポリゴンに頂点を挿入	68	自動スムーズ	69	スムージンググループを設定
70	マテリアル ID を設定	71		72
73		74	境界線をブリッジ	75	ポリゴンをブリッジ
76	平面を X に平行に	77	平面を Y に平行に	78	平面を Z に平行に
79	エッジを回転	80	リラックス	81	ペイントの変形
82	エッジをブリッジ	83		84

<Edit_Poly>.worldToObjectTransform Matrix3 default: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0]) -- matrix3; World_to_Object_Transform

<Edit_Poly>.showCage BooleanClass default:false -- boolean; Show_Cage

[ポリゴン編集モード](Edit Poly Mode)ロールアウトの[ケージを表示](Show Cage)チェックボックスの状態を取得/設定します。

<Edit_Poly>.CageColor Point3 default: [1,0.588235,0] -- point3; Cage_Color

ケージカラーを取得/設定します。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.selectedCageColor Point3 default: [0.94902,0.85098,0] -- point3; Selected_Cage_Color

選択されているケージカラーを取得/設定します。3ds Max 8 以降 で使用可能です。

選択

<Edit_Poly>.useStackSelection BooleanClass default: false -- boolean; Use_Stack_Selection

[選択] (Selection)ロールアウトの[スタック選択を使用](Use Stack Selection)チェックボックスの状態を取得/設定します。チェックマークが付いている場合、モディファイヤのサブオブジェクト選択ではなく、取り込まれたスタック選択が使用されます。

<Edit_Poly>.selectByVertex BooleanClass default: false-- boolean; Select_By_Vertex

<Edit_Poly>.ignoreBackfacing BooleanClass default: false -- boolean; Ignore_Backfacing

[選択] (Selection)ロールアウトの[背面を無視](Ignore Backfacing)チェックボックスの状態を取得/設定します。

<Edit_Poly>.selectByAngle BooleanClass default: false -- boolean; Select_by_Angle

[選択] (Selection)ロールアウトの[角度による選択](Select By Angle)チェックボックスの状態を取得/設定します。

<Edit_Poly>.selectAngle Float default: 45.0 -- angle; Selection_Angle

[選択] (Selection)ロールアウトの[角度による選択](Select Angle)の角度値を取得/設定します。

<Edit_Poly>.loopEdgeSel Integer default: 0 -- integer; Edge_Loop

[エッジループ](Edge Loop)の値を取得/設定します。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.ringEdgeSel Integer default: 0 -- integer; Edge_Ring

[エッジリング](Edge Ring)の値を取得/設定します。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.selectMode Integer default: 0 -- integer; Select_Mode

[ポリゴン編集の選択モード](Edit Poly Selection Mode)を取得/設定します。3ds Max 2008 以降 で使用可能です。

有効な値は次のとおりです。

0 - オフ

1 - サブオブジェクト

2 - マルチ

ソフト選択

<Edit_Poly>.useSoftSel BooleanClass default: false-- boolean; Use_Soft_Selection

[ソフト選択](Soft Selection)ロールアウトの[ソフト選択を使用](Use Soft Selection)チェックボックスの状態を取得/設定します。

<Edit_Poly>.ssUseEdgeDist BooleanClass default: false-- boolean; Use_Edge_Distance

[ソフト選択](Soft Selection)ロールアウトの[エッジの距離](Edge Distance)チェックボックスの状態を取得/設定します。

<Edit_Poly>.ssEdgeDist Integer default:1 -- integer; Edge_Distance

[ソフト選択](Soft Selection)ロールアウトの[エッジの距離](Edge Distance)を取得/設定します。

<Edit_Poly>.affectBackfacing BooleanClass default: true-- boolean; Affect_Backfacing

[ソフト選択](Soft Selection)ロールアウトの[背面に影響](Affect Backfacing)チェックボックスの状態を取得/設定します。

<Edit_Poly>.falloff Float default: 20.0 -- animatable; world units

[ソフト選択](Soft Selection)ロールアウトの[フォールオフ] (Falloff)の値を取得/設定します。

<Edit_Poly>.pinch Float default: 0.0 -- animatable; float

[ソフト選択](Soft Selection)ロールアウトの[ピンチ] (Pinch)の値を取得/設定します。

<Edit_Poly>.bubble Float default: 0.0 -- animatable; float

[ソフト選択](Soft Selection)ロールアウトの[バブル] (Bubble)の値を取得/設定します。

<Edit_Poly>.lockSoftSel BooleanClass default: false -- boolean; Lock_Soft_Selection

[ソフト選択](Soft Selection)ロールアウトの[ソフト選択をロック](Lock Soft Selection)チェックボックスの状態を取得/設定します。有効にされているときには、ソフト選択が自動的に再計算されることはなく、[ソフト選択ペイント](Paint Soft Selection)のツールを使用して定義できます。

<Edit_Poly>.paintSelValue Float default: 1.0 -- float; Selection_Value

[ソフト選択](Soft Selection)ロールアウトの[ソフト選択ペイント](Paint Soft Selection)領域の選択値を取得/設定します。これにより、ペイントブラシによって頂点に適用される選択値が決まります。

<Edit_Poly>.paintSelSize Float default: 10.0 -- world units; Brush_Size

ペイント選択のブラシのサイズを取得/設定します。

<Edit_Poly>.paintSelStrength Float default: 1.0 -- float; Brush_Strength

ペイント選択のブラシの強度を取得/設定します。

<Edit_Poly>.paintSelMode     Integer    default: 0   --  integer; Paint_Mode

[ソフト選択ペイント](Paint Soft Selection)モードを取得/設定します。値は次のとおりです。

0 = 無効/オフ
1 = ペイント
2 = 復元
3 = ブラー

頂点/エッジ/縁取り/ポリゴン/要素を編集

頂点/エッジ/面の押し出し

<Edit_Poly>.extrudeEdgeHeight Float default: 0.0 -- animatable; world units; Edge_Extrude_Height

エッジの[押し出しの高さ](Extrusion Height)の値を取得/設定します。

<Edit_Poly>.extrudeEdgeWidth Float default: 0.0 -- animatable; world units; Edge_Extrude_Width

エッジの[押し出しの幅](Extrusion Width)の値を取得/設定します。

<Edit_Poly>.extrudeFaceHeight Float default: 0.0 -- animatable; world units; Polygon_Extrude_Height

面の[押し出しの高さ](Extrusion Height)の値を取得/設定します。

<Edit_Poly>.extrudeFaceType Integer default: 0 -- integer; Type_of_Extrusion

面押し出しのタイプを決めるラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - グループ

1 - ローカル法線

2 - ポリゴン別

<Edit_Poly>.extrudeFaceBias     Float    default: 1.0   --  animatable; float

面押し出しのバイアスレベルを取得/設定します。これは、extrudeFaceType が 1 (ローカル法線)の場合に押し出しに影響します。1.0 を設定すると、元の法線に沿って面が押し出されます。複数の面で 1 つのエッジを共有する場合は、0.0 を設定して、共有されたエッジの平均に向かって結果をバイアスします。

<Edit_Poly>.extrudeVertexHeight Float default: 0.0 -- animatable; world units; Vertex_Extrude_Height

頂点の[押し出しの高さ](Extrusion Height)の値を取得/設定します。

<Edit_Poly>.extrudeVertexWidth Float default: 0.0 -- animatable; world units; Vertex_Extrude_Width

頂点の[押し出しの幅](Extrusion Width)の値を取得/設定します。

関連するメソッド:

[押し出し] (Extrude) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #ExtrudeVertex, #ExtrudeEdge、#ExtrudeFace の演算を参照してください。

連結

<Edit_Poly>.weldEdgeThreshold Float default: 0.1 -- animatable; world units; Edge_Weld_Threshold

[エッジを連結](Weld Edge)のしきい値を取得/設定します。

<Edit_Poly>.weldVertexThreshold Float default: 0.1 -- animatable; world units; Vertex_Weld_Threshold

[頂点を連結](Weld Vertex)のしきい値を取得/設定します。

関連するメソッド:

[連結] (Weld) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #WeldVertex および #WeldEdge の演算を参照してください。

「EditPolyMod インタフェース - 連結メソッド」も参照してください。

面取り

<Edit_Poly>.chamferEdgeAmount Float default:1.0 -- animatable; world units; Edge_Chamfer_Amount

[エッジ面取りの量](Edge Chamfer Amount)の値を取得/設定します。

<Edit_Poly>.chamferEdgeOpen BooleanClass default: false -- boolean; Open_Chamfer

[エッジの面取り](Edge Chamfer)ダイアログボックスの[開く] (Open)チェックボックスの状態を取得/設定します。true に設定すると、面取り操作によって作成された新しいポリゴンが削除されて開口部が残ります。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.chamferVertexAmount Float default: 1.0 -- animatable; world units; Vertex_Chamfer_Amount

[頂点面取りの量](Vertex Chamfer Amount)を取得/設定します。

<Edit_Poly>.chamferVertexDepth     Float    default: 0.5   --  float; Vertex_Depth

頂点の面取りの奥行きを取得/設定します。3ds Max 2021 以降で使用可能です。

<Edit_Poly>.chamferVertexOpen BooleanClass default: false -- boolean; Open_Chamfer

[頂点の面取り](Vertex Chamfer)ダイアログボックスの[開く] (Open)チェックボックスの状態を取得/設定します。true に設定すると、面取り操作によって作成された新しいポリゴンが削除されて開口部が残ります。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.chamferVertexSegments     Integer    default: 1   --  integer; Vertex_Chamfer_Segments

頂点面取りセグメントの数を取得/設定します。3ds Max 2021 以降で使用可能です。

<Edit_Poly>.chamferVertexSmooth BooleanClass default: true -- boolean; Smooth

頂点の面取りのスムーズ設定を取得/設定します。3ds Max 2021 以降で使用可能です。

<Edit_Poly>.chamferVertexSmoothThreshold Float default: 30.0 -- float; Smooth_Threshold

頂点の面取りのスムージングしきい値を取得/設定します。3ds Max 2021 以降で使用可能です。

<Edit_Poly>.chamferVertexSmoothType Integer default: 0 -- integer; Smooth_Type

頂点の面取りのスムージングタイプを取得/設定します。値は次のとおりです。 3ds Max 2021 以降で使用可能です。

0 = オブジェクト全体スムーズ
1 = 面取りのみスムーズ

<Edit_Poly>.edgeChamferDepth Float default: 0.5 -- float; Edge_Depth

エッジ面取りの奥行きを取得/設定します。 3ds Max 2021 以降で使用可能です。

<Edit_Poly>.edgeChamferEndBias Float default: 0.5 -- float; Edge_End_Bias

エッジ面取りの終了バイアスを取得/設定します。3ds Max 2021 以降で使用可能です。

<Edit_Poly>.edgeChamferMiteringType Integer default: 2 -- integer; Chamfer_Edge_Mitering_Type

エッジ面取りの留め継ぎタイプを取得/設定します。値は次のとおりです。3ds Max 2021 以降で使用できます。

0 = 四角形
1 = 三角形
2 = 均等
3 = 円形
4 = パッチ

注: このプロパティは、廃止された edgeChamferType および edgeChamferQuadIntersections プロパティを置き換えます。

<Edit_Poly>.edgeChamferRadialBias     Float    default: 0.0   --  float; Edge_Radial_Bias

エッジ面取りの放射状バイアスを取得/設定します。3ds Max 2021 以降で使用可能です。

<Edit_Poly>.edgeChamferSegments Integer default: 1 -- integer; Edge_Chamfer_Segments

[エッジの面取りセグメント](Edge Chamfer Segments)量の値を取得/設定します。エッジの面取りにセグメントを追加すると、エッジのフィレット(エッジの丸め)を効率的に実行することができます。3ds Max 2008 以降 で使用可能です。

<Edit_Poly>.edgeChamferQuadIntersections BooleanClass default: false -- boolean; alias: quad_intersections

旧式: [四角形交差](Quad Intersections)モードを取得/設定します。このプロパティは、3ds Max 2021 で edgeChamferMiteringType に置き換えられます。

関連するメソッド:

[面取り] (Chamfer) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #ChamferVertex および #ChamferEdge の演算を参照してください。

<Edit_Poly>.edgeChamferSmooth BooleanClass default: true -- boolean; Smooth

[面取り] (Chamfer)ダイアログボックスの[スムーズ] (Smooth)チェックボックスの状態を取得/設定します。

<Edit_Poly>.edgeChamferSmoothThreshold Float default: 30.0 -- float; Smooth_Threshold

[面取り] (Chamfer)ダイアログボックスの[スムージングしきい値](Smooth Threshold)チェックボックスの値を取得/設定します。

<Edit_Poly>.edgeChamferSmoothType Integer default: 0 -- integer; Smooth_Type

[面取り] (Chamfer)ダイアログボックスの[スムーズタイプ](Smooth Type)オプションを取得/設定します。

有効な値は次のとおりです。

0 - [オブジェクト全体スムーズ](Smooth Entire Object)

1 - [面取りのみスムーズ](Smooth Chamfers Only)

<Edit_Poly>.edgeChamferTension Float default: 1.0 -- float; Edge_Tension

[面取り] (Chamfer)モードの[テンション] (Tension)の値を取得/設定します。

<Edit_Poly>.edgeChamferType Integer default: 0 -- integer; Chamfer_Type

旧式: 面取りのタイプを取得/設定します。このプロパティは、3ds Max 2021 で edgeChamferMiteringType に置き換えられます。

<Edit_Poly>.edgeChamferInvert BooleanClass default: false -- boolean; Invert_Open

[面取り] (Chamfer)ダイアログボックスの[開口を反転](Invert Open)チェックボックスの状態を取得/設定します。

True に設定すると、面取りされたポリゴンが保持され、元のポリゴンが削除されます。

接続

<Edit_Poly>.connectEdgeSegments Integer default: 1 -- animatable; integer; Connect_Edge_Segments

[エッジセグメントの接続](Connect Edge Segments)の既定値を取得/設定します。

<Edit_Poly>.connectEdgePinch Integer default: 0 -- animatable; integer; Connect_Edge_Pinch

[エッジ接続](Edge Connect)ダイアログボックスの[ピンチ] (Pinch)の値を取得/設定します。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.connectEdgeSlide Integer default: 0 -- animatable; integer; Connect_Edge_Slide

[エッジ接続](Edge Connect)ダイアログボックスの[スライド] (Slide)の値を取得/設定します。3ds Max 8 以降 で使用可能です。

関連するメソッド:

[接続] (Connect) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #ConnectVertices および #ConnectEdges の演算を参照してください。

アウトライン

<Edit_Poly>.outlineAmount Float default: 0.0 -- animatable; world units; Outline_Amount

[アウトラインの量](outline amount)の値を取得/設定します。

関連するメソッド:

[アウトライン] (Outline) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #Outline 演算を参照してください。

ベベル

<Edit_Poly>.bevelHeight Float default: 0.0 -- animatable; world units; Bevel_Height

ベベルの[押し出しの高さ](Extrusion Height)の値を取得/設定します。

<Edit_Poly>.bevelOutline Float default: 0.0 -- animatable; world units; Bevel_Outline

ベベルの[アウトライン] (Outline)の値を取得/設定します。

<Edit_Poly>.bevelType Integer default: 0 -- integer; Bevel_Type

[ベベル] (Bevel)ダイアログボックスの[押し出しタイプ](Extrusion Type)を取得/設定します。

0 - グループ

1 - ローカル法線

2 - ポリゴン別

関連するメソッド:

[ベベル] (Bevel) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #Bevel 演算を参照してください。

<Edit_Poly>.bevelFaceBias     Float    default: 1.0   --  animatable; float

ベベルのバイアス値を取得/設定します。これは、bevelType が 1 (ローカル法線)の場合にベベルに影響します。1.0 を設定すると、元の法線に沿って面のベベルが行われます。複数の面で 1 つのエッジを共有する場合は、0.0 を設定して、共有されたエッジの平均に向かって結果をバイアスします。

インセット

<Edit_Poly>.insetAmount Float default: 0.0 -- animatable; world units; Inset_amount

[インセット量](Inset Amount)の値を取得/設定します。

<Edit_Poly>.insetType Integer default: 0 -- integer; Inset_Type

[インセットタイプ](Inset Type)を取得/設定します。

0 - グループ

1 - ポリゴン別

関連するメソッド:

[インセット] (Inset) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #Inset 演算を参照してください。

ブリッジ

<Edit_Poly>.bridgeSelected Integer default: 1-- integer; Bridge_Selected

[ブリッジ] (Bridge)ダイアログボックス内のラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - 固有のポリゴンを使用

1 - ポリゴン選択を使用

<Edit_Poly>.bridgeSegments Integer default: 1 -- animatable; integer; Bridge_Segments

[ブリッジ] (Bridge)セグメントの数を取得/設定します。

<Edit_Poly>.bridgeTaper Float default: 0.0 --animatable; float; Bridge_Taper

[ブリッジテーパ](Bridge Taper)の値を取得/設定します。

<Edit_Poly>.bridgeBias Float default: 0.0 --animatable; float; Bridge_Bias

[ブリッジバイアス](Bridge Bias)の値を取得/設定します。

<Edit_Poly>.bridgeSmoothThreshold Float default: 45.0 -- animatable; angle; Bridge_Smoothing_Threshold;

[ブリッジスムージングしきい値](Bridge Smooth Threshold)を取得/設定します。

<Edit_Poly>.bridgeTarget1 Integer default: 0-- integer; Bridge_Target_1

ブリッジの最初のターゲットポリゴンのインデックスを取得/設定します。

<Edit_Poly>.bridgeTarget2 Integer default: 0-- integer; Bridge_Target_2

ブリッジの 2 番目のターゲットポリゴンのインデックスを取得/設定します。

<Edit_Poly>.bridgeTwist1 Integer default:0 -- integer; Bridge_Twist_1

最初の[ツイスト] (Twist)の値を取得/設定します。

<Edit_Poly>.bridgeTwist2 Integer default:0 -- integer; Bridge_Twist_2

2 番目の[ツイスト] (Twist)の値を取得/設定します。

<Edit_Poly>.bridgeEdgeAdjacent Float default: 45.0 -- animatable; angle; Bridge_Adjacent

[近接ブリッジ](Bridge Adjacent)の値を取得/設定します。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.bridgeReverseTriangle Integer default: 0 -- integer; Reverse_Triangles

[三角形化を反転](Reverse Triangulation)チェックボックスの状態を取得/設定します。3ds Max 8 以降 で使用可能です。

有効な値は次のとおりです。

0 - 無効

1 - 有効

関連するメソッド:

[ブリッジ] (Bridge) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #BridgeBorder および #BridgePolygon の演算と #PickBridgeTarget1 および #PickBridgeTarget2 のコマンドモードを参照してください。

「EditPolyMod インタフェース - ブリッジメソッド」も参照してください。

<boolean>editPolyModReadyToBridge()

現在選択されているフェース、エッジ、境界、または Edit_Poly モディファイアが適用されている現在選択済みのオブジェクトの要素をブリッジする準備ができているかどうかを返します。これは、EdititablePoly.ReadyToBridgeFlagged() と似ていますが、選択レベルの引数またはフラグを取らないで、現在の選択レベルにのみ適用されます。

Hinge

<Edit_Poly>.hingeAngle Float default: 0.0 -- animatable; angle; Hinge_From_Edge_Angle

[関節角度](Hinge Angle)の値を取得/設定します。

<Edit_Poly>.hingeBase Point3 default: [0,0,0] -- animatable; point3; Hinge_from_Edge_Base

<Edit_Poly>.hingeDirection Point3 default: [1,0,0] -- animatable; point3; Hinge_from_Edge_Direction

<Edit_Poly>.hingeSegments Integer default: 1 -- animatable; integer; Hinge_From_Edge_Segments

[関節セグメント](Hinge Segment)の値を取得/設定します。

関連するメソッド:

[関節] (Hinge) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #HingeFromEdge 演算と #HingeFromEdge および \# PickHinge のコマンドモードを参照してください。

スプラインに沿って押し出し

<Edit_Poly>.extrudeAlongSplineAlign BooleanClass default: true -- animatable; boolean; Extrude_Along_Spline_Align

[スプラインに沿って押し出し](Extrude Along Spline)ダイアログボックスの[面法線に位置合わせ](Align To Face Normal)チェックボックスの状態を取得/設定します。

<Edit_Poly>.extrudeAlongSplineNode UndefinedClass default: undefined -- node; Extrude_Along_Spline_Node

[スプラインに沿って押し出し](Extrude Along Spline)のスプラインノードを取得/設定します。

<Edit_Poly>.extrudeAlongSplineRotation Float default: 0.0 -- animatable; angle; Extrude_Along_Spline_Rotation;

[スプラインに沿って押し出し](Extrude Along Spline)ダイアログボックスの[回転] (rotation)の値を取得/設定します。

<Edit_Poly>.extrudeAlongSplineSegments Integer default: 6 -- animatable; integer; Extrude_Along_Spline_Segments

[スプラインに沿って押し出し](Extrude Along Spline)ダイアログボックスの[セグメント] (segments)数の値を取得/設定します。

<Edit_Poly>.extrudeAlongSplineTaper Float default: 0.0 -- animatable; float; Extrude_Along_Spline_Taper_Amount

[スプラインに沿って押し出し](Extrude Along Spline)ダイアログボックスの[テーパ量](Taper Amount)を取得/設定します。

<Edit_Poly>.extrudeAlongSplineTaperCurve Float default: 0.0 -- animatable; float; Extrude_Along_Spline_Taper_Curve

[スプラインに沿って押し出し](Extrude Along Spline)ダイアログボックスの[テーパカーブ](taper curve)の値を取得/設定します。

<Edit_Poly>.extrudeAlongSplineTwist Float default: 0.0 -- animatable; angle; Extrude_Along_Spline_Twist

[スプラインに沿って押し出し](Extrude Along Spline)ダイアログボックスの[ツイスト] (Twist)の値を取得/設定します。

関連するメソッド:

[スプラインに沿って押し出し](Extrude Along Spline) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #ExtrudeAlongSpline 演算を参照してください。

頂点/エッジの削除

この機能に関して公開されているプロパティはありません。[削除] (Remove) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #RemoveVertex および #RemoveEdge の演算を参照してください。

頂点のブレーク

この機能に関して公開されているプロパティはありません。[ブレーク] (Break) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #BreakVertex 演算を参照してください。

エッジを分割

この機能に関して公開されているプロパティはありません。[分割] (Split) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の ##SplitEdges 演算を参照してください。

面/要素を反転

この機能に関して公開されているプロパティはありません。[反転] (Flip) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #FlipFace および #FlipElement の演算を参照してください。

エッジ/面に頂点を挿入

この機能に関して公開されているプロパティはありません。[頂点を挿入](Insert Vertex) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #InsertVertexInEdge および #InsertVertexInFace の演算を参照してください。

分離頂点を除去

この機能に関して公開されているプロパティはありません。[分離頂点を除去](RemoveIsolated Vertices)/[未使用マップ頂点を除去](Remove Unused Map Verts) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #RemoveIsoVerts および #RemoveIsoMapVerts の演算を参照してください。

ジオメトリを編集する

[拘束]

<Edit_Poly>.constrainType Integer default: 0 -- integer; Vertex_Constraint_Type

[頂点のコンストレイントタイプ](Vertex Constraint type)を取得/設定します。

有効な値は次のとおりです。

0 - なし

1 - エッジ

2 - 面

3 - 法線

UV を保存

<Edit_Poly>.preserveUVs BooleanClass default: false -- boolean; Preserve_UVs

[UV を保存](Preserve UVs)チェックボックスの状態を取得/設定します。true に設定されているとき、動くサブオブジェクト要素はテクスチャ座標に影響しません。

関連するメソッド:

関連するメソッドについては、「EditPolyMod インタフェース - PreserveMap メソッド」を参照してください。

[リラックス] (Relax)ダイアログボックス

<Edit_Poly>.relaxAmount Float default: 0.5 -- animatable; float; Amount

[リラックス量](Relax Amount)を取得/設定します。

<Edit_Poly>.relaxIterations Integer default: 1 -- animatable; integer; Iterations

[リラックス反復](Relax Iterations)の値を取得/設定します。

<Edit_Poly>.relaxHoldBoundaryPoints BooleanClass default: true -- boolean; Hold_Boundary_Points

[境界点を保持](Hold Boundary Points)チェックボックスの状態を取得/設定します。

<Edit_Poly>.relaxHoldOuterPoints BooleanClass default: false -- boolean; Hold_Outer_Points

[外側ポイントを保持](Hold Outer Points)チェックボックスの状態を取得/設定します。

関連するメソッド:

[リラックス] (Relax) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #Relax 演算を参照してください。

スライス平面

<Edit_Poly>.slice_plane SubAnim default: SubAnim:Slice_Plane -- transform; SubAnim

Edit_Poly.slice_plane - superclass: MAXObject; super-superclass:Value - 3:3 - classID: #(8197, 0)

<Edit_Poly.slice_plane>.position Point3 default: [0,0,0] -- animatable; point3

スライス平面の位置を取得/設定します。

<Edit_Poly.slice_plane>.rotation Quat default: (quat 0 0 0 1) -- animatable; quat

スライス平面の回転を取得/設定します。

<Edit_Poly.slice_plane>.scale Point3 default: [1,1,1] -- animatable; point3

スライス平面のスケールを取得/設定します。

<Edit_Poly>.split BooleanClass default: false -- boolean

[分割] (Split)オプションの状態を取得/設定します。

関連するメソッド:

スライス操作を実行するには、「EditPolyMod インタフェース演算メソッド」の #ResetSlicePlane, #Slice、#SliceSelectedFaces の演算と #SlicePlane コマンドモードを参照してください。

「EditPolyMod インタフェース - スライスメソッド」も参照してください。

位置合わせ平面

<Edit_Poly>.alignPlaneNormal Point3 default: [0,0,0] -- animatable; point3; Align_Plane_Normal

位置合わせ平面の法線ベクトルを取得/設定します。

<Edit_Poly>.alignPlaneOffset Float default: 0.0 -- animatable; float; Align_Plane_Offset

位置合わせ平面のオフセットを取得/設定します。

<Edit_Poly>.alignType Integer default: 0 -- integer; Align_Type

位置合わせ平面のタイプを取得/設定します。

関連するメソッド:

位置合わせ操作を実行するには、「EditPolyMod インタフェース演算メソッド」の #Align 演算を参照してください。

メッシュをスムーズ化

<Edit_Poly>.smoothness Float default: 1.0 -- float

[サブディビジョンサーフェス](Subdivision Surface)ロールアウトのビューポートの[スムーズさ] (Smoothness)の値を取得/設定します。

<Edit_Poly>.separateByMaterial BooleanClass default: false -- boolean; Separate_by_Material_ID

[サブディビジョンサーフェス](Subdivision Surface)ロールアウトの[マテリアルで分類](Separate By Materials)チェックボックスを取得/設定します。

<Edit_Poly>.separateBySmoothing BooleanClass default: false -- boolean; Separate_by_Smoothing_Groups

[サブディビジョンサーフェス](Subdivision Surface)ロールアウトの[スムージングで分類](Separate By Smoothing)チェックボックスを取得/設定します。

関連するメソッド:

位置合わせ操作を実行するには、「EditPolyMod インタフェース演算メソッド」の #MeshSmooth 演算を参照してください。

面分割

<Edit_Poly>.tessellateByFace Integer default: 0 -- animatable; integer; Tessellate_By

[面分割] (Tessellation)タイプを取得/設定します。

0 -エッジ

1 - 面

<Edit_Poly>.tessTension Float default: 0.0 -- animatable; float; Tessellation_Tension

[面分割テンション](Tessellation Tension)を取得/設定します。

関連するメソッド:

位置合わせ操作を実行するには、「EditPolyMod インタフェース演算メソッド」の #Tessellate 演算を参照してください。

分離した頂点を削除

<Edit_Poly>.deleteIsolatedVerts BooleanClass default: true -- boolean; Delete_Isolated_Vertices

[分離した頂点を削除](Delete Isolated Vertices)チェックボックスの状態を取得/設定します。

集約

この機能に関して公開されているプロパティはありません。[集約] (Collapse) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #CollapseVertex, #CollapseEdge、#CollapseFace の演算を参照してください。

表示/非表示

この機能に関して公開されているプロパティはありません。[非表示] (Hide)/[表示] (Unhide) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #HideVertex, #HideFace, #HideUnselectedVertex, #HideUnselectedFace, #UnhideAllVertex、#UnhideAllFace の演算を参照してください。

名前付き選択セットのコピー/貼り付け

この機能に関して公開されているプロパティはありません。[コピー] (Copy)/[貼り付け] (Paste) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #NamedSelectionCopy および #NamedSelectionPaste の演算を参照してください。

平面化

この機能に関して公開されているプロパティはありません。[平面化](Make Planar) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #MakePlanar, #MakePlanarInX, #MakePlanarInY、#MakePlanarInZ の演算を参照してください。

[ポリゴン: マテリアル ID]

<Edit_Poly>.materialIDToSet Integer default: 0 -- animatable; integer; Material_ID_to_Set

選択した面について設定するマテリアル ID の値を取得/設定します。

<Edit_Poly>.selectByMaterialID Integer default: 0 -- integer; Select_By_Material_ID

[マテリアル ID による選択](Select By Material ID)機能で使用する ID を取得/設定します。

<Edit_Poly>.selectByMaterialClear BooleanClass default: false -- boolean; Select_By_Material_Clear

[マテリアル ID による選択](Select By Material ID)機能の[クリア] (Clear)チェックボックスの状態を取得/設定します。true に設定すると、新しい面を選択する前にそれまでの選択がクリアされます。

メソッド:

<Edit_Poly>.MatID Floater()

このロールアウトの、[ポリゴン : マテリアル ID]フロータバージョンの可視性を切り替えます。

3ds Max 2010以降で使用可能です。

<boolean><Edit_Poly>.MatID FloaterVisible()

[ポリゴン: マテリアル ID]フロータが表示されていれば true を返し、非表示であれば false を返します。

3ds Max 2010以降で使用可能です。

関連するメソッド:

[ID を選択](Select ID) ボタンを押すには、「EditPolyMod インタフェース演算メソッド」の #SelectByMaterial 演算を参照してください。

ポリゴン: スムージンググループ

<Edit_Poly>.smoothingGroupsToSet Integer default: 0 -- integer; Smoothing_Groups_to_Set

設定するスムージンググループを取得/設定します。

注:

この値は long 型の整数で、32 ビットごとにスムージンググループを設定します。最初のビットは 2^0、2 番目のビットは 2^1、というようになり、最後のビットは 2^31 です。このプロパティに割り当てるべき整数を得るためには、設定すべきすべてのビットの合計を計算します。

たとえば、ビット 20 を設定する場合は、2^(20-1) = 524288 に設定します。

スムージンググループ 1、5、17 を設定する場合には、次の加算を行います。2^(1-1) + 2^(5-1) + 2^(17-1) = 65553。

<Edit_Poly>.smoothingGroupsToClear Integer default: 0 -- integer; Smoothing_Groups_to_Clear

クリアするスムージンググループを取得/設定します。この値は long 型の整数で、32 ビットごとにスムージンググループをクリアします。例については、上記のプロパティを参照してください。

<Edit_Poly>.selectBySmoothingGroup Integer default: 0 -- integer; Select_By_Smoothing_Group

選択に使用するスムージンググループを取得/設定します。

<Edit_Poly>.selectBySmoothingGroupClear BooleanClass default: false -- boolean; Select_By_Smoothing_Group_Clear

[スムーズグループによる選択](Select By Smooth Group)ダイアログボックスの[クリア] (Clear)チェックボックスの状態を取得/設定します。true に設定すると、新しい面を選択する前にそれまでの選択がクリアされます。

<Edit_Poly>.autoSmoothThreshold Float default: 45.0 -- animatable; angle; Autosmooth_Threshold

自動スムージングのしきい値の角度を取得/設定します。隣接した 2 つの面の法線の間の角度がしきい値と比較されます。しきい値より角度が小さい場合、2 つの面には自動的に同じスムージンググループが割り当てられ、共通のエッジに沿ってスムーズなシェーディングが生成されます。

メソッド:

<Edit_Poly>.SmGrp Floater()

このロールアウトの、[スムージンググループ]フロータバージョンの可視性を切り替えます。

3ds Max 2010以降で使用可能です。

<boolean><Edit_Poly>.SmGrp FloaterVisible()

3ds Max 2010以降で使用可能です。

関連するメソッド:

「EditPolyMod インタフェース演算メソッド」の #SelectBySmooth, #AutoSmooth、#SetSmooth の演算を参照してください。

ペイント変形

<Edit_Poly>.paintDeformAxis Integer default: 1 -- integer; Push_Pull_Direction

[ペイント変形](Paint Deformation)ロールアウトの[押す/引く方向](Push/Pull Direction)ラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

1 - オリジナル法線

2 - 変形された法線

3 - 変換軸: X

4 - 変換軸: Y

5 - 変換軸: Z

<Edit_Poly>.paintDeformValue Float default: 10.0 -- float; Deformation_Value

[ペイント変形](Paint Deform)ブラシによって適用される値を取得/設定します。

<Edit_Poly>.paintDeformSize Floatdefault: 10.0 -- world units; Deformation_Size

[ペイント変形](Paint Deform)の[ブラシサイズ] (Size)を取得/設定します。

<Edit_Poly>.paintDeformStrength Float default: 1.0 -- float; Deformation_Strength

[ペイント変形](Paint Deform)の[ブラシ強度] (Strength)を取得/設定します。

<Edit_Poly>.paintDeformMode Integer    default: 0   --  integer; Paint_Mode

[ペイント変形](Paint Deformation)モードを取得/設定します。値は次のとおりです。

0 = オフ/無効
4 = 押す/引く
5 = リラックス
6 = 復元

その他のプロパティ

<Edit_Poly>.breakDistance Float default: 0.0 -- animatable; float; Amount

ブレークの距離の値を取得/設定します。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.remveEdgeCtrlKey BooleanClass default: false -- boolean; Remove_Edge_Control_Key

エッジコントロールキーオプションの状態を取得/設定します。3ds Max 8 以降 で使用可能です。

<Edit_Poly>.dataChannel     Integer    default: 0   --  integer

データチャネルを整数として取得/設定します。

3ds Max 2016 以降で使用可能です。

<Edit_Poly>.dataValue     Float    default: 0.0   --  float

データ値を浮動小数点として取得/設定します。

3ds Max 2016 以降で使用可能です。

<Edit_Poly>.hardedgedisplay     Integer    default: 0   --  integer

ハードエッジ表示オプションの状態を整数として取得/設定します。

有効な値は次のとおりです。

0 - 無効

1 - 有効

3ds Max 2016 以降で使用可能です。

<Edit_Poly>.hardedgedisplaycolor     Color    default: (color 0 237.15 39.78)   --  RGB color

ハードエッジの表示カラー値を取得/設定します。

3ds Max 2016 以降で使用可能です。

<Editable_Poly>.hardedgedisplay : integer

ハードエッジ表示オプションの状態を整数として取得/設定します。

有効な値は次のとおりです。

0 - 無効

1 - 有効

3ds Max 2016 以降で使用可能です。

<Editable_Poly>.hardedgedisplaycolor : RGB color

ハードエッジの表示カラー値を取得/設定します。

3ds Max 2016 以降で使用可能です。

ポリゴン編集インタフェース:

Interface:EditPolyMod

注:

EditPolyMod インタフェースは、Edit_Poly モディファイヤによって公開された「Mixin インタフェース」です。

以下にリストするメソッドは、そのインタフェースにスタンドアロンとして、つまりポリゴン編集モディファイヤを最初の引数として、その他のすべての引数よりも先に渡すことによって、呼び出すことができます。

このため、以下を使用することができます。

EditPolyMod.GetSelection $Box01.modifiers[#Edit_Poly] #Vertex
--or shorter,
EditPolyMod.GetSelection $Box01.Edit_Poly #Vertex

また、以下にリストするメソッドは、ポリゴン編集モディファイヤ自体によって公開されるメソッドとして呼び出すこともできます。これは、MAXScript は両モディファイヤとそのインタフェースを対象としてメソッド名を検索するからです。

つまり、以下を使用する代わりに、

$Box01.modifiers[#Edit_Poly].EditPolyMod.GetSelection #Vertex
--or
$Box01.Edit_Poly.EditPolyMod.GetSelection #Vertex

以下のいずれかを使用することができます。

$Box01.modifiers[#Edit_Poly].GetSelection #Vertex
--or
$Box01.Edit_Poly.GetSelection #Vertex

スタンドアロンインタフェースのアクセスは、通常、代わりとなるメソッドよりも飛躍的に計算が速くなります。

メソッド:

選択メソッド

<enum>GetEPolySelLevel()

GetEPolySelLevel enums: {#Object|#Vertex|#Edge|#Border|#Face|#Element|#CurrentLevel}

ポリゴン編集の選択レベルを返します。

<enum>GetMeshSelLevel()

GetMeshSelLevel enums: {#Object|#Vertex|#Edge|#Face|#CurrentLevel}

メッシュ選択レベルを返します。

Edit Poly の選択レベルが #Border に設定されているとき、メッシュ選択レベルは #Edge として返されます。

Edit Poly の選択レベルが #Element に設定されているとき、メッシュ選択レベルは #Face として返されます。

<void>SetEPolySelLevel <enum>selectionLevel

selectionLevel enums: {#Object|#Vertex|#Edge|#Border|#Face|#Element|#CurrentLevel}

ポリゴン編集の選択レベルを設定します。

<integer>ConvertSelection <enum>fromLevel <enum>toLevel requireAll:<boolean>

fromLevel enums: {#Object|#Vertex|#Edge|#Border|#Face|#Element|#CurrentLevel}
toLevel enums: {#Object|#Vertex|#Edge|#Border|#Face|#Element|#CurrentLevel}
requireAll default value: false

選択を fromLevel から toLevel に変換します。requireAll: が true に設定されている場合、選択するターゲットサブ要素のために、ターゲットサブ要素が共有するすべてのソースサブ要素を選択しておく必要があります。たとえば、ポリゴンはそのすべての頂点が選択されている場合にのみ選択され、頂点は頂点を共有するすべてのポリゴンが選択されている場合にのみ選択されるなどです。

<bitArray>GetSelection <enum>meshSelLevel node:<node>

meshSelLevel enums: {#Object|#Vertex|#Edge|#Face|#CurrentLevel}
node default value: undefined

指定された選択を bitArray 値として返します。

node: が指定されている場合、指定されたノードに割り当てられたモディファイヤからの選択を返します。

<boolean>SetSelection <enum>meshSelLevel <&bitArray>newSelection node:<node>

meshSelLevel enums: {#Object|#Vertex|#Edge|#Face|#CurrentLevel}
newSelection is In and Out parameter node default value: undefined

与えられた bitArray で、指定された選択を設定します。

node: が指定されている場合、指定されたノードに割り当てられたモディファイヤインスタンスを使用します。

<boolean>Select <enum>meshSelLevel <&bitArray>newSelection invert:<boolean> select:<boolean> node:<node>

meshSelLevel enums: {#Object|#Vertex|#Edge|#Face|#CurrentLevel}
newSelection is In and Out parameter
invert default value: false
]select default value: true
node default value: undefined

参照で渡された bitArray を、指定されたサブオブジェクトレベルのサブオブジェクト選択に追加します。選択を正しく設定するためには、モディファイヤがコマンドパネルに表示され、要求されたサブオブジェクトモードに含まれている必要があります。

オプションの invert : キーワードが指定され、かつ true に設定されている場合は、指定されたサブオブジェクトの選択状態が反転されます。指定されたサブオブジェクトが選択されている場合は選択解除され、選択されていない場合は選択されます。false の場合、または指定されていない場合は、選択された状態になるか、既に選択されている場合は選択された状態が保持されます。

オプションの select: キーワードが指定され、かつ false に設定されている場合は、指定されたサブオブジェクトが既に選択されている場合は選択解除され、選択されていない場合は選択されていない状態が保持されます。true または何も指定されていない場合は、選択されていない場合は選択され、既に選択されている場合は選択された状態が保持されます。

モディファイヤが複数のノード間でインスタンス化されていて、オプションの node : キーワードが指定されている場合は、このメソッドは指定されたノードを使用します。

例:

    --Create a box with 10x10x10 segments:
    b = box width:100 length:100 height:100 heightsegs:10 widthsegs:10 lengthsegs:10
    ep = Edit_Poly()--create an Edit_Poly modifier
    addModifier b ep--add the Edit_Poly modifier to the box
    max modify mode--switch to Modify tab of Command panel
    modPanel.setCurrentObject ep--set the Edit_Poly as the current level
    subObjectLevel = 3--switch to Border level
    --Now print the selection level using stand-alone interface access:
    format"Selection Level Is: %\n"(EditPolyMod.GetEPolySelLevel ep)
    --Now print the Mesh selection level using interface access via the modifier:
    format"Mesh Selection Level Is: %\n"(ep.EditPolyMod.GetMeshSelLevel())
    subObjectLevel = 4--switch to Face level
    --Select a whole side of the box- last 100 polygons. Call the method
    --without explicitly specifying the EditPolyMod interface - still works:
    ep.Select #Face #{501..600}
    ep.convertSelection #Face #Edge--convert the face selection to edge selection
    subObjectLevel = 2--switch to edge mode to see the result

出力:

    $Box:Box01 @ [0.000000,0.000000,0.000000]
    Edit_Poly:Edit Poly
    OK
    OK
    OK
    3
    Selection Level Is: #Border
    OK
    Mesh Selection Level Is: #edge
    OK
    4
    true
    220
    2

<void>MoveSelection <point3>amount parent:<matrix3> axis:<matrix3> localOrigin:<boolean>
       parent default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       axis default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       localOrigin default value: false

指定された Point3 値で現在の選択を移動します。

parent : が指定されている場合は、そのローカル座標系が使用されます。

axis : が指定されている場合、カスタムの座標系としてそれを使用します。

localOrigin : が指定されている場合、変換では選択のローカル変換の中心を原点として使用します。

<void>RotateSelection <quat>amount parent:<matrix3> axis:<matrix3> localOrigin:<boolean>
       parent default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       axis default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       localOrigin default value: false

現在の選択を、指定の四元数値だけ回転します。

parent: が指定されている場合は、そのローカル座標系が使用されます。

axis: が指定されている場合、カスタムの座標系としてそれを使用します。

localOrigin: が指定されている場合、回転は選択のローカル変換の中心の周りで行われます。

<void>ScaleSelection <point3>amount parent:<matrix3> axis:<matrix3> localOrigin:<boolean>
       parent default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       axis default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       localOrigin default value: false

現在の選択を指定したPoint3 値でスケールします。

parent: が指定されている場合は、そのローカル座標系が使用されます。

axis: が指定されている場合、カスタムの座標系としてそれを使用します。

localOrigin: が指定されている場合、スケールは選択のローカル変換の中心の周りで行われます。

<void>RingSelect <integer>RingValue <boolean>MoveOnly <boolean>Add

リング選択を移動します。3ds Max 8 以降 で使用可能です。

RingValue は、シフトするエッジの量です。

MoveOnly を true にすると、選択したエッジが移動します。

Add を true、MoveOnly を true にすると、新しく選択したエッジが現在の選択に追加されます。

MoveOnly を true、Add を false にすると、新しく選択したエッジが現在の選択から削除されます。

例:

    p = plane width:100 length:100 widthsegs:10 lengthsegs:10--create a plane
    ep = Edit_Poly()--create an Edit_Poly modifier
    addModifier p ep--add modifier to the plane
    max modify mode--switch to modify mode
    select p--select theplane
    subObjectLevel = 2--switch to Edge mode
    ep.select #Edge #{1}--select first edge
    ep.ButtonOp #SelectEdgeLoop--select Loop using the first edge
    ep.RingSelect 3 true false--shift the selection by 3

可能な引数の組み合わせをすべて使用して、1 つまたはすべてのエッジループを 3 つずつずらします。

MoveOnly	Add	結果:
true	false
true	false
true	true
true	true
false	true
false	true
false	false
false	false

<void>LoopSelect <integer>LoopValue <boolean>MoveOnly <boolean>Add

ループ選択を移動します。3ds Max 8 以降 で使用可能です。

LoopValue は、シフトするエッジの量です。

MoveOnly を true にすると、選択したエッジが移動します。

Add を true、MoveOnly を true にすると、新しく選択したエッジが現在の選択に追加されます。

MoveOnly を true、Add を false にすると、新しく選択したエッジが現在の選択から削除されます。

<integer>ConvertSelectionToBorder <enum>fromLevel <enum>toLevel

fromLevel enums:{#Object|#Vertex|#Edge|#Border|#Face|#Element|#CurrentLevel}
toLevel enums:{#Object|#Vertex|#Edge|#Border|#Face|#Element|#CurrentLevel}

現在の選択を境界線選択に変換します。最初の引数は、変換元のサブオブジェクトタイプを表します。2 番目の引数は、変換先のサブオブジェクトタイプを表します。

3ds Max 8 以降 で使用可能です。

例:

    p = plane width:100 length:100 widthsegs:10 lengthsegs:10--create a plane
    ep = Edit_Poly()--create an Edit_Poly modifier
    addModifier p ep--add modifier to the plane
    max modify mode--switch to modify mode
    select p--select theplane
    subObjectLevel = 4--switch to face SO level
    editPolyMod.select ep #Face #{12,13,14,23,33}--select some faces
    editPolyMod.ConvertSelectionToBorder ep #Face #Edge--convert to edge selection
    subObjectLevel = 2--switch toedgeSO levelto see the result:

演算メソッド

<enum>GetOperation()

GetOperation enums: {#GrowSelection | #ShrinkSelection | #SelectEdgeLoop | #SelectEdgeRing | #GetStackSelection | #HideVertex | #HideFace | #HideUnselectedVertex | #HideUnselectedFace | #UnhideAllVertex | #UnhideAllFace | #NamedSelectionCopy | #NamedSelectionPaste | #Cap | #DeleteVertex | #DeleteFace | #RemoveVertex | #RemoveEdge | #DetachVertex | #DetachFace | #SplitEdges | #BreakVertex | #CollapseVertex | #CollapseEdge | #CollapseFace | #ResetSlicePlane | #Slice | #SliceSelectedFaces | #Cut | #WeldVertex | #WeldEdge | #CreateShape | #MakePlanar | #MakePlanarInX | #MakePlanarInY | #MakePlanarInZ | #Align | #Relax | #MeshSmooth | #Tessellate | #Retriangulate | #FlipFace | #FlipElement | #ExtrudeVertex | #ExtrudeEdge | #ExtrudeFace | #Bevel | #Inset | #Outline | #ExtrudeAlongSpline | #HingeFromEdge | #ConnectVertices | #ConnectEdges | #ChamferVertex | #ChamferEdge | #RemoveIsoVerts | #RemoveIsoMapVerts | #ToggleShadedFaces | #TransformVertex | #TransformEdge | #TransformFace | #Create | #Attach | #TargetWeldVertex | #TargetWeldEdge | #EditTriangulation | #TurnEdge | #CreateEdge | #CloneVertex | #CloneEdge | #CloneFace | #InsertVertexInEdge | #InsertVertexInFace | #Autosmooth | #SetSmooth | #SetMaterial | #SelectBySmooth | #SelectByMaterial | #BridgeBorder | #BridgePolygon | #BridgeEdge| #PreserveUVSettings | #RemoveEdgeRemoveVertices | #MakeHardEdges | #MakeSmoothEdges | #SelectHardEdges | #SelectSmoothEdges | #DeleteEdge}

現在のポリゴン編集操作を返します。

<void>SetOperation<enum>operation

operation enums: {#GrowSelection | #ShrinkSelection | #SelectEdgeLoop | #SelectEdgeRing | #GetStackSelection | #HideVertex | #HideFace | #HideUnselectedVertex | #HideUnselectedFace | #UnhideAllVertex | #UnhideAllFace | #NamedSelectionCopy | #NamedSelectionPaste | #Cap | #DeleteVertex | #DeleteFace | #RemoveVertex | #RemoveEdge | #DetachVertex | #DetachFace | #SplitEdges | #BreakVertex | #CollapseVertex | #CollapseEdge | #CollapseFace | #ResetSlicePlane | #Slice | #SliceSelectedFaces | #Cut | #WeldVertex | #WeldEdge | #CreateShape | #MakePlanar | #MakePlanarInX | #MakePlanarInY | #MakePlanarInZ | #Align | #Relax | #MeshSmooth | #Tessellate | #Retriangulate | #FlipFace | #FlipElement | #ExtrudeVertex | #ExtrudeEdge | #ExtrudeFace | #Bevel | #Inset | #Outline | #ExtrudeAlongSpline | #HingeFromEdge | #ConnectVertices | #ConnectEdges | #ChamferVertex | #ChamferEdge | #RemoveIsoVerts | #RemoveIsoMapVerts | #ToggleShadedFaces | #TransformVertex | #TransformEdge | #TransformFace | #Create | #Attach | #TargetWeldVertex | #TargetWeldEdge | #EditTriangulation | #TurnEdge | #CreateEdge | #CloneVertex | #CloneEdge | #CloneFace | #InsertVertexInEdge | #InsertVertexInFace | #Autosmooth | #SetSmooth | #SetMaterial | #SelectBySmooth | #SelectByMaterial | #BridgeBorder | #BridgePolygon | #BridgeEdge | #PreserveUVSettings | #RemoveEdgeRemoveVertices | #MakeHardEdges | #MakeSmoothEdges | #SelectHardEdges | #SelectSmoothEdges | #DeleteEdge}

編集ポリゴンモディファイヤを指定された操作モードにします。

<void>PopupDialog<enum>operation

operation enums: {#GrowSelection | #ShrinkSelection | #SelectEdgeLoop | #SelectEdgeRing | #GetStackSelection | #HideVertex | #HideFace | #HideUnselectedVertex | #HideUnselectedFace | #UnhideAllVertex | #UnhideAllFace | #NamedSelectionCopy | #NamedSelectionPaste | #Cap | #DeleteVertex | #DeleteFace | #RemoveVertex | #RemoveEdge | #DetachVertex | #DetachFace | #SplitEdges | #BreakVertex | #CollapseVertex | #CollapseEdge | #CollapseFace | #ResetSlicePlane | #Slice | #SliceSelectedFaces | #Cut | #WeldVertex | #WeldEdge | #CreateShape | #MakePlanar | #MakePlanarInX | #MakePlanarInY | #MakePlanarInZ | #Align | #Relax | #MeshSmooth | #Tessellate | #Retriangulate | #FlipFace | #FlipElement | #ExtrudeVertex | #ExtrudeEdge | #ExtrudeFace | #Bevel | #Inset | #Outline | #ExtrudeAlongSpline | #HingeFromEdge | #ConnectVertices | #ConnectEdges | #ChamferVertex | #ChamferEdge | #RemoveIsoVerts | #RemoveIsoMapVerts | #ToggleShadedFaces | #TransformVertex | #TransformEdge | #TransformFace | #Create | #Attach | #TargetWeldVertex | #TargetWeldEdge | #EditTriangulation | #TurnEdge | #CreateEdge | #CloneVertex | #CloneEdge | #CloneFace | #InsertVertexInEdge | #InsertVertexInFace | #Autosmooth | #SetSmooth | #SetMaterial | #SelectBySmooth | #SelectByMaterial | #BridgeBorder | #BridgePolygon | #BridgeEdge | #PreserveUVSettings | #RemoveEdgeRemoveVertices | #MakeHardEdges | #MakeSmoothEdges | #SelectHardEdges | #SelectSmoothEdges | #DeleteEdge}

対応するポップアップダイアログを開きます。

<void>ButtonOp<enum>operation

operation enums: {#GrowSelection | #ShrinkSelection | #SelectEdgeLoop | #SelectEdgeRing | #GetStackSelection | #HideVertex | #HideFace | #HideUnselectedVertex | #HideUnselectedFace | #UnhideAllVertex | #UnhideAllFace | #NamedSelectionCopy | #NamedSelectionPaste | #Cap | #DeleteVertex | #DeleteFace | #RemoveVertex | #RemoveEdge | #DetachVertex | #DetachFace | #SplitEdges | #BreakVertex | #CollapseVertex | #CollapseEdge | #CollapseFace | #ResetSlicePlane | #Slice | #SliceSelectedFaces | #Cut | #WeldVertex | #WeldEdge | #CreateShape | #MakePlanar | #MakePlanarInX | #MakePlanarInY | #MakePlanarInZ | #Align | #Relax | #MeshSmooth | #Tessellate | #Retriangulate | #FlipFace | #FlipElement | #ExtrudeVertex | #ExtrudeEdge | #ExtrudeFace | #Bevel | #Inset | #Outline | #ExtrudeAlongSpline | #HingeFromEdge | #ConnectVertices | #ConnectEdges | #ChamferVertex | #ChamferEdge | #RemoveIsoVerts | #RemoveIsoMapVerts | #ToggleShadedFaces | #TransformVertex | #TransformEdge | #TransformFace | #Create | #Attach | #TargetWeldVertex | #TargetWeldEdge | #EditTriangulation | #TurnEdge | #CreateEdge | #CloneVertex | #CloneEdge | #CloneFace | #InsertVertexInEdge | #InsertVertexInFace | #Autosmooth | #SetSmooth | #SetMaterial | #SelectBySmooth | #SelectByMaterial | #BridgeBorder | #BridgePolygon | #BridgeEdge | #PreserveUVSettings | #RemoveEdgeRemoveVertices | #MakeHardEdges | #MakeSmoothEdges | #SelectHardEdges | #SelectSmoothEdges | #DeleteEdge}

対応するユーザインタフェースボタンを押します。

<void>Commit()

ユーザインタフェースの[確認]ボタンを押した場合に相当します。編集を確認します。

<void>CommitUnlessAnimating()

モディファイヤがアニメーションモードでない場合は、ユーザインタフェースの[確認]ボタンを押します。

<void>CommitAndRepeat()

[確認] (Commit)ボタンを押し、前回の操作を繰り返します。

<void>Cancel()

[キャンセル] (Cancel)ボタンを押した場合に相当します。現在の操作で行われた変更がすべて取り消されます。

<void>ToggleCommandMode <enum>commandMode

commandMode enums: {#CreateVertex | #CreateEdge | #CreateFace | #DivideEdge | #DivideFace | #ExtrudeVertex | #ExtrudeEdge | #ExtrudeFace | #ChamferVertex | #ChamferEdge | #Bevel | #InsetFace | #OutlineFace | #SlicePlane | #Cut | #Weld | #EditTriangulation | #TurnEdge | #QuickSlice | #HingeFromEdge | #PickHinge | #BridgeBorder | #BridgePolygon | #PickBridgeTarget1 | #PickBridgeTarget2}

指定されたコマンドモードを切り替えます。有効になっている場合は無効にし、無効になっている場合は有効にします。

<enum>getCommandMode

現在のコマンドモードを返します(上記の toggleCommandMode() の列挙を参照)。コマンドモードが有効でない場合は、-1 を返します。

<void>EnterCommandMode <enum>commandMode

commandMode enums: {#CreateVertex | #CreateEdge | #CreateFace | #DivideEdge | #DivideFace | #ExtrudeVertex | #ExtrudeEdge | #ExtrudeFace | #ChamferVertex | #ChamferEdge | #Bevel | #InsetFace | #OutlineFace | #SlicePlane | #Cut | #Weld | #EditTriangulation | #TurnEdge | #QuickSlice | #HingeFromEdge | #PickHinge | #BridgeBorder | #BridgePolygon | #PickBridgeTarget1| #PickBridgeTarget2}

指定されたコマンドモードを有効にします。

<void>EnterPickMode <enum>commandMode

commandMode enums: {#Attach|#PickShape}

指定されたピックモードを入力します。

<enum>GetCommandMode()

GetCommandMode enums: {#CreateVertex| #CreateEdge| #CreateFace| #DivideEdge| #DivideFace| #ExtrudeVertex| #ExtrudeEdge| #ExtrudeFace| #ChamferVertex| #ChamferEdge| #Bevel| #InsetFace| #OutlineFace| #SlicePlane| #Cut| #Weld| #EditTriangulation| #TurnEdge| #QuickSlice| #HingeFromEdge| #PickHinge| #BridgeBorder| #BridgePolygon| #PickBridgeTarget1| #PickBridgeTarget2}

現在のコマンドモードを返します。有効になっているモードがない場合は -1 を返します。

<enum>GetPickMode()

GetPickMode enums: {#Attach|#PickShape}

現在のピックモードを返します。有効になっているモードがない場合は -1 を返します。

<void>RepeatLastOperation()

[ジオメトリを編集]ロールアウトで[最後のアクションを繰り返す]ボタンを押した場合に相当します。最後に行った操作を繰り返します。

<int>GetLastOperation()

最後に実行された操作を返し、RepeatLastOperation() が呼び出された場合に実行される操作を示します。このメソッドが返すことができる有効な値と対応する操作のリストについては、上記の currentOperation() を参照してください。

3ds Max 2020 以降で使用可能です。

<boolean>ShowOperationDialog()

操作ダイアログボックスを表示します。3ds Max 8 以降 で使用可能です。

<boolean>ShowingOperationDialog()

モディファイヤが操作ダイアログボックスを表示している場合は true、それ以外の場合は false を返します。3ds Max 8 以降 で使用可能です。

<void>CloseOperationDialog()

操作ダイアログボックスを閉じます。3ds Max 8 以降 で使用可能です。

トポロジ編集メソッド

スライスメソッド

<void>MoveSlicePlane <point3>amount parent:<matrix3> axis:<matrix3>
       parent default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       axis default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])

スライス平面を指定したPoint3 値で移動します。parent が指定されている場合は、そのローカル座標系が使用されます。axis が指定されている場合、カスタムの座標系としてそれを使用します。

<void>RotateSlicePlane <quat>amount parent:<matrix3> axis:<matrix3> localOrigin:<boolean>
       parent default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       axis default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       localOrigin default value: false

スライス平面を、指定の四元数値だけ回転します。parent が指定されている場合は、そのローカル座標系が使用されます。axis が指定されている場合、カスタムの座標系としてそれを使用します。localOrigin が指定されている場合、回転はスライス平面のローカル変換の中心の周りで行われます。

<void>ScaleSlicePlane <point3>amount parent:<matrix3> axis:<matrix3> localOrigin:<boolean>
       parent default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       axis default value: (matrix3 [1,0,0] [0,1,0] [0,0,1] [0,0,0])
       localOrigin default value: false

スライス平面を指定したPoint3 値でスケールします。parent が指定されている場合は、そのローカル座標系が使用されます。axis が指定されている場合、カスタムの座標系としてそれを使用します。localOrigin が指定されている場合、スケールはスライス平面のローカル変換の中心の周りで行われます。

<boolean>InSlicePlaneMode()

編集ポリゴンモディファイヤがスライス平面モードの場合は true、それ以外の場合は false を返します。

<void>ResetSlicePlane()

スライス平面をリセットします。

<matrix3 by value>GetSlicePlaneTM()

GetSlicePlaneTM - 呼び出し後に自動再描画は行われません。

スライス平面の変換行列を返します。

<void>SetSlicePlane <point3>planeNormal <point3>planeCenter

与えられた法線ベクトルと平面の中心を使用して、スライス平面の向きを設定します。

<void>GetSlicePlane <&point3>planeNormal <&point3>planeCenter

planeNormal is Out parameter
planeCenter is Out parameter

与えられた参照渡しの引数に書き込むことによって、平面の法線ベクトルと平面の中心を返します。

<boolean>InSlice()

モディファイヤがスライスモードの場合は true、そうでない場合は false を返します。3ds Max 8 以降 で使用可能です。

作成メソッド

<index>CreateVertex <point3>point node:<node>

node default value: undefined

指定されたポイントで新しい頂点を作成します。新しい頂点のインデックスを返します。

<index>CreateFace <index array>vertices node:<node>

node default value: undefined

与えられたインデックスの配列から新しい面を作成します。新しい面のインデックスを返します。

<index>CreateEdge <index>vertex1 <index>vertex2 node:<node>

node default value:undefined

2 つの指定された頂点インデックスの間にエッジを作成します。新しいエッジのインデックスを返します。

三角形化の編集メソッド

<void>SetDiagonal <index>vertex1 <index>vertex2 node:<node>

node default value: undefined

vertex1 と vertex2 の間の対角線を設定します。このメソッドは手動で三角形化を調整するために使用できます。

切り取りメソッド

<void>StartCut <enum>level <index>index <point3>point <point3>normal node:<node>

level enums: {#Object | #Vertex | #Edge | #Face | #CurrentLevel} node default value: undefined

指定されたサブオブジェクトレベルのカットモードになります。

<void>SetCutEnd <point3>endPoint node:<node>

node default value: undefined

オブジェクト空間で指定したポイントに切り取りの終端を設定します。オプションのノードパラメータを指定した場合は、そのオブジェクト空間でポイントが取られます。モディファイヤが複数のノードでインスタンス化されている場合に便利です。3ds Max 8 以降 で使用可能です。

<index>GetLastCutEnd()

最終切り取りの終端のインデックスを返します。3ds Max 8 以降 で使用可能です。

<void>ClearLastCutEnd()

最終切り取りの終端をクリアします。3ds Max 8 以降 で使用可能です。

<void>CutCancelnode:<node>

node default value: undefined

切り取りをキャンセルします。3ds Max 8 以降 で使用可能です。

連結メソッド

<void>WeldVertices <index>vertex1 <index>vertex2 node:<node>

node default value: undefined

指定された 2 つの頂点を連結します。

<void>WeldEdges <index>edge1 <index>edge2 node:<node>

node 既定値: undefined

指定された 2 つのエッジを連結します。

ブリッジメソッド

<void>BridgeBorders <index>edge1 <index>edge2 node:<node>

node default value: undefined

指定された 2 つのエッジをブリッジします。

<void>BridgePolygons<index>poly1 <index>poly2 node:<node>

node default value: undefined

指定された 2 つのポリゴンをブリッジします。

<void>BridgeEdges <index>edge1 <index>edg2 node:<node>

node default value: undefined

指定された 2 つのエッジをブリッジします。3ds Max 8 以降 で使用可能です。

<node>GetBridgeNode()

インデックスで指定されたブリッジノードを返します。

<void>SetBridgeNode<node>node

ブリッジノードを設定します。

editPolyModReadyToBridge <modifier>mod

指定した選択レベルとフラグについてブリッジの用意ができていれば true、その他の場合は false を返します。

分割メソッド

<index>DivideEdge <index>edgeID <float>proportion node:<node>

node default value: undefined

指定したエッジを特定比率で 2 つのエッジに分割します。3ds Max 8 以降 で使用可能です。

<index>DivideFace <index>faceID <float array>vertexCoefficients node:<node>

node default value: undefined

指定した頂点係数の配列を使用して、指定した面を分割します。3ds Max 8 以降 で使用可能です。

マップの保存メソッド

<boolean>GetPreserveMap <integer>mapChannel

指定されたマップチャネルの[UVを保存]の状態を返します。

<void>SetPreserveMap <integer>mapChannel <boolean>preserve

指定されたマップチャネルの[UVを保存]の状態を、指定されたブール値に設定します。

アタッチ/デタッチメソッド

<void>Attach <node>nodeToAttach editPolyNode:<node>

editPolyNode default value: undefined

指定されたノードをアタッチします。

<void>AttachList <node array>nodesToAttach editPolyNode:<node>
       editPolyNode default value: undefined

指定された複数のノードをアタッチします。

<void>DetachToObject <&string>newObjectName

newObjectName is In and Out parameter

選択したサブオブジェクト選択を、指定された名前の新しいオブジェクトにデタッチします。

シェイプの作成メソッド

<void>CreateShape <&string>newShapeName

newShapeName is In and Out parameter

選択したエッジから、与えられた名前のシェイプを作成します。

ジオメトリデータメソッド

<integer>GetNumVerticesnode:<node>

node default value: undefined

ポリゴン編集の頂点の数を返します。

<point3 by value>GetVertex <index>vertexID node:<node>

node default value: undefined

指定されたインデックスの頂点を返します。

<integer>GetVertexFaceCount <index>vertexID node:<node>

node default value: undefined

インデックスで指定された頂点を共有する面の数を返します。

<index>GetVertexFace <index>vertexID <index>face node:<node>

node default value: undefined

インデックスで指定された頂点を共有するインデックス付けされた面を返します。

<integer>GetVertexEdgeCount <index>vertexID node:<node>

node default value: undefined

インデックスで指定された頂点を共有するエッジの数を返します。

<index>GetVertexEdge <index>vertexID <inredex>edge node:<node>

node default value: undefined

インデックスで指定された頂点を共有するインデックス付けされたエッジを返します。

<integer>GetNumEdgesnode:<node>

node default value: undefined

エッジの数を返します。

<index>GetEdgeVertex <index>edgeID <index>end node:<node>

node default value: undefined

指定されたエッジで共有されるインデックス付けされた頂点を返します。

<index>GetEdgeFace <index>edgeID <index>side node:<node>

node default value: undefined

指定されたエッジで共有されるインデックス付けされた面を返します。

<integer>GetNumFacesnode:<node>

node default value: undefined

面の数を返します。

<integer>GetFaceDegree <index>faceID node:<node>

node default value: undefined

インデックスで指定された面の側面 (エッジ/頂点) の数を返します。3 の値は三角形の面、4 の値は四角形の面を意味します。

<index>GetFaceVertex <index>faceID <index>corner node:<node>

node default value: undefined

インデックスで指定された面のインデックスで指定されたコーナーで使用されている頂点を返します。

<index>GetFaceEdge <index>faceID <index>side node:<node>

node default value: undefined

インデックスで指定された面のインデックスで指定された側面で使用されているエッジを返します。

<index>GetFaceMaterial <index>faceID node:<node>

node default value: undefined

インデックスで指定された面のマテリアル ID を返します。

<integer>GetFaceSmoothingGroups <index>faceID node:<node>

node default value: undefined

インデックスで指定された面のスムージンググループを返します。スムージンググループは long 型の整数に格納され、32 ビットのそれぞれが 32 のスムージンググループの状態に対応します。

<integer>GetNumMapChannelsnode:<node>

node default value: undefined

マッピングチャネルの数を返します。

<boolean>GetMapChannelActive <integer>mapChannel node:<node>

node default value: undefined

指定されたマッピングチャネルがアクティブな場合は true を返し、それ以外の場合は false を返します。

<integer>GetNumMapVertices <integer>mapChannel node:<node>

node default value: undefined

指定されたマッピングチャネルのマップ頂点の数を返します。

<point3 by value> GetMapVertex <integer>mapChannel <index>vertexID node:<node>

node default value: undefined

指定されたマッピングチャネルからのインデックスで指定されたマップ頂点を返します。

<index>GetMapFaceVert <integer>mapChannel <index>faceID <index>corner node:<node>

node default value: undefined

指定されたマッピングチャネルのインデックスで指定された面の、インデックスで指定されたコーナーの頂点を返します。

その他のメソッド

<void>RefreshScreen()

変更を更新するには、画面を再描画します。3ds Max 8 以降 で使用可能です。

<void>SetPrimaryNode <node>node

主ノードを設定します。編集ポリゴンモディファイヤはどのような数のノードへのインスタンスとしても割り当てることができます。このメソッドは、主なノードはどれかを指定します。

<node>GetPrimaryNode()

主ノードを返します。3ds Max 8 以降 で使用可能です。

<matrix3 by value>GetNodeTMnode:<node>

node default value: undefined

ノード変換行列を返します。3ds Max 8 以降 で使用可能です。

<void>Listnode:<node>

node 既定値: undefined

<void>LocalDataChanged <integer>parts

3ds Max 8 以降 で使用可能です。

Edit_Poly: モディファイヤ

ポリゴンを編集モード

選択

ソフト選択

頂点/エッジ/縁取り/ポリゴン/要素を編集

頂点/エッジ/面の押し出し

連結

面取り

接続

アウトライン

ベベル

インセット

ブリッジ

Hinge

スプラインに沿って押し出し

頂点/エッジの削除

頂点のブレーク

エッジを分割

面/要素を反転

エッジ/面に頂点を挿入

分離頂点を除去

ジオメトリを編集する

[拘束]

UV を保存

[リラックス] (Relax)ダイアログ ボックス

スライス平面

位置合わせ平面

メッシュをスムーズ化

面分割

分離した頂点を削除

集約

表示/非表示

名前付き選択セットのコピー/貼り付け

平面化

[ポリゴン: マテリアル ID]

ポリゴン: スムージング グループ

ペイント変形

その他のプロパティ

ポリゴン編集インタフェース:

選択メソッド

演算メソッド

トポロジ編集メソッド

スライス メソッド

作成メソッド

三角形化の編集メソッド

切り取りメソッド

連結メソッド

ブリッジ メソッド

分割メソッド

マップの保存メソッド

アタッチ/デタッチ メソッド

シェイプの作成メソッド

ジオメトリ データ メソッド

その他のメソッド

関連ページ

[リラックス] (Relax)ダイアログボックス

ポリゴン: スムージンググループ

スライスメソッド

ブリッジメソッド

アタッチ/デタッチメソッド

ジオメトリデータメソッド