ジャンプ先: 概要. 戻り値. フラグ. MEL 例.

概要

loadUI [-listTypes] [-uiFile string] [-uiString string] [-verbose] [-workingDirectory string]

loadUI は、取り消し可能、照会不可能、および編集不可能です。

loadUI を使用すると、Qt ユーザ インタフェース (.ui) ファイルから Maya ユーザ インタフェースを生成できます。インタフェースの作成時に、Qt ウィジェットのクラスが認識され、Maya に相当するウィジェットが存在する場合は、Maya に相当するウィジェットが使用されます。「-」で始まるダイナミック ウィジェット プロパティは MEL のキーと値のペアとして扱われます。「+」で始まるウィジェット プロパティは Python のキーと値のペアとして扱われます。プロパティは、作成時にウィジェットに適用されます。UI ファイルの詳細については、Qt のドキュメントを参照してください。

戻り値

stringルート コントロールへのフル パス名

フラグ

listTypes, uiFile, uiString, verbose, workingDirectory
ロング ネーム(ショート ネーム) 引数タイプ プロパティ
-listTypes(-lt) create
認識された UI タイプと接続された Maya コマンドのリストを返します。
-uiFile(-f) string create
ユーザ インタフェース ファイルをロードするためのフル パス
-uiString(-s) string create
フォーマットされた文字列から UI をロード
-verbose(-v) create
作成されたコントロールに関する追加の情報は出力されます。
-workingDirectory(-wd) string create
作業ディレクトリを設定し、ローダはこのディテクトリからの相対パスにてアイコンやリソース ファイルなどのリソースを探します。
フラグはコマンドの作成モードで表示できます フラグはコマンドの編集モードで表示できます
フラグはコマンドの照会モードで表示できます コマンド内でフラグを複数回使用できます。

MEL 例

// Note: mydialog.ui must already exist
string $dialog1 = `loadUI -f "/users/username/mydialog.ui"`;
showWindow $dialog1;

// Load from string
global string $dialog;
global int    $counter = 0;

// Define the button command callback
proc onClick() {
    global string $dialog;
    global int    $counter;

    $counter++;

    string $control = ($dialog + "|verticalLayout|mybutton");
    button -e
      -l ("Clicked " + $counter + " times")
      $control;

    print($counter +"\n");
}

// Create a dialog with a button from a UI description in string form
proc showDialog()
{
    // Since MEL doesn't support multi-line strings
    // we use a string array to hold each line ...
    string $ui[] = {
    "<?xml version='1.0' encoding='UTF-8'?>",
    "<ui version='4.0'>",
    " <class>Dialog</class>",
    " <widget class='QDialog' name='Dialog'>",
    "  <layout class='QVBoxLayout' name='verticalLayout'>",
    "   <item>",
    "    <widget class='QPushButton' name='mybutton'>",
    "     <property name='text'>",
    "      <string>Clicked 0 times</string>",
    "     </property>",
    "     <property name='-command'>",
    "      <string>\"onClick()\"</string>",
    "     </property>",
    "    </widget>",
    "   </item>",
    "  </layout>",
    " </widget>",
    "</ui>"
    };

    // .. and then concatenate entries together.
    string $dialogString = stringArrayToString($ui, "\n");

    // Next we load the UI from string with verbose output
    global string $dialog;
    $dialog = `loadUI -v -s $dialogString`;
    window -e -wh 200 50 $dialog;

    // Display the dialog
    showWindow $dialog;
}

showDialog();