Exposes the Alembic Exporter plugin to MAXScript. Available in 3ds Max 2016 and higher.

Constructor

Class instances not creatable by MAXScript.

Aliases:

Alembic_Export
AlembicExport

Alembic_Export interfaces:

Interface: AlembicExport

Properties:

Several properties have been renamed, are new, or have been removed. Available in 3ds Max 2019 and higher.

 AlembicExport.CoordinateSystem : enum : Read|Write
CoordinateSystem enums: {#Max|#Maya|#ZUp|#YUp}

Sets the coordinate system of the exported Alembic file.

Possible values are:

• #Max (or #ZUp) (default) - Z-up, right-handed coordinate system used by Autodesk 3dsMax
• #Maya (or #YUp) - Y-up, right-handed coordinate system used by Autodesk Maya

 AlembicExport.ArchiveType : enum : Read|Write
ArchiveType enums: {#HDF5|#Ogawa}

Sets the archive type of the exported Alembic file.

Possible values are:

• #HDF5 (default) - the original storage format of Alembic version 1.0
• #Ogawa - the improved storage format introduced in Alembic version 1.5

 AlembicExport.ParticleAsMesh : boolean : Read|Write

Sets whether particle shapes are exported as meshes.

 AlembicExport.AnimTimeRange : enum : Read|Write
   CacheTimeRange enums: {#CurrentFrame|#TimeSlider|#StartEnd}

Sets how the animation is saved.

Possible values are:

• #CurrentFrame - saves the current frame.
• #TimeSlider (default) - saves the active time segments on the time slider.
• #StartEnd - saves a range specified by the Step

 AlembicExport.StartFrame : integer : Read|Write

Sets the start frame for an animation range, when CacheTimeRange is #StartEnd.

 AlembicExport.EndFrame : integer : Read|Write

Sets the end frame for an animation range, when CacheTimeRange is #StartEnd.

 AlembicExport.ShapeSuffix : boolean : Read|Write

When set to true, appends the string "Shape" to the name of each exported mesh. This property is set to false by default.

 AlembicExport.SamplesPerFrame : integer : Read|Write     

Sets the number of animation samples per frame for AnimTimeRange #TimeSlider and #StartEnd.

 AlembicExport.Hidden : boolean : Read|Write     

When true, export the hidden geometry.

 AlembicExport.UVs : boolean : Read|Write     

When true, export the mesh UV map channel.

 AlembicExport.Normals : boolean : Read|Write     

When true, export the mesh normals.

 AlembicExport.VertexColors : boolean : Read|Write     

When true, export the mesh vertex color map 0 and the current vertex color display data when it differs.

 AlembicExport.ExtraChannels : boolean : Read|Write     

When true, export the mesh extra map channels (map channels greater than channel 1).

 AlembicExport.Velocity : boolean : Read|Write     

When true, export the mesh vertex and particle velocity data.

 AlembicExport.MaterialIDs : boolean : Read|Write     

When true, export the mesh material IDs as Alembic face sets.

 AlembicExport.Visibility : boolean : Read|Write     

When true, export the node visibility data.

 AlembicExport.LayerName : boolean : Read|Write     

When true, export the node layer name as an Alembic object property.

 AlembicExport.MaterialName : boolean : Read|Write     

When true, export the geometry node material name as an Alembic object property.

 AlembicExport.ObjectID : boolean : Read|Write     

When true, export the geometry node g-buffer object ID as an Alembic object property.

 AlembicExport.CustomAttributes : boolean : Read|Write     

When true, export the node and its modifiers custom attributes into an Alembic object compound property.

Methods:

    <void>setDefaults()
       setDefaults - no automatic redraw after invoked

Reset all AlembicExport properties to their default values.

Actions:

No actions exposed.

EXAMPLE

resetMaxFile #noprompt --reset the scene
c = cone() --create a Cone primitive
b = bend() --create a Bend modifier
addModifier c b --add the Bend to the Cone
with animate on (--enable animation
  at time 100 ( --and set on frame 100
    b.angle = 90 --the Bend Angle to 90
    c.pos = [10,20,30] --and move the Cone
  )--end time context
)--end animate on context
AlembicExport.ArchiveType = #hdf5 --force the old file format
AlembicExport.CoordinateSystem = #max --force Z up coordinates
--Export the file without opening the dialog
--The explicit using: argument is not necessary as the export plugin 
--needed will be resolved automatically based on the file extension:
exportFile (GetDir #export +"\\alembictest_hdm5_max.abc") #noPrompt using:AlembicExport

AlembicExport.ArchiveType = #ogawa --force the new file format
AlembicExport.CoordinateSystem = #maya --force Y up coordinates
--Export the file without opening the dialog
--This time we will ommit the explicit using: argument:
exportFile (GetDir #export +"\\alembictest_ogawa_maya.abc") #noPrompt

--RESULT: We now have two files, one using Max Z up and HDF5 storage, 
--and one using Maya Y up and the newer Ogawa storage.

--See the AlembicImport:ImporterPlugin topic for an example
--of importing these files back into 3ds Max.