Häufig gestellte Fragen: Wie kann ich ein Projekt oder einen Ordner mit Zeichnungsdateien in der aktuellen Version neu abspeichern?

Speichern Sie ein Projekt oder ein Verzeichnis mit Zeichnungsdateien aus einer früheren Version mithilfe einer Stapeldatei in der aktuellen Version neu ab.

Sie können das erneute Abspeichern von Zeichnungsdateien, die in Vorgängerversionen des AutoCAD Architecture 2024-Toolset gespeichert wurden, in der aktuellen Version mithilfe einer Stapeldatei automatisieren.

Durch Ausführen der Stapeldatei wird eine vollständige Kopie des Projekts oder des Ordners mit Zeichnungen aus Vorgängerversionen erstellt. Anschließend wird rekursiv nach allen DWG-, DWT- und DWS-Dateien an diesem Speicherort gesucht und eine Skriptdatei erstellt.

Durch Ausführen der Skriptdatei werden alle kopierten DWG- und DWT-Dateien geöffnet, gespeichert und geschlossen. Dadurch werden alle DWG- und DWT-Dateien in der aktuellen Version neu abgespeichert.

Im Skript werden die Pfade zu den DWS-Dateien angezeigt. Sie müssen die DWS-Dateien manuell öffnen und sie in der aktuellen Version speichern.

Wichtig: Erstellen Sie eine Sicherungskopie aller Dateien, bevor Sie die Stapel- und Skriptdateien ausführen. Wenn Sie ein Projekt an einen neuen Speicherort kopiert haben, verknüpfen Sie das Projekt vor dem Ausführen der Stapeldatei erneut mit der ursprünglichen Version des AutoCAD Architecture 2024-Toolset.

So importieren Sie Dateien mithilfe einer Stapeldatei in die aktuelle Version

Wichtig: Stellen Sie sicher, dass Sie die Schritte genau beachten.

Starten Sie den Microsoft®-Editor.
Kopieren Sie den Text (Stapeldatei) zwischen den beiden gestrichelten Linien in den Editor.
Speichern Sie die Datei unter dem Namen promote.bat, und schließen Sie den Editor.

Führen Sie in der Windows®-Befehlszeile die Datei promote.bat unter Verwendung der folgenden Syntax aus:

promote.bat [projectName] [projectLocation] [scriptName] [promotionTarget] 
Replace [projectName] with the name of the original folder containing the drawings to be imported to the current version. 
Replace [projectLocation] with the path to the original folder entered as [projectName]. 
Replace [scriptName] with the name of the script that will be generated. The root of the file name can be customized but the file extension must always be .scr. 
Replace [promotionTarget] with a path and folder name of the location where the imported drawings must be copied.

Anmerkung: Argumente, die Leerzeichen enthalten, müssen in Anführungszeichen eingeschlossen werden. Wenn Sie z. B. Zeichnungen aus Vorgängerversionen im Ordner R:\CAD_Files\Projects\2010\Hospital gespeichert haben und möchten, dass die neu abgespeicherten Dateien im Ordner R:\CAD_Files\Projects\2014\Hospital erstellt werden, verwenden Sie die folgende Syntax:

promote.bat Hospital R:\CAD_Files\Projects\2010\ promote.scr R:\CAD_Files\Projects\2014

Zum Schluss wird eine Skriptdatei mit dem von Ihnen angegebenen Namen im selben Ordner wie die Datei promote.bat erstellt. Führen Sie diese Skriptdatei aus, um jede der kopierten Zeichnungen im Ordner [Umwandlungsziel] in der aktuellen Version neu abzuspeichern.

Stapeldatei

--------------------------------------------------------------------------------------------
@echo off
SETLOCAL
@rem promote.bat
@rem This script promotes a project to the current DWG format.
:Greeting
echo.
echo This script promotes a project to the current DWG format.
echo For best results, please run this script using administrator privileges in Windows.
echo.
PAUSE
:checkCmdArgs
if [%4] EQU [] goto :badArgCount
if [%3] EQU [] goto :badArgCount
if [%2] EQU [] goto :badArgCount
if [%1] EQU [] goto :badArgCount
if [%5] NEQ [] goto :badArgCount
set prjName=%1
set prjDir=%2
set scrName=%3
set targetDir=%4
goto :checkProject
:getProject
set /P prjName="What is the name of the project?: "
set /P prjDir="Where can it be found?: "
goto :checkProject
:checkProject
set prjNameEsc=%prjName:&=^&%
set firstChar=%prjName:~0,1%
if ^%firstChar% EQU ^" set prjName=%prjNameEsc:~1,-1%
set prjNameDisplay=%prjName:&=^^^&%
set prjDirEsc=%prjDir:&=^&%
set firstChar=%prjDir:~0,1%
if ^%firstChar% EQU ^" set prjDir=%prjDirEsc:~1,-1%
set prjDirDisplay=%prjDir:&=^^^&%
set project="%prjDir%\%prjName%"
if not exist %project% goto :noProject
if not defined scrName (goto :getScript) else (goto :checkScript)
:getScript
set /P scrName="Specify a name for the ACAD script: "
goto :checkScript
:checkScript
set scrNameEsc=%scrName:&=^&%
set firstChar=%scrName:~0,1%
if ^%firstChar% EQU ^" set scrName=%scrNameEsc:~1,-1%
set scrExt=%scrName:~-4%
if /I "%scrExt%" NEQ ".scr" set scrName=%scrName%.scr
set scrNameDisplay=%scrName:&=^^^&%
if exist "%scrName%" goto :scrFound
if not defined targetDir (goto :getTarget) else (goto :checkTarget)
:getTarget
set /P targetDir="Specify a directory to host the promoted project: "
goto :checkTarget
:checkTarget
set targetDirEsc=%targetDir:&=^&%
set firstChar=%targetDir:~0,1%
if ^%firstChar% EQU ^" set targetDir=%targetDirEsc:~1,-1%
set targetDirDisplay=%targetDir:&=^^^&%
set prjDest="%targetDir%\%prjName%"
if not exist "%targetDir%" (
md "%targetDir%"
echo.
echo Created target directory %targetDirDisplay%
goto :copyProject
) else (
if exist %prjDest% (goto :targetFound) else (goto :copyProject)
)
ENDLOCAL
exit /B
:badArgCount
echo.
echo This utility can be run as a single command with the following syntax:
echo.
echo promote.bat [projectName] [projectLocation] [scriptName] [promotionTarget].
echo.
goto :getProject
:noProject
echo.
echo You have specified a project %prjNameDisplay% in the directory %prjDirDisplay%.
echo This could not be found. Please try again.
echo.
goto :getProject
:badScrExt
echo.
echo Your Autocad script must have the extension ".scr" and you specified %scrNameDisplay%.
echo Please try again.
echo.
goto :getScript
:scrFound
echo.
echo An Autocad script with the name %scrNameDisplay% is already present in the working directory.
echo Delete this script or specify a different script name.
echo.
goto :getScript
:targetFound
echo.
echo A project with name %prjNameDisplay% was found in the target area %targetDirDisplay%.
echo Delete this project or specify another target area.
echo.
goto :getTarget
:copyProject
echo.
CLS
echo Copying project %prjNameDisplay%...
xcopy %project% %prjDest% /E /I /Q /H
attrib -A -R %prjDest% /D /S
echo Copied project %prjNameDisplay% to %prjDest%.
echo.
goto :genScript
:genScript
echo.
set count=0
@for /R %prjDest% %%i in (*.dwg) do (
set /a count+=1
echo _open "%%i">>"%scrName%"
echo _qsave>>"%scrName%"
echo _close>>"%scrName%"
)
echo Found %count% DWG files to be updated in the project %prjNameDisplay%.
set /a totalFiles=%count%
set count=0
@for /R %prjDest% %%i in (*.dwt) do (
set /a count+=1
echo _open "%%i">>"%scrName%"
echo _qsave>>"%scrName%"
echo _close>>"%scrName%"
)
echo Found %count% DWT files to be updated in the project %prjNameDisplay%.
echo.
set /a totalFiles=%totalFiles%+%count%
if %totalFiles% == 0 (
echo.
echo No DWG or DWT files were found in the project %prjName%!
echo There is nothing to promote.
echo.
echo Deleting the copy of %prjName% from %targetDir%.
echo The directory %targetDir% has been retained in case other folders or files are present.
echo.
RMDIR /Q/S %prjDest%
) else (
echo.
echo TO COMPLETE THE PROMOTION:
echo.
echo [1] Start ADT and make sure that a project is NOT currently active.
echo [2] Disable the previous version courtesy dialog using the AecFileOpenMessage command.
echo [3] Verify that the copy of the project located at %targetDirDisplay% has the same
echo file count as the original copy located at %prjDirDisplay%.
echo [4] Run the script %scrNameDisplay%.
@for /R %prjDest% %%i in (*.dws) do (
set /a foundDWS=1
goto :break
)
:break
if DEFINED foundDWS (
echo [5] Resave the following DWS file^(s^), making sure to preserve filenames.
echo ^(These cannot be promoted via a script as DWT and DWG files can.^)
echo.
@for /R %prjDest% %%i in (*.dws) do (
echo %%i
)
)
echo.
echo.
echo The project %prjNameDisplay% located in %targetDirDisplay% will then be promoted
echo to the current file format.
echo.
echo After this process is complete you may use this project
echo where it currently resides, or replace the old one with this new copy.
echo.
)
ENDLOCAL
exit /B
------------------------------------------------------------------------------------------------------

Fehlerbehebung

Wenn bei Verwendung dieses Skripts eine Zeichnung in einer Vorgängerversion geöffnet ist und ein Dialogfeld angezeigt wird, wird das Skript beendet. So fahren Sie mit dem erneuten Abspeichern der übrigen Zeichnungen in der aktuellen Version fort:

Bearbeiten Sie die Skriptdatei, und entfernen Sie alle Referenzen bis zur letzten Zeichnung der Vorgängerversion, die erfolgreich neu abgespeichert wurde.
Ermitteln Sie die Ursache für die unerwünschte Anzeige des Dialogfelds, und ergreifen Sie die entsprechenden Maßnahmen, um das Problem zu beheben.
Führen Sie die geänderte Skriptdatei aus. Die verbleibenden kopierten Zeichnungen sollten in der aktuellen Version neu abgespeichert werden.

Wird die Ausführung des Skripts häufig aufgrund der Anzeige unerwarteter Dialogfelder unterbrochen, geben Sie in der Befehlszeile des AutoCAD Architecture 2024-Toolset AecFileOpenMessage ein und ändern den Wert in Nein.

Wichtig: Setzen Sie den Wert AecFileOpenMessage nach Abschluss des erneuten Abspeicherns wieder auf Ja.

Häufig gestellte Fragen: Wie kann ich ein Projekt oder einen Ordner mit Zeichnungsdateien in der aktuellen Version neu abspeichern?

Stapeldatei

Fehlerbehebung

Zugehörige Konzepte