Interface: TrackSelectionSets

The TrackSelectionSets Core Interface provides MAXScript access to the Track Selection Sets functionality.

Properties:

TrackSelectionSets.count : integer : Read      

Gets the number of track selection sets.

Methods:

<boolean>TrackSelectionSets.create <string>name <maxObject by value array>tracks     trackNames:<string array>   

trackNames default value: #() 

Creates a new track selection set with the given name out of the supplied tracks. Returns true on success.

EXAMPLE

   t=teapot()
   trackSelectionSets.create "My Objects" #($Teapot001[4]) trackNames:#("My Teapot")
   --> true

<boolean>TrackSelectionSets.delete <string>name 

Deletes the named track selection set. Returns true on success.

EXAMPLE

   trackSelectionSets.count
   --> 1
   trackSelectionSets.delete "My Objects"
   --> true
   trackSelectionSets.count
   --> 0

<string>TrackSelectionSets.getName <index>index 

Returns the name of the indexed track selection set.

EXAMPLE

   trackSelectionSets.create "My Objects" #($Teapot001[4]) trackNames:#("My Teapot")
   --> true
   trackSelectionSets.count
   --> 1
   trackSelectionSets.getName 1
   --> "My Objects"

<void>TrackSelectionSets.setName <index>index <string>name 

Sets a new name in the named track selection set.

EXAMPLE

   trackSelectionSets.getName 1
   --> "My Objects"
   trackSelectionSets.setName 1 "Some New Name"
   --> OK
   trackSelectionSets.getName 1
   --> "Some New Name"

<string>TrackSelectionSets.getCurrent <Interface>trackview 

Returns the current track selection set in the supplied trackview.

<maxObject by value array>TrackSelectionSets.getTracks <string>name <&maxObject array>tracks trackNames:<&string array> 

tracks is Out parameter 
trackNames default value: #() 
trackNames is Out parameter 

Returns the tracks in the named track selection set.

EXAMPLE

   --call the method to get the tracks passing variable names by reference
   trackSelectionSets.getTracks "My Objects" &my_tracks trackNames:&my_names
   --> OK
   --check the by-reference variables for the return array values
   my_tracks
   --> #(Teapot)
   my_names
   --> #("My Teapot")

<boolean>TrackSelectionSets.add <string>name <maxObject by value array>tracks trackNames:<string array> 

trackNames default value: #() 

Adds the specified objects to the named track selection set. Returns true on success.

<boolean>TrackSelectionSets.remove <string>name <maxObject by value array>tracks 

Removes the specified objects from the named track selection set. Returns true on success.