Interface: IInteractionMode

This Core Interface exposes the Interaction Mode tab of the Preference Settings dialog to MAXScript.

See also the related Interface: MouseConfigManager.

Available in 3ds Max 2013 and higher.

Properties:

IInteractionMode.CurrentMode : enum : Read|Write 

CurrentMode enums: {#3dsMaxMode|#MayaMode|#CustomizedMode}

Get/set the current Interaction Mode for both mouse and keyboard.

Corresponds to the Interaction Mode tab of the Preference Settings dialog.

EXAMPLE

(
theProps = #("ArcRotateLocked", "MayaSelectionMode", "AutoFocusViewportOnKeyPress", "ZoomWheelIncrement",
    "MiddleMouseStrokeMode", "ZoomAboutMousePointOrthographic", "ZoomAboutMousePointPerspective", 
    "RightClickMenuOverSelectedOnly", "ZoomInDirection")
theMethods = #("GetZoomShortcut","GetPanShortcut","GetRotateShortcut")

fn printInteractionSettings =
(
    for p in theProps do format "%: %\n" p (execute ("MouseConfigManager."+p))
    for m in theMethods do (
        (execute ("MouseConfigManager."+m+" &theKey &theButton" ))
        format "%: %+%\n" m (theKey as string) (theButton as string)
    )--end m loop
)--end fn

for i in #("3dsMaxMode", "MayaMode", "CustomizedMode") do
(
    format "INTERACTION MODE: %\n" i
    IInteractionMode.CurrentMode = (i as name)
    printInteractionSettings()
    format "\n"
)
)

SAMPLE OUTPUT

INTERACTION MODE: 3dsMaxMode
ArcRotateLocked: false
MayaSelectionMode: false
AutoFocusViewportOnKeyPress: false
ZoomWheelIncrement: 1.0
MiddleMouseStrokeMode: false
ZoomAboutMousePointOrthographic: false
ZoomAboutMousePointPerspective: false
RightClickMenuOverSelectedOnly: false
ZoomInDirection: #North
GetZoomShortcut: CtrlAlt+MiddleButton
GetPanShortcut: null+MiddleButton
GetRotateShortcut: alt+MiddleButton

INTERACTION MODE: MayaMode
ArcRotateLocked: true
MayaSelectionMode: true
AutoFocusViewportOnKeyPress: true
ZoomWheelIncrement: 1.0
MiddleMouseStrokeMode: false
ZoomAboutMousePointOrthographic: false
ZoomAboutMousePointPerspective: false
RightClickMenuOverSelectedOnly: false
ZoomInDirection: #SouthEast
GetZoomShortcut: alt+RightButton
GetPanShortcut: alt+MiddleButton
GetRotateShortcut: alt+LeftButton

INTERACTION MODE: CustomizedMode
ArcRotateLocked: true
MayaSelectionMode: true
AutoFocusViewportOnKeyPress: true
ZoomWheelIncrement: 1.0
MiddleMouseStrokeMode: false
ZoomAboutMousePointOrthographic: false
ZoomAboutMousePointPerspective: false
RightClickMenuOverSelectedOnly: false
ZoomInDirection: #SouthEast
GetZoomShortcut: alt+RightButton
GetPanShortcut: alt+MiddleButton
GetRotateShortcut: alt+LeftButton

OK