スクリプト マニピュレータ

半径マニピュレータ

半径マニピュレータはかなり単純なもので、スクリプト マニピュレータ システムを記述する場合の良い例になります。

このマニピュレータのコードには次のコードが含まれます。コードの後ろにどのように動作するか詳細に記載されています。

--------------------------------------------------------------------
-- Generic radius manipulator
-- Written by Scott Morrison
-- This manipulator sets the radius on any object or modifier with
-- a parameter named "radius". It creates a circle gizmo of the appropriate
-- radius centered at the origin in the XY plane.
plugin simpleManipulator radiusManip
name:"RadiusManip"
invisible:true
(
-- Create the green and red colors for the gizmo
local g = [0, 1, 0], r = [1, 0, 0]
-- This manipulator manipulates any node with a "radius" property
on canManipulate target return (findItem (getPropNames target) #radius) != 0
-- Create the manipulator gizmo.
-- This is called initially and whenever the manipulator target changes
on updateGizmos do
(
-- Clear the current gizmo cache
this.clearGizmos()
-- Set the radius of circle gizmo a little bigger than the target radius
giz = manip.makeCircle [0,0,0] (target.radius * 1.01) 28
-- Add the circle to the manipulator
this.addGizmoShape giz 0 g r
-- return the ToolTip string
return node.name + " radius = " + target.radius as string
)
-- mouseMove is called on every mouse move when dragging the manip
-- It needs to convert the mouse position 'm' into a new value for the radius
on mouseMove m which do
(
-- Create the XY plane.
-- manip.makePlaneFromNormal takes a normal vector and a point
-- and creates a plane passing through the point with the given normal
local pl = manip.makePlaneFromNormal z_axis [0, 0, 0],
projectedPoint = [0,0,0]
-- Compute the hit-ray in local coordinates
viewRay = this.getLocalViewRay m
-- Intersect the plane with the view ray
res = pl.intersect viewRay &projectedPoint
-- If the intersection worked, set the radius
if (res) then target.radius = (length projectedPoint) / 1.01
)
)
-------------------------------------------------------------------- 

ヘッダ:

plugin simpleManipulator radiusManip
name:"RadiusManip"
invisible:true

MAXScript に、これが「RadiusManip」というスクリプト マニピュレータ プラグインであることを知らせます。「invisible:true」は、作成パネルでマニピュレータ用の作成ボタンを作らないことをシステムに伝えます。

本体:

各種イベント用ハンドラのセット。

on canManipulate target return (findItem (getPropNames target) #radius) != 0

「 canManipulate 」は、「操作」ボタンを押したときに選択されるノードごとに、各マニピュレータで呼び出されます。「 target 」パラメータは、操作する可能性のあるオブジェクトです。これは、基本オブジェクト、オブジェクト上のすべてのモディファイヤ、およびオブジェクトのノード上の変換コントローラで呼び出されます。また、変換コントローラが PRS コントローラの場合、位置、回転、およびスケール コントローラで「 canManipulate 」を呼び出します。

半径マニピュレータの場合は、「 radius 」というプロパティを持つオブジェクトを操作できます。

球のような特定のオブジェクト タイプを操作するマニピュレータを作成する場合は、次のスクリプトを使用します。

on canManipulate target return classOf target == sphere

「canManipulateNode n 」という、代替ハンドラが必要になる場合もあります。これは、選択したノードをハンドラに渡すたびに渡されます。これは通常は必要ではありませんが、「 canManipulate 」に「 target 」として渡されるもの以外のノードのプロパティをマニピュレータで操作する場合は有効です。

次のハンドラは「 updateGizmos 」と呼ばれ、マニピュレータがギズモを作る必要があるとき常に呼び出されます。マニピュレータの作成時に操作中のターゲットが変わる場合は、常にこれが呼び出されます。

MAXScript は、マニピュレータの作成時に、ハンドラへの呼び出しの内部で有効な変数を設定します。その 1 つが「 target 」と呼ばれる変数で、操作対象のオブジェクト、モディファイヤ、またはコントローラになります。もう 1 つは「 this 」で、これはマニピュレータ自体のことです。これも、ギズモでフラグとして使用可能な定数値を設定します。詳細は、後で説明します。「 node 」値も使用できます。これはターゲットを含むノードです。

すべてのマニピュレータが「 updateGizmos 」ハンドラの最初に含める必要があるものは、「 this.clearGizmos() 」呼び出しです。これは現在キャッシュされているギズモをクリアします。

次に、ビューポートに表示されるギズモのセットを作成します。半径マニピュレータの場合は、操作する半径を表す単一の円を作成します。

giz =manip.makeCircle [0,0,0] (target.radius * 1.01) 28

「 manip 」は、マニピュレータから使用可能な、エクスポートされたユーティリティ インタフェース関数のセットです。詳細については、下記の参照を参照してください。この例では円を作成しています。円の中心は原点にあり、半径は操作する半径の 1.01 倍で、セグメントは 28 です。操作中のオブジェクトからギズモがほんの少しだけ突き出るように、係数「1.01」が加えられています。半径を直接使用すると、操作中のオブジェクトと同じ場所にあるため、ビューポートからは見えない場合があります。

3D ギズモは、マニピュレータのターゲットを含むノードの、ローカル座標系で定義されることに注意してください。マニピュレータの表示やヒットテスト実行時にノードを移動、回転、またはスケールすると、システムが自動的に補正を行います。

次に、マニピュレータにギズモを追加します。

this.addGizmoShapegiz 0 g r

これは、特殊なフラグ値を含めずに(つまり「0」で)シェイプ ギズモをマニピュレータに追加することを、マニピュレータに伝えます。 これらのフラグすべてについては、以下で説明します。また、このコマンドは、未選択のカラーとして緑(「g」)、選択済みのカラーとして赤(「r」)を指定しています。選択済みのカラーはマウスがその上を通過する際に使用され、未選択のカラーはマウスがその上にない場合に使用されます。最後に、このメソッドは文字列値を返します。

この文字列値は、マウスがギズモの上を通過する際にツール チップとして使用されます。

通常ギズモは、メッシュ、形状(ワイヤフレーム)、テキスト、およびマーカーで構成されます。詳細は、下記の「参照」で説明されています。

次のハンドラは、「 mouseMove m which 」と呼ばれます。これは、ターゲットの操作中、マウスを移動するたびに呼び出されます。「 m 」パラメータはマウス位置のスクリーン座標を保持し、「 which 」パラメータは、ドラッグ中のギズモを示すインデックスです。ギズモは、「 updateGizmos 」で作成された順に、0 で始まる番号が付けられます。

mouseMove ハンドラは、通常、マニピュレータの実装で最も扱いにくい部分です。できるだけ、マニピュレータ ギズモがマウスの下を通るように、操作中のパラメータ値を更新する必要があります。

3 次元空間に存在するマニピュレータの場合、これは通常「 ヒットレイ 」を計算することで実行されます。ヒットレイはマウス位置を通過する 3 次元空間内のレイで、ビューの方向に移動します。

次のように計算されます。

viewRay = this.getLocalViewRaym

このビュー レイはこの後いくつかの平面と交差し、その交差点を使用して新しいパラメータ値が計算されます。

半径マニピュレータの場合、ここで使用している平面は XY 平面です。これは、半径円がローカル座標スペースの XY 平面にあるためです。

次のように計算されます。

local pl = manip.makePlaneFromNormalz_axis [0, 0, 0],

これにより、法線が Z 軸である平面で原点([0,0,0])を通る、「pl」が作成されます。

これをビュー レイと交差させるため、平面上で「交差」演算を使用します。

projectedPoint= [0,0,0]
res =pl.intersect viewRay &projectedPoint

まず最初に、交差の結果のホルダに「 projectedPoint 」を設定します。戻り値「 res 」は、交差を実行したかどうかを示すブール値です。true であれば交差は実行済み、false であれば失敗であることを示します。平面がビュー レイと平行している場合は、失敗することがあります。

「 projectedPoint 」にいったん交差点ができたら、それを使って半径の新しい値を決定します。このレイでは、新しい半径として原点(「 length projectedPoint 」)からの距離を使用します。操作中の実際の半径より 1.01 倍大きいギズモを作成したため、これを補正するために 1.01 で除算してスケールします。

これで操作は終了しました。通常は、「mouseMove」ハンドラで三角関数と線形代数を使う必要があります。直接操作を行うのは、ギズモはマウスの下を直接通る必要があるという考え方からです。

より複雑な 3D マニピュレータの例については、 UVWManip.ms のコードを確認してください。

ヘルパー関数

マニピュレータがサポートするいくつかの組み込み関数、およびユーティリティ関数を含む 2 つのヘルパー パッケージがあります。

simpleManipulator タイプ自体が、これらの利用可能な関数を保持します。

this.clearGizmos()

これは、現在のギズモ キャッシュをクリアするために「updateGizmos」ハンドラの先頭で呼び出す必要があります。

this.addGizmoMesh mesh flags unselColor selColor

これによって、メッシュ(MAXの用語ではジオメトリ)からギズモが作成されます。メッシュはどの MAX メッシュでもよく、MAXScript のメッシュ作成用のツールで作成されていてもかまいません。簡単な方法の 1 つとしては、プリミティブのインスタンスを作成し、メッシュを作成する方法があります。

フラグには、0 を設定したり、1 つまたは複数の値を設定したりすることができます。複数のフラグを適用するには、各フラグの値を加算します。

次に、すべてのフラグ、および addGizmoText、addGizmoMarker、addGizmoShape、addGizmoMesh で使用可能かどうかを示します。

gizmoDontDisplay

ギズモを表示しないようにシステムに指示します。ヒット テストが行われますが、表示はされません。すべてに適用されます。

gizmoDontHitTest

ギズモをヒットテストしないようにシステムに指示します。ヒット テストが行われますが、表示はされません。すべてに適用されます。

gizmoActiveViewportOnly

アクティブなビューポートの該当するギズモの表示とヒット テストだけを行うようシステムに通知します。

this.addGizmoShapegizmo Shape flags unselColor selColor

これによって、シェイプ オブジェクトからギズモが作成されます。gizmoShape は、次に説明するように、「manip」パッケージの関数を使って作成できます。

フラグには「addGizmoMesh」と同じ値をセットできるほか、さらに 2 つの値がサポートされます。

gizmoUseScreenSpace

シェイプの座標を 3 次元の値ではなく、ビューポートのデバイス座標として解釈するようにシステムに指示します。値は 3 次元座標として引き続き指定されますが、「Z」座標は無視され、addGizmoMesh 以外のすべてに適用されます。

gizmoUseRelativeScreenSpace

これは gizmoUseScreenSpace に似ていますが、座標は 0.0 から 1.0 までの値として指定され、各ビューポートでビューポートの幅または高さのパーセントとして解釈され、addGizmoMesh 以外のすべてに適用されます。

addGizmoMarker markerType position flags unselColor selColor

これによって、マーカーからギズモが作成されます。「markerType」パラメータの値は次のとおりです。

#point #hollowBox #plusSign #asterisk #xMarker #bigBox #circle #triangle #diamond #smallHollowBox #smallCircle #smallTriangle #smallDiamond #dot #smallDot

position は、3D 空間上のポイントまたは 2D の画面空間上のポイントです。フラグは、addGizmoShape でサポートされるものと同じです。

addGizmoText text position flags unselColor selColor

これによって、画面上にテキストのギズモが作成されます。テキストはヒットテストを行ったり、マウスで選択したりすることはできません。これは表示のためだけに使用されます。

getLocalViewRay m

この関数はマウスの位置をとり、ビューの方向でそのマウス位置を通るレイを返します。戻り値は、マニピュレータ ターゲットを所有するノードのローカル座標で返されます。

平面オブジェクト

「manip.makePlaneFromNormal」から返される平面オブジェクトには、利用可能な次の関数があります。

intersectionPoint= [0,0,0]
plane.intersect ray &intersectionPoint

これは、与えられたレイを平面と交差させます。成功した場合はture、失敗した場合は false を返します。成功した場合、交差点は「intersectionPoint」値で設定されます。

plane.mostOrthogonal ray otherPlane

これは、与えられたレイに最も直交する平面を返します。つまり、ビュー方向に対して最も「四角い」平面です。

マニピュレータが、レイの投影に、2 つの別々の平面の間を選択することもあります。通常は、直接的にビュー レイに面する平面に投影するのが最善で、この関数がそれを決定します。使用例は、「UVWManip.ms」を参照してください。

plane.getNormal()

平面の法線を返します。

plane.getPoint()

平面が通るポイントを返します。

plane.getPlaneConstant()

平面定数の値を返します。これは、平面を定義する方程式の中の「D」の値です。

Ax + By + Cz + D = 0

GizmoShape オブジェクト

GizmoShape は、ワイヤフレーム ギズモの作成時に使用可能なシェイプ オブジェクトです。空の GizmoShape は次のように取得できます。

local giz = manip.makeGizmoShape()

これらの関数は、次のとおりです。

giz.addPoint point

シェイプに新しいポイントを追加します。このポイントは、ワイヤフレームを作るためにライン セグメントに接続されます。閉じたシェイプにする場合、最初のポイントを最後のポイントとして、再度追加する必要があります。

giz.startNewLine()

シェイプ内で新しいライン セグメントを開始します。

giz.transform matrix

指定した Matrix3 変換を使ってギズモを変換します。