mental_ray_string_オプション

macroScript MR_Progressive category:"MXS Help"
(
global MentalRayStringOptions_Progressive
try(destroyDialog MentalRayStringOptions_Progressive)catch()
rollout MentalRayStringOptions_Progressive "mr Progressive Rendering"
(
checkbutton chk_progressiveOn ">Enable Progressive Rendering" width:190 align:#center
spinner spn_samplingSize "Sampling Size:" range:[1,128,8] type:#integer fieldwidth:50 tooltip:"The size of pixel blocks in the initial coarse pass. 0 disables."
 
label lbl_mode "Sampling Mode:" across:2 align:#left offset:[0,2]
dropdownlist ddl_samplingMode items:#("detail", "sparse") width:80 align:#right offset:[1,0] tooltip:"Controls the appearance of not yet rendered subsampling pixels. Detail=Nearest Color, Coarse=Black"
label lbl_pattern "Sampling Pattern:" across:2 align:#left
dropdownlist ddl_samplingPattern items:#("scatter", "linear") width:80 align:#right offset:[1,-2] tooltip:"Controls the sequence in which the samples are computed. Scatter=Quasi-Random; Linear=Line By Line In Block"
 
spinner spn_samplingMinSamples "Sampling Min.Samples:" range:[1,1000,4] type:#integer fieldwidth:50 tooltip:"Min. samples per pixel to render before considering any of the Stop Criteria below."
spinner spn_samplingMaxSamples "Sampling Max.Samples:" range:[1,1000,100] type:#integer fieldwidth:50 tooltip:"Max. samples per pixel to render before stopping."
spinner spn_MaxTime "Max.Time (sec):" range:[0,1000,10] type:#integer fieldwidth:50 tooltip:"Max. time to render before stopping."
spinner spn_errorThreshold "Error Threshold:" range:[0.01,1,0.05] scale:0.01 type:#float fieldwidth:50 tooltip:"Error Threshold to reach before stopping."
 
button btn_quickRender "QUICK RENDER" width:190 align:#center height:30
button btn_clearSettings "Remove Settings And Close" width:190 align:#center tooltip:"Pressing this button will clear the settings from memory and close. Closing with [X] will keep the settings."
fn removeProgressiveOptions =
(
local m = mental_ray_string_options
for i = m.numOptions to 1 by -1 where matchPattern (m.GetOptionString i) pattern:"progressive*"do
m.removeOption i
)
 
fn setProgressiveOptions =
(
removeProgressiveOptions()
local m = mental_ray_string_options
m.addOption "progressive" chk_progressiveOn.state
m.addOption "progressive subsampling size" spn_samplingSize.value
m.addOption "progressive subsampling mode" ddl_samplingMode.selected
m.addOption "progressive subsampling pattern" ddl_samplingPattern.selected
m.addOption "progressive min samples" spn_samplingMinSamples.value
m.addOption "progressive max samples" spn_samplingMaxSamples.value
m.addOption "progressive max time" spn_MaxTime.value
m.addOption "progressive error threshold" spn_errorThreshold.value
)
fn getProgressiveOptions =
(
local m = mental_ray_string_options
for i = 1 to m.numOptions do
case m.GetOptionString i of
(
"progressive": chk_progressiveOn.state = m.GetOptionValue i
"progressive subsampling size": spn_samplingSize.value = m.GetOptionValue i
"progressive subsampling mode": ddl_samplingMode.selection = findItem ddl_samplingMode.items (m.GetOptionValue i)
"progressive subsampling pattern": ddl_samplingPattern.selection= findItem ddl_samplingPattern.items (m.GetOptionValue i)
"progressive min samples": spn_samplingMinSamples.value = m.GetOptionValue i
"progressive max samples": spn_samplingMaxSamples.value = m.GetOptionValue i
"progressive max time": spn_MaxTime.value = m.GetOptionValue i
"progressive error threshold": spn_errorThreshold.value = m.GetOptionValue i
)
)
on chk_progressiveOn changed state do setProgressiveOptions()
on spn_MaxTime changed value do setProgressiveOptions()
on spn_samplingSize changed value do setProgressiveOptions()
on spn_samplingMinSamples changed value do setProgressiveOptions()
on spn_samplingMaxSamples changed value do setProgressiveOptions()
on spn_errorThreshold changed value do setProgressiveOptions()
on ddl_samplingMode selected value do setProgressiveOptions()
on ddl_samplingPattern selected value do setProgressiveOptions()
on btn_quickRender pressed do max quick render
on btn_clearSettings pressed do
(
removeProgressiveOptions()
destroyDialog MentalRayStringOptions_Progressive
)
on MentalRayStringOptions_Progressive open do getProgressiveOptions()
)--end rollout
createDialog MentalRayStringOptions_Progressive 200 250
)--end script

m = mental_ray_string_options
for i = 1 to m.numOptions do
m.removeOption 1 --remove any previous options
m.addoption "importon" true
m.addoption "importon density" 1.0

macroScript MR_IrradPart category:"MXS Help"
(
global MentalRayStringOptions_IrradianceParticles
try(destroyDialog MentalRayStringOptions_IrradianceParticles) catch()
rollout MentalRayStringOptions_IrradianceParticles "mr Irradiance Particles"
(
checkbutton chk_IrraPartOn ">Enable Irradiance Particles" width:190 align:#center
group "Global Settings"
(
spinner spn_Rays "Rays:" range:[1,4096,256] type:#integer fieldwidth:50 tooltip:"The number of rays to shoot. Default is 256."
spinner spn_Passes "Indirect Passes:" range:[-1,32,0] type:#integer fieldwidth:50 tooltip:"Number of passes. 0 means direct illumination only."
checkbox chk_LockScale "Lock" across:2 align:#left
spinner spn_ScaleR "Scale R:" range:[0,1000,1] type:#float fieldwidth:50 tooltip:"Global Scale of Red Component or Global RGB Scale if Locked."
spinner spn_ScaleG "Scale G:" range:[0,1000,1] type:#float fieldwidth:50 tooltip:"Global Scale of Green Component"
spinner spn_ScaleB "Scale B:" range:[0,1000,1] type:#float fieldwidth:50 tooltip:"Global Scale of Blue Component"
dropdownlist ddl_interpolationMode items:#("No Interpolation","Interpolate All","Interpolate Secondary") width:140 selection:2 align:#right offset:[1,0] tooltip:"Controls the interpolation mode."
spinner spn_interpPoints "Interpolate Points:" range:[8,4096,64] type:#integer fieldwidth:50 tooltip:"Number of nearest neigbor points to interpolate."
)
group "Environment Irradiance"
(
checkbox chk_envOnOff "Enable Environment Irradiance"
checkbox chk_envLockScale "Lock" across:2 align:#left
spinner spn_envScaleR "Env.Scale R:" range:[0,1000,1] type:#float fieldwidth:50 tooltip:"Scale Red Env. Component or Env. RGB Scale if Locked on top of the Global Scale."
spinner spn_envScaleG "Env.Scale G:" range:[0,1000,1] type:#float fieldwidth:50 tooltip:"Scale Green Env. Component on top of the Global Scale."
spinner spn_envScaleB "Env.Scale B:" range:[0,1000,1] type:#float fieldwidth:50 tooltip:"Scale Blue Env. Component on top of the Global Scale."
spinner spn_envRays "Env.Rays:" range:[1,4096,256] type:#integer fieldwidth:50 tooltip:"The number of Env. rays to shoot. Default is 256."
)
group "Irradiance Particles Cache File"
(
button btn_setParticleFile "Set Irradiance Particles Cache File..." width:185 align:#center
edittext edt_particleFile "" fieldwidth:185 offset:[-10,-3]
checkbox chk_rebuild "Rebuild Map" checked:true tooltip:"When checked, the map will be rebuild. When unchecked, the disk or previous animation frame map will be reused."
)
 
button btn_quickRender "QUICK RENDER" width:190 align:#center height:30
button btn_clearSettings "Remove Settings And Close" width:190 align:#center tooltip:"Pressing this button will clear the settings from memory and close. Closing with [X] will keep the settings."
fn removeOptions =
(
local m = mental_ray_string_options
for i = m.numOptions to 1 by -1 where matchPattern (m.GetOptionString i) pattern:"irradiance*"do
m.removeOption i
)
 
fn setOptions =
(
removeOptions()
local m = mental_ray_string_options
m.addOption "irradiance particles" chk_IrraPartOn.state
m.addOption "irradiance particles rays" spn_Rays.value
m.addOption "irradiance particles indirect passes" spn_passes.value
if chk_LockScale.state then
m.addOption "irradiance particles scale" spn_scaleR.value
else
m.addOption "irradiance particles scale" (Point3 spn_scaleR.value spn_scaleG.value spn_scaleB.value)
m.addOption "irradiance particles interpolate" (ddl_interpolationMode.selection-1)
m.addOption "irradiance particles interppoints" spn_interppoints.value
m.addOption "irradiance particles env" chk_envOnOff.state
if chk_envLockScale.state then
m.addOption "irradiance particles env scale" spn_envScaleR.value
else
m.addOption "irradiance particles env scale" (Point3 spn_envScaleR.value spn_envScaleG.value spn_envScaleB.value)
m.addOption "irradiance particles env rays" spn_envRays.value
m.addOption "irradiance particles file" edt_particleFile.text
m.addOption "irradiance particles rebuild" chk_rebuild.state
try (
renderers.current.FinalGatherEnable2 = false
renderers.current.CommitUI()
renderers.current.UpdateUI()
)catch()
)
fn getOptions =
(
local m = mental_ray_string_options
for i = 1 to m.numOptions do
(
local theVal = m.GetOptionValue i
case m.GetOptionString i of
(
"irradiance particles": chk_IrraPartOn.state = theVal
"irradiance particles rays": spn_Rays.value = theVal
"irradiance particles indirect passes": spn_passes.value = theVal
"irradiance particles scale": (
if classof theVal == Point3 then
(
spn_scaleR.value = theVal.x
spn_scaleG.value = theVal.y
spn_scaleB.value = theVal.z
chk_LockScale.state = false
spn_scaleG.enabled = spn_scaleB.enabled = true
)
else if classof theVal == Integer or classof theVal == Float do
(
spn_scaleR.value = theVal
chk_LockScale.state = true
spn_scaleG.enabled = spn_scaleB.enabled = false
)
)
"irradiance particles interpolate": (
ddl_interpolationMode.selection = if classof theVal == Integer then theVal+1 else
((findItem #("never", "always","secondary") theVal)+1)
)
"irradiance particles interppoints": spn_interppoints.value = theVal
"irradiance particles env": chk_envOnOff.state = theVal
"irradiance particles env scale": (
if classof theVal == Point3 then
(
spn_envScaleR.value = theVal.x
spn_envScaleG.value = theVal.y
spn_envScaleB.value = theVal.z
chk_envLockScale.state = false
spn_envScaleG.enabled = spn_envScaleB.enabled = true
)
else if classof theVal == Integer or classof theVal == Float do
(
spn_envScaleR.value = theVal
chk_envLockScale.state = true
spn_envScaleG.enabled = spn_envScaleB.enabled = false
)
)
"irradiance particles env rays": spn_envRays.value = theVal
"irradiance particles file": edt_particleFile.text = theVal
"irradiance particles rebuild": chk_rebuild.state = theVal
)--end case
)--end i loop
)
on chk_IrraPartOn changed state do setOptions()
on spn_Rays changed value do setOptions()
on spn_Passes changed value do setOptions()
on chk_LockScale changed state do
(
setOptions()
spn_scaleG.enabled = spn_scaleB.enabled = not state
)
on spn_ScaleR changed value do setOptions()
on spn_ScaleG changed value do setOptions()
on spn_ScaleB changed value do setOptions()
on ddl_interpolationMode selected itm do setOptions()
on spn_interppoints changed value do setOptions()
on chk_envOnOff changed state do setOptions()
on chk_envLockScale changed state do
(
setOptions()
spn_envScaleG.enabled = spn_envScaleB.enabled = not state
)
on spn_envScaleR changed value do setOptions()
on spn_envScaleG changed value do setOptions()
on spn_envScaleB changed value do setOptions()
on spn_envRays changed value do setOptions()
on btn_setParticleFile pressed do
(
local theVal = getSaveFileName caption:"Specify Irradiance Particles Cache Filename:" types:"Irradiance Particles Cache (*.ipc)|*.ipc"
if theVal != undefined do
(
edt_particleFile.text = theVal
setOptions()
)
)
on edt_particleFile entered txt do setOptions()
on chk_rebuild changed state do setOptions()
on btn_quickRender pressed do max quick render
on btn_clearSettings pressed do
(
removeOptions()
try(renderers.current.FinalGatherEnable2 = true)catch()
destroyDialog MentalRayStringOptions_IrradianceParticles
)
on MentalRayStringOptions_IrradianceParticles open do getOptions()
)--end rollout
createDialog MentalRayStringOptions_IrradianceParticles 200 490
)--end script