BeginModal イベント(ActiveX)

モーダル ダイアログが表示される直前に開始されます。

サポートされているプラットフォーム: Windows のみ

構文と要素

VBA:

object.BeginModal()

object

タイプ: Application

有効なコンテナ オブジェクトを評価するオブジェクト式この場合、有効なコンテナはアプリケーションだけです。

注意

モーダル ダイアログが表示されている間、イベントは発生しません。

BeginModal イベントのイベント ハンドラ内からメッセージ ボックスを起動させないでください。

例

VBA:

Public WithEvents ACADApp As AcadApplication    ' Use with Application Event Examples
Sub Example_AcadApplication_Events()
    ' This example intializes the public variable (ACADApp) which will be used
    ' to intercept AcadApplication Events
    '
    ' The VBA WithEvents statement makes it possible to intercept an generic object
    ' with the events associated with that object.
    '
    ' Before you will be able to trigger any of the AcadApplication events,
    ' you will first need to run this procedure.
    
    ' We could get the application from the ThisDocument object, but that would
    ' require having a drawing open, so we grab it from the system.
    Set ACADApp = GetObject(, "AutoCAD.Application.25.0")
End Sub

Private Sub ACADApp_BeginModal()
    ' This example intercepts an Application BeginModal event.  We use a Beep instead of
    ' a message box to notify the user when the event is triggered, since a message box
    ' is a modal entity and would cause continuous BeginModal/EndModal events to be triggered.
    '
    ' This event is triggered when AutoCAD displays a modal dialog.
    '
    ' To trigger this example event:
    '     1) Make sure to run the example that initializes
    '     the public variable (named ACADApp) linked to this event.
    '
    '     2) Use AutoCAD to begin a modal dialog operation.
    '     For example, use AutoCAD to display a modal file dialog by using File/New

    Beep  ' A modal dialog is about to be displayed!
End Sub

Visual LISP:

Not available