物理: カメラ

Physical - superclass: Camera; super-superclass:Node - 53:0 - classID: #(1181315608, 686293133)

物理カメラを MAXScript に公開します。3ds Max 2016 以降で使用可能です。

コンストラクタ:

Physical ...
Physical_Camera ...

DOF ボックスの例:

-- Reset Max File
resetmaxfile #noprompt

-- Set the viewport Matrix
viewport.setTM (matrix3 [1,0,0] [0,0,-1] [0,1,0] [6,-150,-800])

-- Create a box
bx = box width:500 height:300 length:2000 backfacecull:true mapcoords:on
addModifier bx (normalModifier flip:true)

-- Create a checker map with tiling in U and V at 10
mp1 = checker color1:[0,200,255] color2:[255,255,200]
mp1.coords.U_Tiling = 10
mp1.coords.V_Tiling = 10

-- Assign a physical material to the box
bx.material = PhysicalMaterial base_color_map:mp1

-- Create and assign to the scene a Physical_Camera_Exposure_Control
SceneExposureControl.exposureControl = Physical_Camera_Exposure_Control()

-- Create a photometric Freelight
om = Free_Light pos:[0,-300,250] global_ev:6

-- Create a Sphere
sph = sphere radius:50 pos:[0,0,50] segs:32
sph.material = PhysicalMaterial base_color:green

-- Create 2 Teapots
tp1 = teapot radius:50 pos:[80,-250,0]
tp1.material = PhysicalMaterial base_color:red

tp2 = teapot radius:50 pos:[-100,500,0]
tp2.material = PhysicalMaterial base_color:blue

-- Switch to High Quality Viewport
actionMan.executeAction -844228238 "12"  --  Viewport Lighting and Shadows: High Quality

-- Create a physical camera from the viewport
macros.run "Lights and Cameras" "PhysicalCamera_CreateFromView"

-- Retrieve the just created camera in the scene "cameras" array
physCam = cameras[1]

-- Place the physical camera target on the sphere
physCam.Target.pos = sph.pos

-- Set a small aperture
physCam.f_number = 0.058

-- Enable Depth of Field in the camera/viewport
physCam.use_dof = on

結果:

プロパティ:

基本ロールアウト

<Physical>.targeted     BooleanClass    default: true   --  boolean

[ターゲット] (Targeted)チェックボックスの状態を取得/設定します。

True (既定)に設定すると、カメラが専用のターゲットオブジェクトを見て、その向きをコントロールします。まっすぐ下を見ると、アップベクトルが XY 平面にあることが原因で、ジンバルロックの問題が発生することがあります。

False に設定すると、カメラは自由になり、ジンバルロックの問題を発生させることなく、独自の変換コントローラだけを使用して、自由に方向を変えることができます。

<Physical>.target_distance     Float    default: 196.85   --  animatable; worldUnits

.targeted 値を True に設定すると、カメラからそのターゲットオブジェクトまでの距離で定義されたターゲットまでの距離を取得します。ターゲットモードの時にこの値を設定すると、カメラとそのターゲットオブジェクト間の実際の距離には影響を及ぼしませんが、その値はカメラ内に保存されます。.targeted プロパィを False に変更すると、値はカメラとそのターゲットオブジェクト間の最新の距離で更新されます。

.targeted プロパティが False に設定されている場合、ターゲットまでの距離を取得/設定します。

<Physical>.show_camera_cone     Integer    default: 0   --  integer

[カメラの円錐を表示](Show Camera Cone)ドロップダウンリストの選択を取得/設定します。

有効な値は次のとおりです。

0 - 選択時(既定)

1 - 常時

2 - しない

<Physical>.horizon_on     BooleanClass    default: false   --  animatable; boolean; Show_Horizon_Line

[水平線を表示](Show Horizon Line)チェックボックスの状態を取得/設定します。

True に設定すると、カメラを通して見た時に、ビューポートに水平線が表示されます。

物理カメラロールアウト

コントロールのフィルム/センサーグループ

<Physical>.film_preset     String    default: "35mm"   --  string

[プリセット] (Preset )ドロップダウンリストの選択を取得/設定します。

この値を設定すると、.film_width_mm と .fov プロパティがプリセット値に設定されます。

有効な値は次のとおりです。

"35mm" - 既定 - 35mm (フルフレーム) - 幅 36.0mm

"APS-C (Canon)" - APS-C (Canon) - 幅 22.3mm

"APS-C (Nikon)" - APS-C (Nikon、Sony など) - 幅 23.7mm

"APS-H (Canon)" - APS-H (Canon) - 幅 27.9mm

"Four Thirds" - フォーサーズ - 幅 17.3mm

"Custom" - カスタム - カスタム幅

<Physical>.film_width_mm     Float    default: 36.0   --  animatable; float

フィルムの幅をミリメートルでコントロールする[幅] (Width)スピナーの値を取得/設定します。

コントロールのレンズグループ

<Physical>.focal_length_mm     Float    default: 40.0   --  animatable; worldUnits; Lens_Focal_Length_mm

カメラの焦点距離をミリメートルでコントロールする[焦点距離](Focal Length)スピナーの値を取得/設定します。

<Physical>.specify_fov     BooleanClass    default: false   --  boolean

[視野を指定](Specify FOV)チェックボックスの状態を取得/設定します。

True に設定すると、カメラに視野を適用するのに .fov プロパティが使用されます。

False (既定)に設定すると、視野はフィルム/センサー幅、焦点距離、ズーム値から自動的に計算されます。

<Physical>.fov     Float    default: 48.112   --  animatable; float

.specify_fov プロパティが True に設定されているときに使用される、明示的な視野の値を取得/設定します。

<Physical>.zoom_factor     Float    default: 1.0   --  animatable; float

[ズーム] (Zoom)スピナーの値を取得/設定します。

この値を 1.0 より大きい値に増やすと、視野が狭くなりズームインされます。

1.0 より小さい値にすると、視野が広がりズームアウトされます。

<Physical>.f_number     Float    default: 8.0   --  animatable; float

[絞り] (Aperture)スピナーの値を取得/設定します。

これは .f_number プロパティに f として表されます。

コントロールのフォーカスグループ

<Physical>.specify_focus     Integer    default: 0   --  animatable; integer; Specify_Focus_Distance

[フォーカス] (Focus)ラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - タ-ゲットまでの距離を使用 - カメラとそのターゲットオブジェクト間の距離。フリーモード時の明示的なターゲットまでの距離の値は、焦点となる被写体の位置を定義するために使用されます。

1 - カスタム - .focus_distance プロパティによって提供される明示的な値が、焦点となる被写体までの距離を定義するために使用されます。

<Physical>.focus_distance     Float    default: 196.85   --  animatable; worldUnits

[焦点距離](Focus Distance)スピナーの値を取得/設定します。

このプロパティは、.specify_focus プロパティが 1 (カスタム)に設定されている場合にのみ使用されます。

<Physical>.lens_breathing_amount     Float    default: 1.0   --  animatable; float

[レンズのブリーズ](Lens Breathing)スピナーの値を取得/設定します。

<Physical>.use_dof     BooleanClass    default: false   --  boolean; Enable_DOF

[被写界深度を有効化](Enable Depth Of Field)チェックボックスの状態を取得/設定します。

コントロールのシャッターグループ

<Physical>.shutter_unit_type     Integer    default: 3   --  integer

[タイプ] (Type)ドロップダウンリストの選択を取得/設定します。

有効な値は次のとおりです。

0 - 1/秒

1 - 秒

2 - 角度

3 - フレーム(既定)

モード 0 と 1 は、モード 2 と 3 とは異なるプロパティセットを使用して、長さとオフセットを指定します。このプロパティが変更されてもそれぞれの値は同期されません。たとえば、モードが 1/秒に設定されていて、.shutter_offset_frames プロパティの設定でオフセットが 0.005 (1/200.0 秒)に変更された場合、UI を角度またはフレームの表示に切り替えると、.shutter_offset_seconds プロパティを使用して明示的に変更しない限り、オフセットは 0.0 で表示されます。

<Physical>.shutter_length_frames     Float    default: 0.5   --  animatable; float

.shutter_unit_type プロパティが 2 (角度)または 3 (フレーム)に設定されている場合に使用される[長さ(フレーム数)] (Duration)スピナーの値を取得/設定します。

角度の表示の場合、UI では長さ(フレーム数)が角度で表されますが、プロパティはフレームとして内部的に設定されることに注意してください。

たとえば、プロパティを 1.0 フレームに設定すると、タイプを角度に設定し、1.0 をフレームに設定した場合に、UI は 360 度の表示になります。

<Physical>.shutter_length_seconds     Float    default: 0.001   --  animatable; float

.shutter_unit_type プロパティが 0 (1/秒)または 1 (秒)に設定されている場合に使用される[長さ(フレーム数)] (Duration)スピナーの値を取得/設定します。

値は常に 1/秒として内部的に表され、一方、UI は .shutter_unit_type プロパティに従ってスピナーを 1/秒と秒に切り替えることに注意してください。たとえば、内部値が 0.001 の場合、UI にはドロップダウンリストの設定に応じて 1000.0 または 0.001 として表示されます。

<Physical>.shutter_offset_enabled     BooleanClass    default: false   --  boolean

[オフセット] (Offset)チェックボックスの状態を取得/設定します。

False (既定)に設定すると、シャッターオフセットは 0.0 とみなされます。

True に設定すると、現在のシャッタータイプ(秒またはフレーム)に対応するシャッターオフセット値が使用されます。詳細については、次の 2 つのプロパティを参照してください。

<Physical>.shutter_offset_frames     Float    default: 0.0   --  animatable; float

.shutter_unit_type プロパティが 2 (角度)または 3 (フレーム)に設定されている場合に使用される[オフセット] (Offset)スピナーの値を取得/設定します。

角度の表示の場合、UI では長さ(フレーム数)が角度で表されますが、プロパティはフレームとして内部的に設定されることに注意してください。

たとえば、プロパティを 0.5 フレームに設定すると、タイプを角度に設定し、0.5 をフレームに設定した場合に、UI は 180 度の表示になります。

<Physical>.shutter_offset_seconds     Float    default: 0.0   --  animatable; float

.shutter_unit_type プロパティが 0 (1/秒)または 1 (秒)に設定されている場合に使用される[オフセット] (Offset)スピナーの値を取得/設定します。

<Physical>.motion_blur_enabled     BooleanClass    default: false   --  boolean

[モーションブラーを有効化](Enable Motion Blur)チェックボックスの状態を取得/設定します。

露出ロールアウト

コントロールの露出ゲイングループ

<Physical>.exposure_gain_type     Integer    default: 1   --  integer

[露出ゲイン](Exposure Gain)ラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - 手動 - .iso プロパティを使用

1 - ターゲット(既定) - .exposure_value プロパティを使用

<Physical>.iso     Float    default: 6000.0   --  animatable; float

.exposure_gain_type プロパティが 0 (手動)に設定されている場合に使用される[手動による ISO](Manual ISO)スピナーの値を取得/設定します。

<Physical>.exposure_value     Float    default: 6.0   --  animatable; float

.exposure_gain_type プロパティが 1 (ターゲット)に設定されている場合に使用される[ターゲット EV](Target ... EV)スピナーの値を取得/設定します。

コントロールのホワイトバランスグループ

<Physical>.white_balance_type     Integer    default: 0   --  integer

[ホワイトバランス](White Balance)ラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - 光源(既定) - .white_balance_illuminant プロパティを使用

1 - 温度 - .white_balance_kelvin プロパティを使用

2 - カスタム - .white_balance_custom プロパティを使用

<Physical>.white_balance_illuminant     Integer    default: 0   --  integer

.white_balance_type property プロパティが 0 に設定されている場合に使用される[光源] (Illuminant)ドロップダウンリストの選択を取得/設定します。

有効な値は次のとおりです。

0 - デイライト(6500K)

1 - サンライト(5200K)

2 - シェーディング(7000K)

3 - オーバーキャスト(6000K)

4 - 白熱光(3200K)

5 - 蛍光灯(4000K)

6 - CIE A - 白熱灯/タングステン

7 - CIE D50 - 水平ライト

8 - CIE D55 - 午前/午後のデイライト

9 - CIE D65 - 正午のデイライト

10-CIE D75 - 極北デイライト

11 -CIE F1 - 蛍光灯のデイライト

12 -CIE F2 - 蛍光灯冷白色

13-CIE F3 - 蛍光灯白色

14-CIE F4 - 蛍光灯温白色

15-CIE F5 - 蛍光灯デイライト

16 -CIE F6 - 蛍光灯白色

17 -CIE F7 - 蛍光灯 D65 シミュレータ

18 -CIE F8 - 蛍光灯 D60 シミュレータ

19-CIE F9 - 蛍光灯冷白光

20 -CIE F10 - 蛍光灯 TL-85

21 -CIE F11 - 蛍光灯 TL-84

22 -CIE F12 - 蛍光灯 TL-83

23 -ハロゲン灯暖色(2800K)

24 -ハロゲン灯(3200K)

25 -ハロゲン灯寒色(4000K)

26 -HID セラミックメタルハロゲン灯暖色(3000K)

27 -HID セラミックメタルハロゲン灯寒色(4200K)

28 -HID クォーツメタルハロゲン灯暖色(3200K)

29 -HID クォーツメタルハロゲン灯(4000K)

30 -HID クォーツメタルハロゲン灯寒色(6000K)

31-HID 水銀灯(3900K)

32 -HID 燐光水銀灯(4000K)

33 -HID キセノン(6000K)

34 -高圧ナトリウム灯(2100K)

35 -低圧ナトリウム灯(1800K)

<Physical>.white_balance_kelvin     Float    default: 6500.0   --  animatable; float; White_Balance_Temperature

.white_balance_type プロパティが 1 に設定されている場合に使用される[温度] (Temperature)スピナーの値を取得/設定します。

<Physical>.white_balance_custom     Color    default: (color 255 255 255 0)   --  animatable;
fRGBA color;
Controller Scaling: ([1,1,1,1] : (color 255 255 255));

プロパティが 2 に設定されている場合に使用される[カスタム] (Custom).white_balance_typeカラーピッカーの値を取得/設定します。

<Physical>.vignetting_enabled     BooleanClass    default: false   --  boolean

[周辺減光を有効化](Enable Vignetting)チェックボックスの状態を取得/設定します。

True に設定すると、レンダリングされたイメージに周辺減光が適用されます。

False に設定すると、周辺減光は適用されません。

<Physical>.vignetting_amount     Float    default: 1.0   --  animatable; float

.vignetting_enabled が true に設定されている場合に周辺減光量をコントロールする[量] (Amount)スピナーの値を取得/設定します。

ぼけ効果(被写界深度)ロールアウト

コントロールの絞りの形状グループ

<Physical>.bokeh_shape     Integer    default: 0   --  animatable; integer

[絞りの形状](Aperture Shape)ラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - 円形(既定)

1 - ブレード型

2 - カスタムテクスチャ

<Physical>.bokeh_blades_number     Integer    default: 7   --  animatable; integer

.bokeh_shape が 1 に設定されている場合に使用される[枚] (Blades)スピナーの値を取得/設定します。

これはぼけ効果の羽根の枚数をコントロールします。

<Physical>.pb_bokeh_blades_rotation_degrees     Float    default: 0.0   --  animatable; float; Bokeh_Blades_Rotation_Degrees

.bokeh_shape が 1 に設定されている場合に使用される[回転] (Rotation)スピナーの値を取得/設定します。

ぼけ効果の羽根の回転角度を定義します。

<Physical>.bokeh_texture     UndefinedClass    default: undefined   --  texturemap; Bokeh_Bitmap

.bokeh_shape が 2 に設定されている場合に使用されるカスタムぼけテクスチャマップを取得/設定します。

<Physical>.bokeh_texture_affect_exposure     BooleanClass    default: true   --  boolean; Bokeh_Bitmap_Affect_Exposure

.bokeh_shape が 2 に設定されている場合に使用される[露出に影響](Affect Exposure)チェックボックスの状態を取得/設定します

True (既定)に設定すると、ぼけテクスチャも露出に影響します。

<Physical>.bokeh_center_bias     Float    default: 0.0   --  animatable; float

[センターバイアス(リングエフェクト)](Center Bias (Ring Effect))スライダの値を取得/設定します。

<Physical>.bokeh_optical_vignetting     Float    default: 0.0   --  animatable; float

[光学周辺減光(Cat Eye 効果)](Optical Vignetting (Cat Eye))スライダの値を取得/設定します。

<Physical>.bokeh_anisotropy     Float    default: 0.0   --  animatable; float

[異方性反射(アナモルフィックレンズ)] (Anisotropy (Anamorphic Lens))スライダの値を取得/設定します。

有効な値の範囲は -1.0 (垂直)から 1.0 (水平)です。

パース制御ロールアウト

コントロールのレンズシフトグループ

<Physical>.horizontal_shift     Float    default: 0.0   --  animatable; float; Controller Scaling: (1 : 100.0);

[水平] (Horizontal)スピナーの値を取得/設定します。

負の値にするとイメージが左にシフトします。

正の値にするとイメージが右にシフトします。

<Physical>.horizontal_shift     Float    default: 0.0   --  animatable; float; Vertical_Shift; Controller Scaling: (1 : 100.0

[垂直] (Vertical)スピナーの値を取得/設定します。

負の値にするとイメージが下にシフトします。

正の値にするとイメージが上にシフトします。

コントロールの傾斜の補正グループ

<Physical>.horizontal_tilt_correction     Float    default: 0.0   --  animatable; float

[水平] (Horizontal)スピナーの値を取得/設定します。

<Physical>.vertical_tilt_correction     Float    default: 0.0   --  animatable; float

[垂直] (Vertical)スピナーの値を取得/設定します。

<Physical>.auto_vertical_tilt_correction     BooleanClass    default: false   --  animatable; boolean

[自動垂直傾斜補正](Auto Vertical Tilt Correction)チェックボックスの状態を取得/設定します。

レンズ歪みロールアウト

<Physical>.distortion_type     Integer    default: 0   --  integer

[歪みのタイプ](Distortion Type)ラジオボタンの状態を取得/設定します。

有効な値は次のとおりです。

0 - なし (既定値)

1 - キュービック

2 - テクスチャ

<Physical>.distortion_cubic_amount     Float    default: 0.0   --  animatable; float

.distortion_type プロパティが 1 に設定されている場合に使用される[量] (Amount)スピナーの値を取得/設定します。

<Physical>.distortion_texture     UndefinedClass    default: undefined   --  texturemap

.distortion_type プロパティが 2 に設定されている場合に使用されるテクスチャマップを取得/設定します。

その他ロールアウト

コントロールのクリッピング平面グループ

<Physical>.clip_on     BooleanClass    default: false   --  boolean; Clipping_Enabled

[有効] (Enable)チェックボックスの状態を取得/設定します。

False (既定)に設定すると、自動的にクリッピングが実行されます。

True に設定すると、近接クリップおよび遠方クリップの値が使用されます。

<Physical>.clip_near     Float    default: 0.0   --  animatable; worldUnits; Clipping_Near

<Physical>.near_clip     Float    default: 0.0   --  animatable; alias for clip_near

<Physical>.nearclip     Float    default: 0.0   --  animatable; alias for clip_near

.clip_on プロパティが 1 に設定されている場合に使用される[近接] (Near)スピナーの値を取得/設定します。

カメラの位置から近接クリッピング平面までの距離をワールド単位で定義します。この距離よりもカメラに近いポイントはレンダリングされません。

<Physical>.clip_far    Float    default: 39370.1   --  animatable; worldUnits; Clipping_Far

<Physical>.far_clip   Float    default: 39370.1   --  animatable; alias for clip_far

<Physical>.farclip     Float    default: 39370.1   --  animatable; alias for clip_far

.clip_on プロパティが 1 に設定されている場合に使用される[近接] (Far)スピナーの値を取得/設定します。

カメラの位置から遠方クリッピング平面までの距離をワールド単位で定義します。

この距離よりカメラから離れているポイントはレンダリングされません。

コントロールの環境範囲領域

<Physical>.environment_far     Float    default: 39370.1   --  animatable; worldUnits; Environment_Range_Far

<Physical>.farrange     Float    default: 39370.1   --  animatable; alias for environment_far

[近接範囲](Near Range)スピナーの値を取得/設定します。

フォグのようなカメラベースの環境効果が効果の近接範囲を定義するために使用されます。

<Physical>.environment_near    Float    default: 0.0   --  animatable; worldUnits; Environment_Range_Near

<Physical>.nearrange    Float    default: 0.0   --  animatable; alias for environment_near

[遠方範囲](Far Range)スピナーの値を取得/設定します。

フォグのようなカメラベースの環境効果が効果の遠方範囲を定義するために使用されます。

ユーザインタフェースには公開されていません

<Physical>.show_focus_plane_in_cam_view     BooleanClass    default: false   --  animatable; boolean; Show_Focus_Plane_in_Camera_View

False に設定すると、半透明なフォーカスプレーンが、ビューポートが物理カメラに設定されている場合に描画されなくなります。

True に設定すると、半透明なフォーカスプレーンは、物理カメラビューポートに表示されます。

物理: カメラ

プロパティ:

関連ページ